source: WorldVistAEHR/trunk/r/INTEGRATED_BILLING-IB-PRQ--IBD--IBQ--PRQS/IBCNRE3.m@ 1608

Last change on this file since 1608 was 613, checked in by George Lilly, 15 years ago

initial load of WorldVistAEHR
File size: 3.2 KB
RevLine 
[613]1IBCNRE3 ;DAOU/DMK - Edit PHARMACY BENEFITS MANAGER (PBM) APPLICATION Sub-file ;23-DEC-2003
2 ;;2.0;INTEGRATED BILLING;**251**;21-MAR-94
3 ;;Per VHA Directive 10-93-142, this routine should not be modified.
4 ;
5 ; Specific to E-PHARM APPLICATION Entry
6 ; Edit LOCAL ACTIVE? Field
7 ;
8 ; 366.023 PHARMACY BENEFITS MANAGER (PBM) APPLICATION
9 ; .01 APPLICATION
10 ; .03 LOCAL ACTIVE?
11 ;
121000 ; Control processing
13 N ANAME,APIEN,FIELDNO,FILENO,FILENO1,QUIT
14 N DISYS
15 ;
16 D INIT1
17 D HEADING
18 F D 2000 Q:QUIT
19 Q
20 ;
212000 ; Control processing
22 N IEN,IENS,IENS1,KEY
23 ;
24 S QUIT=0
25 ;
26 ; Control file entry selection and subfile entry validation
27 D IEN
28 I IEN=-1 S QUIT=1 Q
29 I APIEN=-1 Q
30 ;
31 ; Control file entry printing
32 D PRINT1
33 ;
34 ; Control subfile entry printing
35 D PRINT2
36 ;
37 ; Control subfile entry editing
38 D EDIT
39 Q
40 ;
41EDIT ; Edit subfile entry data
42 ; 366.023 PHARMACY BENEFITS MANAGER (PBM) APPLICATION Subfile
43 ;
44 N DA,DIDEL,DIC,DIE,DLAYGO,DR,DTOUT,X,Y
45 N %,A,D,D0,DDER,DI,DISYS,DQ,OLD
46 ;
47 S DA=APIEN,DA(1)=IEN
48 S DIE=$$ROOT^DILFD(FILENO1,","_IEN_",")
49 ;
50 ; .03 LOCAL ACTIVE
51 S DR=".03R"_"~"_KEY_" - Local Active?"
52 ;
53 ; Quit if value unchanged
54 ; OLD = old value
55 ; X = new value
56 S OLD=$$GET1^DIQ(FILENO1,IENS1,.03,"I")
57 S DR=DR_";"_"S:OLD=X Y="""""
58 ;
59 ; .04 USER EDITED LOCAL
60 S DR=DR_";"_".04////"_DUZ
61 ;
62 ; .05 DATE/TIME LOCAL EDITED
63 S DR=DR_";"_".05////"_$$NOW^XLFDT()
64 ;
65 D ^DIE
66 ;
67 W !
68 Q
69 ;
70HEADING ; Print heading
71 W @IOF
72 W "PHARMACY BENEFITS MANAGER (PBM) File Inquiry and Edit (E-PHARM)",!
73 Q
74 ;
75IEN ; Select file entry
76 N I
77 ;
78 S IEN=$$SELECT1^IBCNRFM1(FILENO,"Select Pharmacy Benefits Manager (PBM) Name: ")
79 I IEN=-1 Q
80 S IENS=IEN_","
81 ;
82 ; E-PHARM APPLICATION Defined?
83 S APIEN=$$LOOKUP2^IBCNRFM1(FILENO,IEN,FIELDNO,ANAME)
84 I APIEN=-1 W " E-PHARM APPLICATION not defined" Q
85 S IENS1=APIEN_","_IEN_","
86 Q
87 ;
88INIT1 ; Initialize variables
89 S ANAME="E-PHARM"
90 S FIELDNO=3
91 S FILENO=366.02
92 S FILENO1=FILENO_FIELDNO
93 I '$D(IOF) D HOME^%ZIS
94 Q
95 ;
96PRINT1 ; Print file entry data
97 ; 366.02 PHARMACY BENEFITS MANAGER (PBM) File
98 ;
99 N A
100 ;
101 W !!
102 ;
103 D GETS^DIQ(FILENO,IENS,"*","","A")
104 ;
105 ; .01 NAME
106 S KEY=A(FILENO,IENS,.01)
107 W $J("Pharmacy Benefits Manager (PBM) Name: ",40),$G(A(FILENO,IENS,.01)),!
108 ;
109 ; .02 DATE/TIME CREATED
110 W $J("Date/Time Created: ",40),$G(A(FILENO,IENS,.02)),!
111 Q
112 ;
113PRINT2 ; Print subfile entry data
114 ; 366.023 PHARMACY BENEFITS MANAGER (PBM) APPLICATION Subfile
115 ;
116 N A
117 ;
118 W !
119 ;
120 D GETS^DIQ(FILENO1,IENS1,"*","","A")
121 ;
122 ; .01 APPLICATION
123 W $J("Application: ",40),$G(A(FILENO1,IENS1,.01)),!
124 ;
125 ; .13 DATE/TIME CREATED
126 W $J("Date/Time Created: ",40),$G(A(FILENO1,IENS1,.13)),!
127 ;
128 ; .11 DEACTIVATED
129 W $J("Deactivated? ",40),$G(A(FILENO1,IENS1,.11)),!
130 ;
131 ; .12 DATE/TIME DEACTIVATED
132 W $J("Date/Time Deactivated: ",40),$G(A(FILENO1,IENS1,.12)),!
133 ;
134 ; .02 NATIONAL ACTIVE
135 W $J("National Active? ",40),$G(A(FILENO1,IENS1,.02)),!
136 ;
137 ; .06 DATE/TIME NATIONAL EDITED
138 W $J("Date/Time National Edited: ",40),$G(A(FILENO1,IENS1,.06)),!
139 ;
140 ; .03 LOCAL ACTIVE
141 W $J("Local Active? ",40),$G(A(FILENO1,IENS1,.03)),!
142 ;
143 ; .05 DATE/TIME LOCAL EDITED
144 W $J("Date/Time Local Edited: ",40),$G(A(FILENO1,IENS1,.05)),!
145 ;
146 ; .04 USER EDITED LOCAL
147 W $J("User Edited Local: ",40),$G(A(FILENO1,IENS1,.04)),!
148 Q
Note: See TracBrowser for help on using the repository browser.