source: WorldVistAEHR/trunk/r/LEXICON_UTILITY-LEX-GMPT/LEX2043P.m@ 1753

Last change on this file since 1753 was 613, checked in by George Lilly, 15 years ago

initial load of WorldVistAEHR
File size: 4.7 KB
RevLine 
[613]1LEX2043P ; ISL/KER - Pre/Post Install ; 09/06/2006
2 ;;2.0;LEXICON UTILITY;**43**;Sep 23, 1996;Build 1
3 ;
4 ; External References
5 ; DBIA 10086 HOME^%ZIS
6 ; DBIA 2052 $$GET1^DID
7 ; DBIA 2055 PRD^DILFD
8 ; DBIA 10014 EN^DIU2
9 ; DBIA 10141 BMES^XPDUTL
10 ; DBIA 10141 MES^XPDUTL
11 ;
12 Q
13 ;
14POST ; LEX*2.0*43 Post-Install
15 N LEXEDT,LEXCHG,LEXSCHG S LEXEDT=$G(^LEXM(0,"CREATED"))
16 S LEXCHG=0 S:$D(^LEXM(80))!($D(^LEXM(80.1)))!($D(^LEXM(81)))!($D(^LEXM(81.2)))!($D(^LEXM(81.3))) LEXCHG=1
17 ;
18 ;-----------------------------
19 ; Save Changes
20 D SCHG
21 ;
22 ;-----------------------------
23 ; Load Data into Files
24 D LOAD
25 ;
26 ;-----------------------------
27 ; Data Conversion
28 D CON
29 ;
30 ;-----------------------------
31 ; Re-Index Files - N/A for LEX*2.0*43
32 ; Do not use for Annual/Quarterly Updates, it disrupts the Protocol
33 ; D RX
34 ;
35 ;-----------------------------
36 ; Fire Protocol
37 D NOTIFY^LEXXGI
38 ;
39 ;-----------------------------
40 ; Install Remedy Tickets
41 D ALL^LEX2043A
42 ;
43 ;-----------------------------
44 ; Send a Install Message
45 D MSG
46 ;
47 ;-----------------------------
48 ; Clean up and Quit
49 D KLEXM
50 Q
51 ;
52LOAD ; Load Data from ^LEXM into IC*/LEX Files
53 N LEXB,LEXBUILD,LEXCD,LEXIGHF,LEXLAST,LEXLREV D IMP^LEX2043
54 S U="^",LEXB=$G(^LEXM(0,"BUILD")) Q:LEXB="" Q:LEXBUILD=""
55 S LEXCD=0 S LEXCD=+($$CPD^LEX2043)
56 I LEXCD,LEXB=LEXBUILD D G LQ
57 . S X="Data for patch "_LEXBUILD_" has already been installed"
58 . W:'$D(XPDNM) !!,X D:$D(XPDNM) BMES^XPDUTL(X)
59 . S X="" W:'$D(XPDNM) ! D:$D(XPDNM) MES^XPDUTL(X)
60 D:'LEXCD&(LEXB=LEXBUILD) EN^LEXXGI
61LQ ; Load Quit
62 D KLEXM
63 Q
64 ;
65MSG ; Send Installation Message to G.LEXICON
66 Q:+($G(DUZ))=0!($$NOTDEF^LEX2043($G(DUZ)))
67 D HOME^%ZIS N DIFROM,LEXLREV,LEXLAST,LEXBUILD,LEXIGHF
68 D IMP^LEX2043,POST^LEXXFI Q
69 ;
70SCHG ; Save Change File Changes
71 N LEXI,LEXFI,LEXFIL S LEXFI=0 F S LEXFI=$O(^LEXM(LEXFI)) Q:+LEXFI=0 D
72 . S LEXI=0 F S LEXI=$O(^LEXM(LEXFI,LEXI)) Q:+LEXI=0 D
73 . . N LEXCF,LEXIEN S LEXMUMPS=$G(^LEXM(LEXFI,LEXI)),LEXRT=$P(LEXMUMPS,"^",2)
74 . . S:LEXMUMPS["^LEX("!(LEXMUMPS["^LEXT(")!(LEXMUMPS["^LEXC(") LEXFIL=+($P(LEXRT,"(",2))
75 . . S:LEXMUMPS["^ICD9(" LEXFIL=80 S:LEXMUMPS["^ICD0(" LEXFIL=80.1 S:LEXMUMPS["^ICPT(" LEXFIL=81 S:LEXMUMPS["^DIC(81.3" LEXFIL=81.3
76 . . S:+LEXFIL>0 LEXSCHG(+LEXFIL,0)="" S LEXCF=+($P(LEXMUMPS,"LEXC(757.9,""AFIL"",",2))
77 . . S:$P(LEXCF,".",1)'="757"&("^80^80.1^81^81.3^"'[("^"_LEXCF_"^")) LEXCF=""
78 . . S LEXIEN=+($P(LEXMUMPS,("LEXC(757.9,""AFIL"","_+LEXCF_","),2))
79 . . I +LEXIEN>0&(+LEXCF)>0&("^80^80.1^81^81.3)"[LEXCF)&(+LEXFIL=757.9)&(LEXMUMPS["LEXC(757.9") D
80 . . . S LEXSCHG(+LEXFIL,LEXIEN)=LEXCF,LEXSCHG(757.9,"B",+LEXCF,LEXIEN)=""
81 . . S:$L(LEXMUMPS)&($L(LEXCF)) LEXCHGS(LEXCF)=""
82 Q
83 ;
84KLEXM ; Subscripted Kill of ^LEXM
85 N DA S DA=0 F S DA=$O(^LEXM(DA)) Q:+DA=0 K ^LEXM(DA)
86 K ^LEXM(0)
87 Q
88 ;
89PRE ; LEX*2.0*40 Pre-Install (N/A for patch 40)
90 Q
91 ;
92RX ; Reindex files (N/A for patch 40)
93 Q
94 N LEX,DA,DIK,TH,TM,TD
95 D BMES^XPDUTL(" Re-indexing NEW Versioned Text Cross-References")
96 ;
97 D BMES^XPDUTL(" ICD-9 Diagnosis file #80") W !," "
98 S (LEX,DA)=0 F S DA=$O(^ICD9(DA)) Q:+DA=0 K ^ICD9(DA,66,"B"),^ICD9(DA,67,"B"),^ICD9(DA,68,"B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
99 K ^ICD9("AB"),^ICD9("ACC"),^ICD9("ACT"),^ICD9("BA"),^ICD9("D"),^ICD9("AST"),^ICD9("ADS") S DIK="^ICD9(" D IXALL^DIK
100 ;
101 D MES^XPDUTL(" ICD-9 Operations/Procedure file #80.1") W !," "
102 S (LEX,DA)=0 F S DA=$O(^ICD0(DA)) Q:+DA=0 K ^ICD0(DA,66,"B"),^ICD0(DA,67,"B"),^ICD0(DA,68,"B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
103 K ^ICD0("AB"),^ICD0("ACT"),^ICD0("ADS"),^ICD0("AST"),^ICD0("BA"),^ICD0("D"),^ICD0("E") S DIK="^ICD0(" D IXALL^DIK
104 ;
105 D MES^XPDUTL(" DRG file #80.2") W !," "
106 S (LEX,DA)=0 F S DA=$O(^ICD(DA)) Q:+DA=0 K ^ICD(DA,1,"B"),^ICD(DA,66,"B"),^ICD(DA,68,"B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
107 K ^ICD("ADS"),^ICD("B") S DIK="^ICD(" D IXALL^DIK
108 ;
109 D MES^XPDUTL(" CPT/HCPCS Procedure/Services file #81") W !," "
110 S (LEX,DA)=0 F S DA=$O(^ICPT(DA)) Q:+DA=0 D
111 . K ^ICPT(DA,60,"B"),^ICPT(DA,61,"B"),^ICPT(DA,62,"B"),^ICPT(DA,"D","B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
112 K ^ICPT("ACT"),^ICPT("ADS"),^ICPT("AST"),^ICPT("B"),^ICPT("BA"),^ICPT("C"),^ICPT("D"),^ICPT("E"),^ICPT("F") S DIK="^ICPT(" D IXALL^DIK
113 ;
114 D MES^XPDUTL(" CPT Modifier file #81.3") W !," "
115 S (LEX,DA)=0 F S DA=$O(^DIC(81.3,DA)) Q:+DA=0 D
116 . K ^DIC(81.3,DA,60,"B"),^DIC(81.3,DA,61,"B"),^DIC(81.3,DA,62,"B") S LEX=+($G(LEX))+1 W:LEX#120=0 "."
117 K ^DIC(81.3,"ACT"),^DIC(81.3,"ADS"),^DIC(81.3,"AST"),^DIC(81.3,"B"),^DIC(81.3,"BA"),^DIC(81.3,"C"),^DIC(81.3,"D"),^DIC(81.3,"M") S DIK="^DIC(81.3," D IXALL^DIK
118 Q
119 ;
120CON ; Conversion of data (N/A for LEX2043)
121 Q
Note: See TracBrowser for help on using the repository browser.