source: WorldVistAEHR/trunk/r/INCOME_VERIFICATION_MATCH-IVM/IVM20P.m@ 1450

Last change on this file since 1450 was 613, checked in by George Lilly, 15 years ago

initial load of WorldVistAEHR
File size: 4.5 KB
Line 
1IVM20P ;ALB/CPM - IVM V2.0 POST INITIALIZATION ; 23-JUN-94
2 ;;Version 2.0 ; INCOME VERIFICATION MATCH ;; 21-OCT-94
3 ;
4 D ENPAR ; add parameter entry if necessary
5 D MG ; add IVM TRANSMISSIONS group, if necessary
6 D MG1 ; add IVM MESSAGES group
7 D HL7^IVM20P1 ; add/update HL7 parameters
8 D MTCT ; add new MT Changes Types to #408.42
9 D IB ; add new IB Action Status to #350.21
10 D ^IVMONIT ; install protocols
11 D ^IVM20P2 ; install list templates
12 D ^IVM20P3 ; update ^XUTL("XQORM" for IB protocols
13 D SETPRIM ; flag all Means Tests as the primary test
14 D BULL^IVM20P1 ; alert the IVM Center of the installation
15 D PARDATE ; set install date in #301.9
16 ;
17 ; Installation has completed - display final messages
18 ;
19 D NOW^%DTC S IVMEDT=$H
20 W !!,">>> Initialization Complete at " S Y=% D DT^DIQ
21 I $D(IVMBDT) D
22 .S IVMDAY=+IVMEDT-(+IVMBDT)*86400 ;additional seconds of over midnight
23 .S X=IVMDAY+$P(IVMEDT,",",2)-$P(IVMBDT,",",2)
24 .W !," Elapse time for initialization was: ",X\3600," Hours, ",X\60-(X\3600*60)," Minutes, ",X#60," Seconds"
25 ;
26 W !!,"The installation of Income Verification Match Version 2.0 has completed."
27 W !!,"Please be sure that the IVM nightly job (option IVM BACKGROUND JOB) is"
28 W !,"scheduled to run. If it is not, it should be scheduled to run early"
29 W !,"each morning."
30 W !!,"Be sure that it is not scheduled twice!!"
31 ;
32 W !!,"Remember to re-compile the cross reference routines for the INTEGRATED"
33 W !,"BILLING ACTION (#350) and ANNUAL MEANS TEST (#408.31) files, using DIKZ,"
34 W !,"on all of your systems."
35 ;
36 K IVMMIEN,IVMDIEN,IVMBDT,IVMEDT,IVMDAY,X,I
37 Q
38 ;
39 ;
40ENPAR ; Add an entry in the IVM SITE PARAMETER (#301.9) file.
41 Q:$D(^IVM(301.9,1)) ; entry already exists
42 W !!,">>> Creating an entry in the IVM SITE PARAMETER (#301.9) file... "
43 S DIC="^IVM(301.9,",DIC(0)="",X=$P($$SITE^VASITE,"^",3)
44 K DD,DO D FILE^DICN
45 K %,DA,DIC,DIE,X,Y
46 Q
47 ;
48MG ; Add mailgroup for IVM transmissions
49 S X="IVM TRANSMISSIONS"
50 S DIC="^XMB(3.8,",DIC(0)="L",DLAYGO=3.8
51 D ^DIC S (DA,IVMMIEN)=+Y I '$P(Y,U,3) G MGQ
52 W !!,">>> Adding IVM TRANSMISSIONS mailgroup for network transmissions..."
53 S DIE=DIC,DR="4////PU;5////^S X=DUZ;7////n;3///^S X=""Contains members to receive IVM HL7 transmissions"";12///^S X=""S.HL SERVER@""_$S(IVMPROD:"""",1:""B"")_""IVM.VA.GOV"";"
54 D ^DIE
55MGQ K DA,DIC,DIE,DLAYGO,X,Y
56 Q
57 ;
58MG1 ; Add mailgroup for IVM Messages
59 S X="IVM MESSAGES"
60 S DIC="^XMB(3.8,",DIC(0)="L",DLAYGO=3.8
61 D ^DIC S (DA,IVMGPTR)=+Y I '$P(Y,U,3) G MG1Q
62 W !!,">>> Adding IVM MESSAGES mailgroup for sending results of data transmissions..."
63 S DIE=DIC,DR="4////PU;5////^S X=DUZ;7////n" D ^DIE
64 S ^XMB(3.8,IVMGPTR,2,0)="^^3^3^"_DT_"^^^"
65 S ^XMB(3.8,IVMGPTR,2,1,0)="This mail group will receive messages pertaining to erroneous data"
66 S ^XMB(3.8,IVMGPTR,2,2,0)="transmitted to the IVM Center and for data to be uploaded from the IVM"
67 S ^XMB(3.8,IVMGPTR,2,3,0)="Center."
68 ;
69 ; - update pointer in file #301.9
70 S $P(^IVM(301.9,1,0),"^",2)=IVMGPTR
71MG1Q K DA,DIC,DIE,DLAYGO,X,Y,IVMGPTR
72 Q
73 ;
74MTCT ; Add entries to the MEANS TEST CHANGES TYPE (#408.42) file.
75 I $O(^DG(408.42,"B","MEANS TEST UPLOAD",0)),$O(^DG(408.42,"B","UPLOADED MEANS TEST DELETION",0)) Q
76 W !!,">>> Adding new entries to the MEANS TEST CHANGES TYPE (#408.42) file... "
77 F IVMX="MEANS TEST UPLOAD","UPLOADED MEANS TEST DELETION" D
78 .Q:$O(^DG(408.42,"B",IVMX,0))
79 .S DIC="^DG(408.42,",DIC(0)="",DLAYGO=408.42,X=IVMX K DD,DO D FILE^DICN
80 K %,DA,DIC,DLAYGO,IVMX,X,Y
81 Q
82 ;
83PARDATE ; Set today's date into the parameter file.
84 I '$P(^IVM(301.9,1,0),"^",6) S $P(^IVM(301.9,1,0),"^",6)=DT
85 Q
86 ;
87IB ; Add new hold status in file #350.21.
88 Q:$D(^IBE(350.21,21))
89 W !!,">>> Adding a new status in the IB ACTION STATUS (#350.21) file... "
90 S X="HOLD - REVIEW",DIC(0)="",DINUM=21,DLAYGO=350.21,DIC="^IBE(350.21,"
91 D FILE^DICN S IBN=+Y
92 I Y<0 W !," Unable to add new status! Please contact your ISC." G IBQ
93 S ^IBE(350.21,IBN,0)="HOLD - REVIEW^ON HOLD (REVIEW)^REVIEW^0^0^1"
94 S DA=IBN,DIK="^IBE(350.21," D IX1^DIK
95IBQ K X,DIC,DINUM,DLAYGO,DA,DIK
96 Q
97 ;
98SETPRIM ; Set primary and source fields to 1 for all existing means tests.
99 Q:+$G(^DD(301.5,0,"VR"))'<2
100 W !!,">>> Initializing new ANNUAL MEANS TEST file (#408.31) fields for",!," existing entries as follows:"
101 W !," SOURCE OF INCOME TEST (#.23) = VAMC (value = 1)",!," PRIMARY INCOME TEST FOR YEAR? (#2)= YES (value = 1)",!
102 S DIE="^DGMT(408.31,",DR=".23////1;2////1"
103 S DGMTI=0 F DGMTC=1:1 S DGMTI=$O(^DGMT(408.31,DGMTI)) Q:'DGMTI S DA=DGMTI D ^DIE W:'(DGMTC#1000) "."
104 K DA,DR,DIE,DGMTI,DGMTC
105 Q
Note: See TracBrowser for help on using the repository browser.