source: WorldVistAEHR/trunk/r/IMAGING-MAG-ZMAG/MAGGTUP.m@ 1361

Last change on this file since 1361 was 623, checked in by George Lilly, 15 years ago

revised back to 6/30/08 version
File size: 5.3 KB
RevLine 
[623]1MAGGTUP ;WOIFO/GEK - Imaging System User preferences ; [ 06/20/2001 08:57 ]
2 ;;3.0;IMAGING;**7,8,48,45**;Sep 12, 2005
3 ;; +---------------------------------------------------------------+
4 ;; | Property of the US Government. |
5 ;; | No permission to copy or redistribute this software is given. |
6 ;; | Use of unreleased versions of this software requires the user |
7 ;; | to execute a written test agreement with the VistA Imaging |
8 ;; | Development Office of the Department of Veterans Affairs, |
9 ;; | telephone (301) 734-0100. |
10 ;; | |
11 ;; | The Food and Drug Administration classifies this software as |
12 ;; | a medical device. As such, it may not be changed in any way. |
13 ;; | Modifications to this software may result in an adulterated |
14 ;; | medical device under 21CFR820, the use of which is considered |
15 ;; | to be a violation of US Federal Statutes. |
16 ;; +---------------------------------------------------------------+
17 ;;
18 Q
19GET(MAGRY,CODE) ;RPC [MAGGUPREFGET] Call to Get user preferences.
20 ;
21 N Y,PRFIEN,J,X,Z,NODE,MAGPREF
22 N $ETRAP,$ESTACK S $ETRAP="D ERRA^MAGGTERR"
23 K MAGRY
24 S MAGRY(0)="0^Error: Attempting to access user preference"
25 S PRFIEN=$O(^MAG(2006.18,"AC",DUZ,""))
26 ; if first time user
27 I 'PRFIEN S PRFIEN=$$NEWUSER(DUZ) Q:PRFIEN=-1
28 ; merge default settings into User's Preferences
29 D MERGE(PRFIEN)
30 ; This returns the users default Filter, and creates filters if needed.
31 S $P(^MAG(2006.18,PRFIEN,"LISTWIN1"),"^",3)=$$DFTFLT^MAGGSFLT(DUZ)
32 S MAGRY(0)="1^User Preferences returned."
33 ;
34 ; At This point. Then entry in 2006.18 for User DUZ in complete
35 ; it has been merged with defaults, and has a valid Default Filter.
36 ;
37 ; if caller only wants one node, get it then quit.
38 I $L($G(CODE)) S MAGRY($O(MAGRY(""),-1)+1)=CODE_"^"_$G(^MAG(2006.18,PRFIEN,CODE)) Q
39 ;
40 ; loop through User Pref file, returning all nodes.
41 ; Next line was Un-Commented out. BUT Clients before Patch 8 need it.
42 S MAGRY($O(MAGRY(""),-1)+1)="SYS^"_^MAG(2006.18,PRFIEN,0)
43 S NODE=""
44 F S NODE=$O(^MAG(2006.18,PRFIEN,NODE)) Q:(NODE="") D
45 . S MAGRY($O(MAGRY(""),-1)+1)=NODE_"^"_^MAG(2006.18,PRFIEN,NODE)
46 Q
47MERGE(PRFIEN) ; Merge default settings into User Prefs returned.
48 ; This will assure the User Prefs returned have values for New fields.
49 ; PRFIEN = IEN in IMAGING USER PREFERENCES File.
50 N NODE,DARR,MN,YN
51 D DFLTARR(.DARR)
52 S NODE="" F S NODE=$O(DARR($J,NODE)) Q:(NODE="") D
53 . S YN=DARR($J,NODE)
54 . S MN=$G(^MAG(2006.18,PRFIEN,NODE))
55 . F J=1:1:$L(YN,"^") I ($P(YN,"^",J)'=""),($P(MN,"^",J)="") S $P(MN,"^",J)=$P(YN,"^",J)
56 . S ^MAG(2006.18,PRFIEN,NODE)=MN
57 ;
58 Q
59SAVE(MAGRY,DATA) ;RPC [MAGGUPREFSAVE] Call to save User Preferences
60 ;
61 S MAGRY="0^Error: Saving user preferences."
62 N X,Y,NODE,PRFIEN,J
63 N $ETRAP,$ESTACK S $ETRAP="D ERR^MAGGTERR"
64 S PRFIEN=$O(^MAG(2006.18,"AC",DUZ,"")) I 'PRFIEN S PRFIEN=$$NEWUSER(DUZ) Q:PRFIEN=-1
65 S NODE="" F S NODE=$O(DATA(NODE)) Q:NODE="" D
66 . S X=$G(^MAG(2006.18,PRFIEN,NODE))
67 . S Y=DATA(NODE)
68 . F J=1:1:$L(Y,"^") I $L($P(Y,"^",J)) S $P(X,"^",J)=$P(Y,"^",J)
69 . S ^MAG(2006.18,PRFIEN,NODE)=X
70 S MAGRY="1^User Preferences saved."
71 Q
72NEWUSER(USER) ;Returns IEN of New entry in IMAGING USER PREFERENCES File.
73 K DD,DO
74 N DIC
75 S X=$E($$GET1^DIQ(200,USER_",",.01),1,15)_" (SETTING 1)"
76 S DIC="^MAG(2006.18,",DIC(0)="L"
77 S DIC("DR")="1////"_USER_";2////12;3////12;" D FILE^DICN
78 I Y=-1 Q Y
79 D DEFAULT(+Y)
80 Q +Y
81DEFAULT(NEWPREF) ;Setup a new IMAGING USER PREFERENCES entry, with System defaults.
82 ; NEWPREF = IEN in IMAGING USER PREFERENCES File
83 N DFTPREF,N0,DFTSET
84 S DFTPREF=+$$GET1^DIQ(2006.1,$$PLACE^MAGBAPI(DUZ(2)),100,"I") ; DBI - SEB 9/20/2002
85 I DFTPREF,$D(^MAG(2006.18,DFTPREF)) D DEFUSER(NEWPREF,DFTPREF) Q
86 ; save the User name, Setting Name
87 S N0=$P(^MAG(2006.18,NEWPREF,0),U,1,4)
88 D DFLTARR(.DFTSET)
89 M ^MAG(2006.18,NEWPREF)=DFTSET($J)
90 ; reset User name, Setting name.
91 S $P(^MAG(2006.18,NEWPREF,0),U,1,4)=N0
92 Q
93DEFUSER(NEWPREF,DFTPREF) ;Merge New User preference with the Default User as defined
94 ; in the Imaging Site Parameters file
95 ; NEWPREF = new IMAGING USER PREFERENCE (IEN)
96 ; DFLTPREF = DEFAULT USER PREFERENCE in the IMAGING SITE PARAMETERS File
97 ;
98 N X0
99 S X0=$P(^MAG(2006.18,NEWPREF,0),"^",1,4)
100 M ^MAG(2006.18,NEWPREF)=^MAG(2006.18,DFTPREF)
101 S $P(^MAG(2006.18,NEWPREF,0),"^",1,4)=X0
102 ; remove default user's default Filter from new user's preferences.
103 S $P(^MAG(2006.18,NEWPREF,"LISTWIN1"),"^",3)=""
104 Q
105DFLTARR(ARR) ; Return an Array of All Default settings
106 K ARR($J)
107 S ARR($J,0)="^^^^0^1^1^"
108 S ARR($J,"DICOMWIN")="2^320^292^724^487"
109 S ARR($J,"IMAGEGRID")="2^487^2^786^426^1^35,73,67,34,110,46,69,96,76,79,25,0,0^1^"
110 S ARR($J,"REPORT")="2^2^333^722^437^Courier^^10"
111 S ARR($J,"RADLISTWIN")="2^487^10^433^172^0"
112 S ARR($J,"MAIN")="2^1^1^487^172^1"
113 S ARR($J,"ABS")="2^1^160^486^326^134^113^1^1^3^24^2^1^0"
114 S ARR($J,"FULL")="2^310^282^714^487^674^447^^1^1^4^1^0^1"
115 S ARR($J,"GROUP")="2^24^231^427^457^110^70^^1^2^24^2^1^0"
116 S ARR($J,"DOC")="2^298^24^729^429^0^0^3^1^2^4^2^0"
117 S ARR($J,"CAPCONFIG")="1^1^1^0^0^0^0^1^0^1^0^0^1^1^0^0^1^1^1^1^1^1^200^400^300^100^500^0^0^1^"
118 S ARR($J,"CAPTIU")="5^369^760^654^289^67^170^1^1^"
119 S ARR($J,"RIVER")="1^0^0^0^"
120 S ARR($J,"APPPREFS")="1^7^7^10"
121 S ARR($J,"LISTWIN1")="1^1^^1^1"
122 Q
Note: See TracBrowser for help on using the repository browser.