source: WorldVistAEHR/trunk/r/LEXICON_UTILITY-LEX-GMPT/LEX2030P.m@ 1005

Last change on this file since 1005 was 613, checked in by George Lilly, 15 years ago

initial load of WorldVistAEHR
File size: 4.3 KB
Line 
1LEX2030P ;ISA/FJF-Pre/Post Install; 08/04/2004
2 ;;2.0;LEXICON UTILITY;**30**;Sep 23, 1996
3 ;
4 ; External References
5 ; DBIA 10086 HOME^%ZIS
6 ; DBIA 2052 $$GET1^DID
7 ; DBIA 2055 PRD^DILFD
8 ; DBIA 10014 EN^DIU2
9 ; DBIA 10141 BMES^XPDUTL
10 ; DBIA 10141 MES^XPDUTL
11 ;
12 Q
13 ;
14POST ; LEX*2.0*30 Post-Install
15 N LEXEDT,LEXCHG,LEXSCHG S LEXEDT=$G(^LEXM(0,"CREATED"))
16 S LEXCHG=0 S:$D(^LEXM(80))!($D(^LEXM(80.1)))!($D(^LEXM(81)))!($D(^LEXM(81.2)))!($D(^LEXM(81.3))) LEXCHG=1
17 ; Save Changes
18 D SCHG
19 ; Load Data into Files
20 D LOAD
21 ; Re-Index Files
22 D RX
23 ; Notify Applications that a Change has occurred
24 D NOTIFY^LEXXGI
25 ; Send a Install Message
26 D MSG
27 ; Clean up and Quit
28 D KLEXM
29 Q
30 ;
31LOAD ; Load Data from ^LEXM into IC*/LEX Files
32 N LEXB,LEXBUILD,LEXCD,LEXIGHF,LEXLAST,LEXLREV D IMP^LEX2030
33 S U="^",LEXB=$G(^LEXM(0,"BUILD")) Q:LEXB="" Q:LEXBUILD=""
34 S LEXCD=0 S LEXCD=+($$CPD^LEX2030)
35 I LEXCD,LEXB=LEXBUILD D G LQ
36 . S X="Data for patch "_LEXBUILD_" has already been installed"
37 . W:'$D(XPDNM) !!,X D:$D(XPDNM) BMES^XPDUTL(X)
38 . S X="" W:'$D(XPDNM) ! D:$D(XPDNM) MES^XPDUTL(X)
39 D:'LEXCD&(LEXB=LEXBUILD) EN^LEXXGI
40LQ ; Load Quit
41 D KLEXM
42 Q
43 ;
44MSG ; Send Installation Message to G.LEXICON
45 Q:+($G(DUZ))=0!($$NOTDEF^LEX2030($G(DUZ)))
46 D HOME^%ZIS N DIFROM,LEXLREV,LEXLAST,LEXBUILD,LEXIGHF
47 D IMP^LEX2030,SEND^LEXXST Q
48 ;
49SCHG ; Save Change File Changes
50 D MES^XPDUTL(" Updating Change File")
51 N LEXI,LEXFI,LEXFIL S LEXFI=0 F S LEXFI=$O(^LEXM(LEXFI)) Q:+LEXFI=0 D
52 . S LEXI=0 F S LEXI=$O(^LEXM(LEXFI,LEXI)) Q:+LEXI=0 D
53 . . N LEXCF,LEXIEN S LEXMUMPS=$G(^LEXM(LEXFI,LEXI)),LEXRT=$P(LEXMUMPS,"^",2)
54 . . S:LEXMUMPS["^LEX("!(LEXMUMPS["^LEXT(")!(LEXMUMPS["^LEXC(") LEXFIL=+($P(LEXRT,"(",2))
55 . . S:LEXMUMPS["^ICD9(" LEXFIL=80 S:LEXMUMPS["^ICD0(" LEXFIL=80.1 S:LEXMUMPS["^ICPT(" LEXFIL=81 S:LEXMUMPS["^DIC(81.3" LEXFIL=81.3
56 . . S:+LEXFIL>0 LEXSCHG(+LEXFIL,0)="" S LEXCF=+($P(LEXMUMPS,"LEXC(757.9,""AFIL"",",2))
57 . . S:$P(LEXCF,".",1)'="757"&("^80^80.1^81^81.3^"'[("^"_LEXCF_"^")) LEXCF=""
58 . . S LEXIEN=+($P(LEXMUMPS,("LEXC(757.9,""AFIL"","_+LEXCF_","),2))
59 . . I +LEXIEN>0&(+LEXCF)>0&("^80^80.1^81^81.3)"[LEXCF)&(+LEXFIL=757.9)&(LEXMUMPS["LEXC(757.9") D
60 . . . S LEXSCHG(+LEXFIL,LEXIEN)=LEXCF,LEXSCHG(757.9,"B",+LEXCF,LEXIEN)=""
61 . . S:$L(LEXMUMPS)&($L(LEXCF)) LEXCHGS(LEXCF)=""
62 Q
63 ;
64KLEXM ; Subscripted Kill of ^LEXM
65 N DA S DA=0 F S DA=$O(^LEXM(DA)) Q:+DA=0 K ^LEXM(DA)
66 K ^LEXM(0)
67 Q
68 ;
69PRE ; LEX*2.0*30 Pre-Install (N/A for patch 30)
70 Q
71 ;
72RX ; Reindex files 80, 80.1, 80.2, 81 and 81.3
73 N LEX,DA,DIK,TH,TM,TD
74 D BMES^XPDUTL(" Re-indexing NEW Versioned Text Cross-References")
75 ;
76 D BMES^XPDUTL(" ICD-9 Diagnosis file #80") W !," "
77 S (LEX,DA)=0 F S DA=$O(^ICD9(DA)) Q:+DA=0 K ^ICD9(DA,66,"B"),^ICD9(DA,67,"B"),^ICD9(DA,68,"B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
78 K ^ICD9("AB"),^ICD9("ACC"),^ICD9("ACT"),^ICD9("BA"),^ICD9("D"),^ICD9("AST"),^ICD9("ADS") S DIK="^ICD9(" D IXALL^DIK
79 ;
80 D MES^XPDUTL(" ICD-9 Operations/Procedure file #80.1") W !," "
81 S (LEX,DA)=0 F S DA=$O(^ICD0(DA)) Q:+DA=0 K ^ICD0(DA,66,"B"),^ICD0(DA,67,"B"),^ICD0(DA,68,"B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
82 K ^ICD0("AB"),^ICD0("ACT"),^ICD0("ADS"),^ICD0("AST"),^ICD0("BA"),^ICD0("D"),^ICD0("E") S DIK="^ICD0(" D IXALL^DIK
83 ;
84 D MES^XPDUTL(" DRG file #80.2") W !," "
85 S (LEX,DA)=0 F S DA=$O(^ICD(DA)) Q:+DA=0 K ^ICD(DA,1,"B"),^ICD(DA,66,"B"),^ICD(DA,68,"B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
86 K ^ICD("ADS"),^ICD("B") S DIK="^ICD(" D IXALL^DIK
87 ;
88 D MES^XPDUTL(" CPT/HCPCS Procedure/Services file #81") W !," "
89 S (LEX,DA)=0 F S DA=$O(^ICPT(DA)) Q:+DA=0 D
90 . K ^ICPT(DA,60,"B"),^ICPT(DA,61,"B"),^ICPT(DA,62,"B"),^ICPT(DA,"D","B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
91 K ^ICPT("ACT"),^ICPT("ADS"),^ICPT("AST"),^ICPT("B"),^ICPT("BA"),^ICPT("C"),^ICPT("D"),^ICPT("E"),^ICPT("F") S DIK="^ICPT(" D IXALL^DIK
92 ;
93 D MES^XPDUTL(" CPT Modifier file #81.3") W !," "
94 S (LEX,DA)=0 F S DA=$O(^DIC(81.3,DA)) Q:+DA=0 D
95 . K ^DIC(81.3,DA,60,"B"),^DIC(81.3,DA,61,"B"),^DIC(81.3,DA,62,"B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
96 K ^DIC(81.3,"ACT"),^DIC(81.3,"ADS"),^DIC(81.3,"AST"),^DIC(81.3,"B"),^DIC(81.3,"BA"),^DIC(81.3,"C"),^DIC(81.3,"D"),^DIC(81.3,"M") S DIK="^DIC(81.3," D IXALL^DIK
97 Q
98 ;
99CON ; Conversion of data (N/A for patch 30)
100 Q
Note: See TracBrowser for help on using the repository browser.