source: WorldVistAEHR/trunk/r/KERNEL-XU-A4A7-USC-XG-XLF-XNOA-XPD-XQ-XVIR-ZI-ZOSF-ZOSV-ZT-ZU-%Z-XIP--XQAB--XUC--XUR--ZIN--ZTED/XUSNPIX3.m@ 613

Last change on this file since 613 was 613, checked in by George Lilly, 14 years ago

initial load of WorldVistAEHR
File size: 4.2 KB
Line 
1XUSNPIX3 ;OAK_BP/CMW - NPI EXTRACT REPORT ;01-OCT-06
2 ;;8.0;KERNEL;**438,452,453,481**; Jul 10, 1995;Build 21
3 ;;Per VHA Directive 2004-038, this routine should not be modified.
4 ;
5 ; NPI Extract Report
6 ;
7 ; Input parameter: N/A
8 ;
9 ; Other relevant variables:
10 ; XUSRTN="XUSNPIX1NV" (current routine name, used for ^XTMP and ^TMP
11 ; XUSRTN="XUSNPIX2NV" storage subscript)
12 ; Storage Global:
13 ; ^XTMP("XUSNPIX1VA",0) = Piece 1^Piece 2^Piece 3^Piece 4^Piece 5^Piece 6
14 ; ^XTMP("XUSNPIX2VA",0)
15 ; where:
16 ; Piece 1 => Purge Date - 1 year in future
17 ; Piece 2 => Create Date - Today
18 ; Piece 3 => Description
19 ; Piece 4 => Last Date Compiled
20 ; Piece 5 => $H last run start time
21 ; Piece 6 => $H last run completion time
22 ;
23 ; Entry Point - ENT called from XUSNPIX1
24 ;
25 Q
26 ;
27ENT(XUSPROD,XUSVER) ; ENTRY POINT
28 ; init variables
29 N XUSRTN,XUSEOL,DTTM3
30 N XUSNPI,XUSDATA,XUSTYP,XUST
31 N NVIEN,IBA0,PROTYPE,NPIDT,NPINEW
32 K ^TMP("XUSNPI",$J)
33 ;
34 ; Set end of line character
35 S XUSEOL="~~"
36 ;
37 S DTTM3=$$HTE^XLFDT($H,"2")
38 ;
39 S XUST=""
40 ; Loop through IB NON/OTHER VA BILLING PROVIDER records NPI xref
41 S XUSNPI=0
42 F S XUSNPI=$O(^IBA(355.93,"NPI",XUSNPI)) Q:'XUSNPI D
43 . S NVIEN=$O(^IBA(355.93,"NPI",XUSNPI,""))
44 . S IBA0=$G(^IBA(355.93,NVIEN,0))
45 . ; Get Provider Type
46 . S PROTYPE=$P(IBA0,U,2)
47 . S XUSTYP=$S(PROTYPE=1:2,1:1)
48 . ; setup NPI array
49 . S ^TMP("XUSNPI",$J,XUSTYP,XUSNPI)=NVIEN
50 . ;
51 ; If Provider Type is Individual
52 S XUSRTN="XUSNPIX1NV",NVHEADR=" NPI EXTRACT TYPE 1 (NON VA)",NVTYPE="TYPE 1 (NVA)"
53 I $D(^TMP("XUSNPI",$J,1)) D I XUST G EXIT
54 . ; Check to see if report is in use
55 . L +^XTMP(XUSRTN):5 I '$T S XUST=1 Q
56 . D INIT(XUSRTN)
57 . D INST(XUSRTN)
58 . D TYPE1^XUSNPIX4(DTTM3,PTPMAIL,SITE,XUSPROD,XUSHDR)
59 . ;
60 . ; Log Run Completion Time
61 . S $P(^XTMP(XUSRTN,0),U,6)=$H
62 . L -^XTMP(XUSRTN)
63 ;
64 I '$D(^TMP("XUSNPI",$J,1)) D
65 . D INIT(XUSRTN)
66 . D INST(XUSRTN)
67 . S ^TMP(XUSRTN,$J,1)=XUSHDR_U_"Message Number: "_1_U_"Line Count: "_1_U_DTTM3_U_$G(XUSPROD)_XUSEOL
68 . S ^XTMP("XUSNPIXT","1NV")=1_U_0_U_DTTM3
69 . S ^TMP(XUSRTN,$J,2)="END OF FILE"_U_XUSEOL
70 . D EMAIL(XUSRTN)
71 . S ^TMP("XUSNPIXS",$J,3,1)="1 (Non-VA)^0"
72 ;
73 ; If Provider Type is Facility/Group
74 S XUSRTN="XUSNPIX2NV",NVHEADR=" NPI EXTRACT TYPE 2 (NON VA)",NVTYPE="TYPE 2 (NVA)"
75 I $D(^TMP("XUSNPI",$J,2)) D I XUST G EXIT
76 . ; Check to see if report is in use
77 . L +^XTMP(XUSRTN):5 I '$T S XUST=1 Q
78 . D INIT(XUSRTN)
79 . D INST(XUSRTN)
80 . D TYPE2^XUSNPIX4(DTTM3,PTPMAIL,SITE,XUSPROD,XUSHDR)
81 . ;
82 . ; Log Run Completion Time
83 . S $P(^XTMP(XUSRTN,0),U,6)=$H
84 . L -^XTMP(XUSRTN)
85 . ;
86 I '$D(^TMP("XUSNPI",$J,2)) D
87 . D INIT(XUSRTN)
88 . D INST(XUSRTN)
89 . S ^TMP(XUSRTN,$J,1)=XUSHDR_U_"Message Number: "_1_U_"Line Count: "_1_U_DTTM3_U_$G(XUSPROD)_XUSEOL
90 . S ^XTMP("XUSNPIXT","2NV")=1_U_0_U_DTTM3
91 . S ^TMP(XUSRTN,$J,2)="END OF FILE"_U_XUSEOL
92 . D EMAIL(XUSRTN)
93 . S ^TMP("XUSNPIXS",$J,4,1)="2 (Non-VA)^0"
94 ;
95EXIT ;Standard EXIT point
96 K ^TMP("XUSNPI",$J)
97 K XUSNV,P,LDTCMP,PTPMAIL,SITE,NVHEADR,NVTYPE,XUSEOL,DTTM3
98 K XUSHDR
99 ;
100 Q
101 ;
102INIT(XUSRTN) ; check/init variables
103 N XUSDESC
104 ;
105 ;Reset Temporary Scratch Global
106 K ^TMP(XUSRTN)
107 S XUSDESC="NPI EXTRACT NON VA - Do Not Delete"
108 S ^XTMP(XUSRTN,0)=(DT+10000)_U_DT_U_XUSDESC_U_DT_U_$H
109 ;
110 I '$D(^TMP("XUSNPIXU",$J)) D BCBSID^XUSNPIXU
111 Q
112 ;
113INST(XUSRTN) ;Pull station and Institution info
114 N INST,SINFO,DIC4
115 ; Pull site info
116 S SINFO=$$SITE^VASITE
117 ; Station Number
118 S SITE=$P(SINFO,U,3)
119 ; Institution
120 S INST=$P(SINFO,U)
121 ;
122 ; Get institution mailing address
123 I INST D
124 . S DIC4=$G(^DIC(4,INST,4))
125 . S XUSNV(7)=$P(DIC4,U)
126 . S XUSNV(8)=$P(DIC4,U,2)
127 . S XUSNV(9)=$P(DIC4,U,3)
128 . S XUSNV(10)=$P(DIC4,U,4)
129 . I XUSNV(10) S XUSNV(10)=$P($G(^DIC(5,XUSNV(10),0)),U,2)
130 . S XUSNV(11)=$P(DIC4,U,5)
131 . S PTPMAIL=XUSNV(7)_U_XUSNV(8)_U_XUSNV(9)_U_XUSNV(10)_U_XUSNV(11)
132 S XUSHDR="Station: "_SITE_U_XUSNV(9)_U_XUSNV(10)_U_XUSNV(11)_U_NVTYPE_U_XUSVER
133 Q
134 ;
135EMAIL(XUSRTN) ; EMAIL THE MESSAGE
136 N XMY
137 ; Send email to designated recipient for live release
138 S XMY("XXX@Q-NPS.VA.GOV")=""
139 D ESEND
140 Q
141 ;
142ESEND N XMTEXT,XMSUB,XMDUN,XMDUZ,XMZ,XMMG,DIFROM
143 S XMTEXT="^TMP("""_XUSRTN_""","_$J_","
144 S XMSUB=$TR($P($G(^TMP(XUSRTN,$J,1)),U),":")_"("_$G(XUSPROD)_") "_NVHEADR
145 D ^XMD
146 Q
Note: See TracBrowser for help on using the repository browser.