| 1 | PXCAXAM ;ISL/dee - Validates & Translates data from the PCE Device Interface into PCE's PXK format for Exams ;3/14/97
|
|---|
| 2 | ;;1.0;PCE PATIENT CARE ENCOUNTER;**27**;Aug 12, 1996
|
|---|
| 3 | Q
|
|---|
| 4 | ; Variables
|
|---|
| 5 | ; PXCAXAM Copy of a EXAM node of the PXCA array
|
|---|
| 6 | ; PXCAPRV Pointer to the provider (200)
|
|---|
| 7 | ; PXCANUMB Count of the number if XAMs
|
|---|
| 8 | ; PXCAINDX Count of the number of EXAM for one provider
|
|---|
| 9 | ; PXCAFTER Temp used to build ^TMP(PXCAGLB,$J,"XAM",PXCANUMB,0,"AFTER")
|
|---|
| 10 | ; PXCAPNAR Pointer to the provider narrative (9999999.27)
|
|---|
| 11 | ;
|
|---|
| 12 | XAM(PXCAXAM,PXCANUMB,PXCAPRV,PXCAERRS) ;
|
|---|
| 13 | N PXCAFTER
|
|---|
| 14 | S PXCAFTER=$P(PXCAXAM,"^",1)_"^"_PXCAPAT_"^"_PXCAVSIT_"^"
|
|---|
| 15 | S PXCAFTER=PXCAFTER_$P(PXCAXAM,"^",2)
|
|---|
| 16 | S ^TMP(PXCAGLB,$J,"XAM",PXCANUMB,"IEN")=""
|
|---|
| 17 | S ^TMP(PXCAGLB,$J,"XAM",PXCANUMB,0,"BEFORE")=""
|
|---|
| 18 | S ^TMP(PXCAGLB,$J,"XAM",PXCANUMB,0,"AFTER")=PXCAFTER
|
|---|
| 19 | S ^TMP(PXCAGLB,$J,"XAM",PXCANUMB,12,"BEFORE")=""
|
|---|
| 20 | S ^TMP(PXCAGLB,$J,"XAM",PXCANUMB,12,"AFTER")="^^^"_$S(PXCAPRV>0:PXCAPRV,1:"")
|
|---|
| 21 | S ^TMP(PXCAGLB,$J,"XAM",PXCANUMB,812,"BEFORE")=""
|
|---|
| 22 | S ^TMP(PXCAGLB,$J,"XAM",PXCANUMB,812,"AFTER")="^"_PXCAPKG_"^"_PXCASOR
|
|---|
| 23 | Q
|
|---|
| 24 | ;
|
|---|
| 25 | EXAM(PXCA,PXCABULD,PXCAERRS) ;Validation routine for XAM
|
|---|
| 26 | Q:'$D(PXCA("EXAM"))
|
|---|
| 27 | N PXCAXAM,PXCAPRV,PXCANUMB,PXCAINDX
|
|---|
| 28 | N PXCAITEM
|
|---|
| 29 | S PXCAPRV=""
|
|---|
| 30 | S PXCANUMB=0
|
|---|
| 31 | F S PXCAPRV=$O(PXCA("EXAM",PXCAPRV)) Q:PXCAPRV']"" D
|
|---|
| 32 | . I PXCAPRV>0 D
|
|---|
| 33 | .. I '$$ACTIVPRV^PXAPI(PXCAPRV,PXCADT) S PXCA("ERROR","EXAM",PXCAPRV,0,0)="Provider is not active or valid^"_PXCAPRV
|
|---|
| 34 | .. E I PXCABULD!PXCAERRS D ANOTHPRV^PXCAPRV(PXCAPRV)
|
|---|
| 35 | . S PXCAINDX=0
|
|---|
| 36 | . F S PXCAINDX=$O(PXCA("EXAM",PXCAPRV,PXCAINDX)) Q:PXCAINDX']"" D
|
|---|
| 37 | .. S PXCAXAM=$G(PXCA("EXAM",PXCAPRV,PXCAINDX))
|
|---|
| 38 | .. S PXCANUMB=PXCANUMB+1
|
|---|
| 39 | .. I PXCAXAM="" S PXCA("ERROR","EXAM",PXCAPRV,PXCAINDX,0)="EXAM data missing" Q
|
|---|
| 40 | .. S PXCAITEM=+$P(PXCAXAM,U,1)
|
|---|
| 41 | .. I $G(^AUTTEXAM(PXCAITEM,0))="" S PXCA("ERROR","EXAM",PXCAPRV,PXCAINDX,1)="EXAM type not in file 9999999.15^"_PXCAITEM
|
|---|
| 42 | .. S PXCAITEM=$P(PXCAXAM,U,2) I '(PXCAITEM=""!(PXCAITEM="A")!(PXCAITEM="N")) S PXCA("ERROR","EXAM",PXCAPRV,PXCAINDX,2)="EXAM results must be A|N^"_PXCAITEM
|
|---|
| 43 | .. I PXCABULD&'$D(PXCA("ERROR","EXAM",PXCAPRV,PXCAINDX))!PXCAERRS D XAM(PXCAXAM,.PXCANUMB,PXCAPRV,PXCAERRS)
|
|---|
| 44 | Q
|
|---|
| 45 | ;
|
|---|
