source: WorldVistAEHR/trunk/r/ORDER_ENTRY_RESULTS_REPORTING-OR-OCX--ORRC--ORRJ/ORYDLG.m@ 613

Last change on this file since 613 was 613, checked in by George Lilly, 14 years ago

initial load of WorldVistAEHR
File size: 3.5 KB
Line 
1ORYDLG ;SLC/MKB -- Postinit bulletin for order dialogs ;7/28/04 08:18
2 ;;3.0;ORDER ENTRY/RESULTS REPORTING;**141,165,216,243**;Dec 17, 1997;Build 242
3 ;
4EN(PATCH,ORDLG,USERS) ; -- look for local copies of ORDLG(NAME) by package,
5 ; send list in bulletin to DUZ, POSTMASTER, USERS(DUZ) when done
6 ;
7 Q:$O(ORDLG(""))="" ;none
8 N ORZ,ORI,X,NM,I,OR0,PKG,DG,ORPKG,ORNATL,DLG,CNT,LR,PS
9 S ORZ(1)="The following nationally exported order dialogs have been modified by"
10 S X="this patch: ",ORI=1,NM="" F S NM=$O(ORDLG(NM)) Q:NM="" D
11 . S ORI=ORI+1,ORZ(ORI)=X_NM,X=" "
12 . S I=+$O(^ORD(101.41,"AB",NM,0)),OR0=$G(^ORD(101.41,I,0))
13 . S PKG=+$P(OR0,U,7),DG=+$P(OR0,U,5) S:PKG ORPKG(PKG,DG)=""
14 . S:$P(NM," ")="LR" LR=1 S:"^PS^PSJ^PSO^PSH^"[(U_$P(NM," ")_U) PS=1
15 D:$G(LR) LR D:$G(PS) PS ;reset FORMAT codes in changed dialogs
16 S I=0 F I=1:1 S X=$T(NATL+I) Q:X["ZZZZZ" S ORNATL($P(X,";",3))=""
17 S ORI=ORI+1,ORZ(ORI)="Please review and compare the following locally created order dialogs"
18 S ORI=ORI+1,ORZ(ORI)="that may be copies, for any necessary changes:",CNT=0
19 S PKG=0 F S PKG=$O(ORPKG(PKG)) Q:PKG<1 S DLG=0 D
20 . F S DLG=+$O(^ORD(101.41,"APKG",PKG,DLG)) Q:DLG<1 D
21 .. S OR0=$G(^ORD(101.41,DLG,0)) Q:$P(OR0,U,4)'="D"
22 .. Q:'$D(ORPKG(PKG,+$P(OR0,U,5))) ;included DispGrp
23 .. Q:$D(ORNATL($P(OR0,U))) S CNT=CNT+1
24 .. S ORI=ORI+1,ORZ(ORI)=$J(DLG,7)_" "_$P(OR0,U)
25EN1 I CNT>0 D ;local copies found -> send bulletin
26 . N XMDUZ,XMY,I,XMSUB,XMTEXT,DIFROM
27 . S XMDUZ="PATCH OR*3*"_$G(PATCH)_" POSTINIT",XMY(.5)=""
28 . S:$G(DUZ) XMY(DUZ)="" S I=0 F S I=$O(USERS(I)) Q:I<1 S XMY(I)=""
29 . S XMSUB=XMDUZ_" COMPLETED",XMTEXT="ORZ(" D ^XMD
30 . D BMES^XPDUTL("Some national order dialogs have been modified in this patch;")
31 . D MES^XPDUTL("a bulletin has been sent to the installer listing local copies that")
32 . D MES^XPDUTL("may need to be reviewed and updated.")
33 Q
34 ;
35NATL ;;Nationally exported dialogs
36 ;;FHW1
37 ;;FHW2
38 ;;FHW3
39 ;;FHW7
40 ;;FHW8
41 ;;FHW OP MEAL
42 ;;FHW SPECIAL MEAL
43 ;;GMRAOR ALLERGY ENTER/EDIT
44 ;;GMRCOR CONSULT
45 ;;GMRCOR REQUEST
46 ;;GMRVOR
47 ;;LR OTHER LAB TESTS
48 ;;OR GWCOND CONDITION
49 ;;OR GWDIAG DIAGNOSIS
50 ;;OR GWINST DNR
51 ;;OR GXACTV OTHER ACTIVITY ORDER
52 ;;OR GXMISC GENERAL
53 ;;OR GXMOVE ADMIT PATIENT
54 ;;OR GXMOVE DISCHARGE
55 ;;OR GXMOVE EVENT
56 ;;OR GXMOVE TRANSFER
57 ;;OR GXMOVE TREATING SPECIALTY
58 ;;OR GXPARM CALL HO ON
59 ;;OR GXSKIN DRESSING CHANGE
60 ;;OR GXTEXT TEXT ONLY ORDER
61 ;;OR GXTEXT WORD PROCESSING ORDER
62 ;;ORWD GENERIC ACTIVITY
63 ;;ORWD GENERIC DIET
64 ;;ORWD GENERIC NURSING
65 ;;ORWD GENERIC VITALS
66 ;;PS MEDS
67 ;;PSH OERR
68 ;;PSJ OR PAT OE
69 ;;PSJI OR PAT FLUID OE
70 ;;PSO OERR
71 ;;PSO SUPPLY
72 ;;RA OERR EXAM
73 ;;ZZZZZ
74 ;
75PS ; -- reset FORMAT values in PS dialogs
76 N DRUG,OI,STR,DLGNM,DLG,PRMT,DA
77 S DRUG=$$PTR("OR GTX DRUG NAME")
78 S OI=$$PTR("OR GTX ORDERABLE ITEM"),STR=$$PTR("OR GTX STRENGTH")
79 F DLGNM="PS MEDS","PSJ OR PAT OE","PSO OERR","PSO SUPPLY","PSH OERR" D
80 . S DLG=$$PTR(DLGNM)
81 . F PRMT=OI,STR D
82 .. S DA=+$O(^ORD(101.41,DLG,10,"D",PRMT,0))
83 .. S:DA $P(^ORD(101.41,DLG,10,DA,2),U,2)=("@"_DRUG)
84 Q
85 ; IV dialog
86 S DLG=$$PTR("PSJI OR PAT FLUID OE"),PRMT=$$PTR("OR GTX INFUSION RATE")
87 S DA=+$O(^ORD(101.41,DLG,10,"D",PRMT,0))
88 I DA S $P(^ORD(101.41,DLG,10,DA,2),U,2)=("@"_$$PTR("OR GTX SCHEDULE"))
89 Q
90 ;
91LR ; -- reset FORMAT value in LR dialog
92 N DLG,PRMT,DA
93 S DLG=$$PTR("LR OTHER LAB TESTS"),PRMT=$$PTR("OR GTX SPECIMEN")
94 S DA=+$O(^ORD(101.41,DLG,10,"D",PRMT,0))
95 I DA S $P(^ORD(101.41,DLG,10,DA,2),U,2)=("="_$$PTR("OR GTX COLLECTION SAMPLE"))
96 Q
97 ;
98PTR(X) Q +$O(^ORD(101.41,"B",X,0))
Note: See TracBrowser for help on using the repository browser.