| 1 | ORCXPND ; SLC/MKB - Expanded Display ;6/3/97 11:04
|
|---|
| 2 | ;;3.0;ORDER ENTRY/RESULTS REPORTING;;Dec 17, 1997
|
|---|
| 3 | RESULTS ; -- Results Display
|
|---|
| 4 | N ORESULTS S ORESULTS=1
|
|---|
| 5 | EN ; -- main entry point for OR DETAILED DISPLAY
|
|---|
| 6 | I '$G(ORNMBR) S ORNMBR=$$ORDERS^ORCHART("display") I 'ORNMBR S VALMBCK="" Q
|
|---|
| 7 | D EN^VALM("OR DETAILED DISPLAY") S VALMBCK="R"
|
|---|
| 8 | Q
|
|---|
| 9 | ;
|
|---|
| 10 | EN1(DFN,ID,ORTAB) ; -- entry point for independent display
|
|---|
| 11 | Q:'DFN Q:'$D(ID) S:'$D(ORTAB) ORTAB="ORDERS"
|
|---|
| 12 | N ORNMBR,ORVP,ORPNM,ORSSN,ORDOB,ORAGE,ORSEX,ORTS,ORWARD,ORATTEND,ORL,OREBUILD
|
|---|
| 13 | S ORNMBR=-1,^TMP("OR",$J,ORTAB,"IDX",ORNMBR)=ID D SLCT1^ORQPT
|
|---|
| 14 | D EN^VALM("OR DETAILED DISPLAY")
|
|---|
| 15 | Q
|
|---|
| 16 | ;
|
|---|
| 17 | INIT ; -- init variables and list array
|
|---|
| 18 | ; ORNMBR=#[,#,...,#] of selection[s]
|
|---|
| 19 | N LCNT,ORPIECE,NUM,ID S LCNT=0
|
|---|
| 20 | F ORPIECE=1:1:$L(ORNMBR,",") S NUM=$P(ORNMBR,",",ORPIECE) I NUM D:LCNT BORDER S ID=$P($G(^TMP("OR",$J,ORTAB,"IDX",NUM)),U) D @(ORTAB_"^ORCXPND1") ; create ^TMP("ORXPND",$J)
|
|---|
| 21 | S VALMCNT=LCNT,VALM("TITLE")=$$TITLE(ORTAB)
|
|---|
| 22 | M ^TMP("VALM VIDEO",$J,VALMEVL)=^TMP("ORXPND",$J,"VIDEO")
|
|---|
| 23 | Q
|
|---|
| 24 | ;
|
|---|
| 25 | BORDER ; -- Insert border between items
|
|---|
| 26 | S LCNT=LCNT+1,^TMP("ORXPND",$J,LCNT,0)=" "
|
|---|
| 27 | S LCNT=LCNT+1,^TMP("ORXPND",$J,LCNT,0)=$$REPEAT^XLFSTR("*",79)
|
|---|
| 28 | S LCNT=LCNT+1,^TMP("ORXPND",$J,LCNT,0)=" "
|
|---|
| 29 | Q
|
|---|
| 30 | ;
|
|---|
| 31 | MSG ; -- set msg line, XQORM("KEY")
|
|---|
| 32 | N ACTION S ACTION=$P($G(^TMP("ORXPND",$J,0)),U,2)
|
|---|
| 33 | I '$L(ACTION) S VALMSG="Enter ? for more help." Q
|
|---|
| 34 | I ACTION="NEW" S VALMSG="Enter NW to place another order.",XQORM("KEY","NW")=$O(^ORD(101,"B","ORCB NEW ORDER",0))_"^1"
|
|---|
| 35 | I ACTION="RENEW" S VALMSG="Enter RN to renew this order.",XQORM("KEY","RN")=$O(^ORD(101,"B","ORCB RENEW ORDER",0))_"^1"
|
|---|
| 36 | I ACTION="REPLACE" S VALMSG="Enter RP to replace this order.",XQORM("KEY","RP")=$O(^ORD(101,"B","ORCB REPLACE ORDER",0))_"^1"
|
|---|
| 37 | Q
|
|---|
| 38 | ;
|
|---|
| 39 | MARGIN ; -- Reset bottom margin if menu display off
|
|---|
| 40 | N BM S BM=$S(VALMMENU:17,1:21) Q:BM=VALM("BM") ; no change
|
|---|
| 41 | S VALM("BM")=BM,VALM("LINES")=VALM("BM")-VALM("TM")+1,VALMBCK="R"
|
|---|
| 42 | Q
|
|---|
| 43 | ;
|
|---|
| 44 | HELP ; -- help code
|
|---|
| 45 | N X S VALMBCK="" I 'VALMMENU D FULL^VALM1 S VALMBCK="R"
|
|---|
| 46 | W !!,"Use the actions listed to scroll up and down, to view the data; if you want",!,"to search the data for a particular string, enter SL. You may print the"
|
|---|
| 47 | W !,"data, either the entire list or just the current screen, by entering PL or PS",!,"respectively. Enter Q when finished to return to the chart."
|
|---|
| 48 | W !!,"Press <return> to continue ..." R X:DTIME
|
|---|
| 49 | Q
|
|---|
| 50 | ;
|
|---|
| 51 | EXIT ; -- exit code
|
|---|
| 52 | K ^TMP("ORXPND",$J)
|
|---|
| 53 | Q
|
|---|
| 54 | ;
|
|---|
| 55 | SETVIDEO(LINE,COL,WIDTH,ON,OFF) ; -- set video attributes
|
|---|
| 56 | S ^TMP("ORXPND",$J,"VIDEO",LINE,COL,WIDTH)=ON
|
|---|
| 57 | S ^TMP("ORXPND",$J,"VIDEO",LINE,COL+WIDTH,0)=OFF
|
|---|
| 58 | Q
|
|---|
| 59 | ;
|
|---|
| 60 | BLANK ; -- blank line
|
|---|
| 61 | S LCNT=LCNT+1,^TMP("ORXPND",$J,LCNT,0)=" "
|
|---|
| 62 | Q
|
|---|
| 63 | ;
|
|---|
| 64 | ITEM(X) ; -- set name of item into display
|
|---|
| 65 | S LCNT=LCNT+1,^TMP("ORXPND",$J,LCNT,0)=X
|
|---|
| 66 | I $D(IORVON),$D(IORVOFF) D SETVIDEO(LCNT,1,$L(X),IORVON,IORVOFF)
|
|---|
| 67 | Q
|
|---|
| 68 | ;
|
|---|
| 69 | TITLE(TAB) ; -- Screen title
|
|---|
| 70 | N Y S Y=""
|
|---|
| 71 | S:TAB="COVER" Y="Allergies/Alerts"
|
|---|
| 72 | S:TAB="NOTES" Y="Progress Note"
|
|---|
| 73 | S:TAB="PROBLEMS" Y="Problem"
|
|---|
| 74 | S:TAB="MEDS" Y="Medication"
|
|---|
| 75 | S:TAB="LABS" Y="Laboratory"
|
|---|
| 76 | S:TAB="ORDERS" Y=$S($G(ORESULTS):"Results",1:"Order")
|
|---|
| 77 | S:TAB="REPORTS" Y="Report"
|
|---|
| 78 | S:TAB="CONSULTS" Y="Consult/Procedure"
|
|---|
| 79 | S:TAB="XRAYS" Y="Radiology"
|
|---|
| 80 | S:TAB="SUMMRIES" Y="Discharge Summary"
|
|---|
| 81 | S:TAB="PTINQ" Y="Patient Inquiry"
|
|---|
| 82 | S:(TAB="NEW")!(TAB="DELAY") Y="Order"
|
|---|
| 83 | Q Y_" Display"
|
|---|
