source: WorldVistAEHR/trunk/r/LEXICON_UTILITY-LEX-GMPT/LEX2033.m@ 1361

Last change on this file since 1361 was 613, checked in by George Lilly, 15 years ago

initial load of WorldVistAEHR
File size: 9.4 KB
RevLine 
[613]1LEX2033 ;ISL/KER - Environment Check/Pre/Post Install ; 10/01/2004
2 ;;2.0;LEXICON UTILITY;**33**;Sep 23, 1996
3 ;
4 ; External References
5 ; DBIA 10015 EN^DIQ1
6 ; DBIA 10141 $$PATCH^XPDUTL
7 ; DBIA 10141 $$VERSION^XPDUTL
8 ; DBIA 10141 BMES^XPDUTL
9 ; DBIA 10141 MES^XPDUTL
10 ;
11ENV ; LEX*2.0*33 Environment Check
12 ;
13 ; General
14 ;
15 N LEXBUILD,LEXIGHF,LEXREQP,LEXLREV,LEXG,LEXE
16 W !," Code Set Quarterly Update w/FY 2005 DRG Grouper Changes",!
17 D IMP S U="^"
18 ; No user
19 D:+($$UR)'>0 ET("User not defined (DUZ)")
20 ; No IO
21 D:+($$SY)'>0 ET("Undefined IO variable(s)") I $D(LEXE) D ABRT Q
22 ;
23 ; Load Distribution
24 ;
25 ; XPDENV = 0 Environment Check during Load
26 ;
27 ; Check Version (2.0)
28 I $$VERSION^XPDUTL("LEX")'="2.0" D D ABRT Q
29 . D ET("Version 2.0 not found. Please install Lexicon Utility v 2.0")
30 ;
31 ; Check Required Patches
32 D:'$L($G(LEXREQP)) IMP I $L(LEXREQP) D
33 . N LEXPAT,LEXI,LEXPN
34 . F LEXI=1:1 Q:'$L($P(LEXREQP,";",LEXI)) S LEXPAT=$P(LEXREQP,";",LEXI) D
35 . . S LEXPN=$$PATCH^XPDUTL(LEXPAT) W !," Checking for ",LEXPAT I +LEXPN>0 H 1 W " - installed"
36 . . I +LEXPN'>0 D ET((LEXPAT_" not found, please install "_LEXPAT_" before continuing"))
37 I $D(LEXE) D ABRT Q
38 S LEXG=$$RGBL
39 I $D(LEXE)&(+LEXG=0) D ABRT Q
40 I $D(LEXE)&(+LEXG<0) D ABRT Q
41 I '$D(LEXFULL)&(+($G(XPDENV))'=1) D QUIT Q
42 ;
43 ; Install Package(s)
44 ;
45 ; XPDENV = 1 Environment Check during Install
46 ;
47 ; Check Data "is installed" or "is translated"
48 N LEXIT S LEXIT=+($$CPD) I '$D(LEXFULL)&(LEXIT) D QUIT Q
49 ; Checking Global "Write" Protection
50 D:+($G(XPDENV))=1 GBLS I $D(LEXE) D ABRT Q
51 ; Check Import Global Checksum
52 D:+($G(XPDENV))=1 CS I $D(LEXE) D ABRT Q
53 ;
54 ; Quit, Exit or Abort
55 ;
56QUIT ; Quit Passed Environment Check
57 K LEXFULL D OK
58 Q
59EXIT ; Exit Failed Environment Check
60 D:$D(LEXE) ED S XPDQUIT=2 K LEXE,LEXFULL Q
61ABRT ; Abort Failed Environment Check, KILL the distribution
62 D:$D(LEXE) ED S XPDABORT=1,XPDQUIT=1,XPDQUIT("LEX*2.0*33")=1
63 S XPDQUIT("ICD*18.0*12")=1,XPDQUIT("ICPT*6.0*19")=1
64 S XPDQUIT("CTD UTIL 1.0")=1 K LEXE,LEXFULL
65 Q
66 ;
67 ; Checks
68 ;
69GBLS ; Check Write access on globals
70 N LEXE,LEXGBL,LEXRT,LEXT,LEXF,LEXI,LEXX,LEXOK,LEXCPD,LEXS,X S LEXOK=1
71 D BM(" I will now check the protection on ^ICD9, ^ICD0, and ^ICD Globals.")
72 D M(" If you get an ERROR, you will need to change the protection on these")
73 D M(" globals to allow read/write as indicated for the appropriate M system:")
74 D BM(" System World Group UCI")
75 D M(" DSM for OpenVMS RWP RW RW RW")
76 ; D BM(" System World Group User")
77 ; D M(" MSM-DOS RWD RWD RWD RWD")
78 D BM(" Owner Group World Network")
79 D M(" Cache systems RWD RW RW RWD")
80 D BM(" Checking:"),M(" ")
81 S LEXCPD=$$CPD,LEXS="",X=1 F LEXI=1:1 D Q:'$L(LEXX)
82 . S LEXX="" S LEXE="S LEXX=$T(GD+"_LEXI_")" X LEXE S LEXX=$$TRIM(LEXX) Q:'$L(LEXX) Q:'$L($TR(LEXX,";",""))
83 . S LEXGBL=$P(LEXX,";",3) Q:+LEXCPD>0&(LEXGBL="^LEXM(0)") S LEXRT=$P(LEXX,";",4),LEXT=$P(LEXX,";",5),LEXF=$P(LEXX,";",6)
84 . S (LEXB1,LEXB2)="",$P(LEXB1," ",(19-$L(LEXRT)))="",$P(LEXB2," ",(28-$L(LEXT)))=""
85 . I '$D(@LEXGBL) D RGNF S LEXOK=0 D M((" <"_LEXRT_" not found>")) Q
86 . D M((" "_LEXRT_LEXB1_LEXT_LEXB2_LEXF)) S @LEXGBL=$G(@LEXGBL) H 1
87 D:LEXOK M(" --> ok") D:'LEXOK M(" ??") D M(" ")
88 Q
89RGBL(X) ; Check Write access on globals
90 N LEXCPD,LEXS,LEXI,LEXX,LEXEC,LEXGBL,LEXRT,LEXT,LEXF,LEXB1,LEXB2
91 S LEXCPD=$$CPD,LEXS="",X=1 F LEXI=1:1 D Q:'$L(LEXX)
92 . S LEXX="" S LEXEC="S LEXX=$T(GD+"_LEXI_")" X LEXEC S LEXX=$$TRIM(LEXX) Q:'$L(LEXX) Q:'$L($TR(LEXX,";",""))
93 . S LEXGBL=$P(LEXX,";",3) Q:+LEXCPD>0&(LEXGBL="^LEXM(0)") S LEXRT=$P(LEXX,";",4),LEXT=$P(LEXX,";",5),LEXF=$P(LEXX,";",6)
94 . S (LEXB1,LEXB2)="",$P(LEXB1," ",(15-$L(LEXRT)))="",$P(LEXB2," ",(28-$L(LEXT)))=""
95 . I '$D(@LEXGBL) S:LEXS'[LEXRT LEXS=LEXS_", "_LEXRT S X=-1 S:LEXGBL["LEXM("&(X=1) X=0
96 I $L(LEXS),X'>0 D
97 . S:LEXS[", " LEXS=$P(LEXS,", ",1,($L(LEXS,", ")-1))_" and "_$P(LEXS,", ",$L(LEXS,", "))
98 . S:$E(LEXS,1,2)=", " LEXS=$E(LEXS,3,$L(LEXS)) S:$E(LEXS,1,7)[" and " LEXS=$P(LEXS," and ",2)
99 . D:X=-1 ET(("Global"_$S(LEXS[", "!(LEXS[" and "):"s",1:"")_" "_LEXS_" either not found or incomplete."))
100 . D:X=0 CM
101 Q X
102RGNF ; Required global not found
103 N LEXLREV,LEXREQP,LEXBUILD,LEXIGHF D IMP
104 D:$G(LEXGL)["^LEX"&($G(LEXGL)'["^LEXM") ET(""),ET("Required global "_$P($G(LEXGL),"(",1)_" not found.")
105 D:$G(LEXGL)["^LEX"&($G(LEXGL)["^LEXM") CM
106 Q
107CHK ; Check the Checksum
108 D CS I $D(LEXE) D ED Q
109 D BM(" OK"),M(" ")
110 Q
111CS ; Checksum for import global
112 K LEXE
113 D BM(" Running checksum routine on the ^LEXM import global, please wait")
114 N LEXCHK,LEXNDS,LEXVER S LEXCHK=+($G(^LEXM(0,"CHECKSUM")))
115 S LEXNDS=+($G(^LEXM(0,"NODES"))),LEXVER=+($$VC(LEXCHK,LEXNDS))
116 D M(" ") D:LEXVER>0 M(" Checksum is ok"),M(" ")
117 D:LEXVER=0 CM D:LEXVER=-1 CW D:LEXVER=-2 CU D:LEXVER=-3 CF
118 Q
119VC(X,Y) ; Verify Checksum for import global
120 N LEXLREV,LEXREQP,LEXBUILD,LEXIGHF Q:'$D(^LEXM) 0
121 D IMP I $G(^LEXM(0,"BUILD"))'=$G(LEXBUILD) Q -1
122 N LEXCHK,LEXNDS,LEXCNT,LEXLC,LEXL,LEXS,LEXNC,LEXD,LEXN,LEXC,LEXGCS,LEXP,LEXT
123 S LEXCHK=+($G(X)),LEXNDS=+($G(Y))
124 Q:LEXCHK'>0!(LEXNDS'>0) -2
125 S LEXL=64,(LEXCNT,LEXLC)=0,LEXS=(+(LEXNDS\LEXL))
126 S:LEXS=0 LEXS=1 D:+($O(^LEXM(0)))>0 M("")
127 S (LEXC,LEXN)="^LEXM",(LEXNC,LEXGCS)=0 W " "
128 F S LEXN=$Q(@LEXN) Q:LEXN=""!(LEXN'[LEXC) D
129 . Q:LEXN="^LEXM(0,""CHECKSUM"")"
130 . Q:LEXN="^LEXM(0,""NODES"")"
131 . S LEXCNT=LEXCNT+1
132 . I LEXCNT'<LEXS S LEXLC=LEXLC+1 W:LEXLC'>LEXL "." S LEXCNT=0
133 . S LEXNC=LEXNC+1,LEXD=@LEXN,LEXT=LEXN_"="_LEXD
134 . F LEXP=1:1:$L(LEXT) S LEXGCS=$A(LEXT,LEXP)*LEXP+LEXGCS
135 Q:LEXNC'=LEXNDS -3
136 Q:LEXGCS'=LEXCHK -3
137 Q 1
138SY(X) ; Check System variables
139 Q:'$D(IO)!('$D(IOF))!('$D(IOM))!('$D(ION))!('$D(IOSL))!('$D(IOST)) 0
140 Q 1
141UR(X) ; Check User variables
142 Q:'$L($G(DUZ(0))) 0
143 Q:+($G(DUZ))=0!($$NOTDEF(+$G(DUZ))) 0
144 Q 1
145CPD(X) ; Check Current Patched Data is installed
146 N INS S INS=1
147 ; Check Last ICD Diagnosis Set/Kill
148 S:'$D(^ICD9("ACC",14048,14048)) INS=0
149 S:$D(^ICD9("ACC",11553,11553)) INS=0
150 ; Check Last ICD Procedures Set
151 S:'$D(^ICD0(4263,"M")) INS=0
152 ; Check Last DRG Grouper Set/Kill
153 S:'$D(^ICD("B","DRG543",543)) INS=0
154 S:$D(^ICD(540,1,"B","LYMPHOMA AND LEUKEMIA W MAJOR ",1)) INS=0
155 ; Check ICD0 update V2
156 S:$G(^ICD0(4213,0))["^OpP^" INS=0
157 ; Check ICD9 update V4
158 S:$G(^ICD9(14004,0))'="707.07^U^DECUBITUS ULCER,HEEL^^9^^^^^^^^^15^99^3041001" INS=0
159 ; Check ICD9 update V5
160 S:$G(^ICD9(14000,3,1,1,0))="^80.711P^3^3" INS=0
161 S:$G(^ICD9(14000,3,1,1,0))'="^80.711P^3^1" INS=0
162 ; Check ICD9 update V6
163 S:$G(^ICD9(13638,3,0))'="^80.071D^1^1" INS=0
164 S X=+($G(INS))
165 Q X
166 ;
167 ; Error messages
168 ;
169CM ; Missing ^LEXM
170 N LEXLREV,LEXREQP,LEXBUILD,LEXIGHF D IMP
171 D ET(""),ET("Missing import global ^LEXM.") D CO
172 Q
173CW ; Wrong ^LEXM
174 N LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXB D IMP
175 S LEXB=$G(^LEXM(0,"BUILD")) D ET("")
176 I $L(LEXBUILD),$L(LEXB),LEXBUILD'=LEXB D Q
177 . D ET(("Incorrect import global ^LEXM found ("_LEXB_" global)."))
178 . D CKO
179 D ET("Incorrect import global ^LEXM found.") D CKO
180 Q
181CU ; Unable to verify
182 N LEXLREV,LEXREQP,LEXBUILD,LEXIGHF D IMP
183 D ET(""),ET("Unable to verify checksum for import global ^LEXM (possibly corrupt).") D CKO
184 Q
185CF ; Failed checksum
186 N LEXLREV,LEXREQP,LEXBUILD,LEXIGHF D IMP D ET("")
187 D ET("Import global ^LEXM failed checksum.") D CKO
188 Q
189CO ; Obtain new global
190 N LEXLREV,LEXREQP,LEXBUILD,LEXIGHF D IMP
191 D ET(""),ET(" Please obtain a copy of the import global ^LEXM contained in the ")
192 D ET((" global host file "_LEXIGHF_" before continuing with the "_LEXBUILD))
193 D ET((" installation."))
194 Q
195CKO ; Kill and Obtain new global
196 N LEXLREV,LEXREQP,LEXBUILD,LEXIGHF D IMP
197 D ET(""),ET(" Please KILL the existing import global ^LEXM from your system")
198 D ET((" and obtain a new copy of ^LEXM contained in the global host file"))
199 D ET((" "_LEXIGHF_" before continuing with the "_LEXBUILD_" installation."))
200 Q
201ET(X) ; Error Text
202 N LEXI S LEXI=+($G(LEXE(0))),LEXI=LEXI+1,LEXE(LEXI)=" "_$G(X),LEXE(0)=LEXI
203 Q
204ED ; Error Display
205 N LEXI S LEXI=0 F S LEXI=$O(LEXE(LEXI)) Q:+LEXI=0 D M(LEXE(LEXI))
206 D M(" ") K LEXE Q
207 ;
208 ; Miscellaneous
209 ;
210IMP ; Import names
211 S LEXLREV=33,LEXREQP="ICD*18.0*12;LEX*2.0*31",LEXBUILD="LEX*2.0*33"
212 S LEXIGHF="LEX_2_33.GBL"
213 Q
214NOTDEF(IEN) ; Check to see if user is defined
215 N DA,DR,DIQ,LEX,DIC S DA=IEN,DR=.01,DIC=200,DIQ="LEX" D EN^DIQ1 Q '$D(LEX)
216OK ; Environment is OK
217 N LEXBUILD,LEXIGHF,LEXREQP,LEXLREV,LEXT
218 D IMP S LEXT=" Environment "_$S($L(LEXBUILD):("for patch/build "_LEXBUILD_" "),1:"")_"is ok"
219 D BM(LEXT),M(" ")
220 Q
221BM(X) ; Blank Line with Message
222 D BMES^XPDUTL($G(X)) Q
223M(X) ; Message
224 D MES^XPDUTL($G(X)) Q
225TRIM(X) ; Trim Spaces
226 S X=$G(X) F Q:$E(X,1)'=" " S X=$E(X,2,$L(X))
227 F Q:$E(X,$L(X))'=" " S X=$E(X,1,($L(X)-1))
228 Q X
229 ;;^LEX(757.01);^LEX(*;Lexicon;757-757.41
230 ;;^LEXT(757.2);^LEXT(757.2);Lexicon Subsets/Defaults;757.2
231 ;;^LEXC(757.9);^LEXC(*;Lexicon Change File;757.9-757.91
232 ;;^LEXM(0);^LEXM(*;Lexicon Export/Import;No File #
233 ;;^ICPT(0);^ICPT(;CPT/HCPCS;81
234 ;;^DIC(81.1,0);^DIC(81.1);CPT Category;81.1
235 ;;^DIC(81.2,0);^DIC(81.2);CPT Copyright;81.2
236 ;;^DIC(81.3,0);^DIC(81.3);CPT Modifier;81.3
237 Q
238GD ; Global Data
239 ;;^ICD9(0);^ICD9(;ICD Diagnosis;80
240 ;;^ICD0(0);^ICD0(;ICD Operation/Procedure;80.1
241 ;;^ICD(0);^ICD(;DRG Grouper;80.2
Note: See TracBrowser for help on using the repository browser.