source: WorldVistAEHR/trunk/r/TEXT_INTEGRATION_UTILITIES-GMRP-TIU/TIUR.m@ 1556

Last change on this file since 1556 was 623, checked in by George Lilly, 15 years ago

revised back to 6/30/08 version
File size: 6.8 KB
Line 
1TIUR ; SLC/JER - Integrated Document Review ;11/01/03
2 ;;1.0;TEXT INTEGRATION UTILITIES;**74,79,58,100,113,112,207**;Jun 20, 1997
3 ; 11/30/00 Moved PUTLIST & ADDELMNT to TIUR1
4MAKELIST(TIUCLASS,TIUCHVW) ; Get Search Criteria
5 N DIRUT,DTOUT,DUOUT,TIUI,SCREEN,STATUS,TIUTYP,TIUSTAT,TIUEDFLT,TIUDCL
6 N TIUDPRMT,TIUPICT,TIUOUT,STATWORD,STATIFN,NOWFLAG,TIUSC207,TIU1DOC
7 K DIROUT
8 D INITRR^TIULRR(0)
9 ; TIURPN used in Order Entry 2.5, OR OE/RR MENU CLIN:
10 I +$G(ORVP),(+$G(TIUCHVW)'>0) D EN^TIURPN(TIUCLASS,+ORVP) Q
11STATUS S STATUS=$$STAT
12 I +STATUS<0 S VALMQUIT=1 Q
13 S TIUI=0
14 F S TIUI=$O(TIUSTAT(TIUI)) Q:'TIUI!(+$G(TIUOUT)) D
15 . I $P($G(TIUSTAT(TIUI)),U,3)="" S TIUOUT=1 Q
16 . S STATIFN=$O(^TIU(8925.6,"B",$$UPPER^TIULS($P(TIUSTAT(TIUI),U,3)),0))
17 . Q:'STATIFN
18 . S STATUS("IFNS")=$G(STATUS("IFNS"))_STATIFN_";"
19 I +$G(TIUOUT) S VALMQUIT=1 Q
20 S TIUI=1,STATWORD=$$UPPER^TIULS($P(TIUSTAT(1),U,3))
21 I +$G(TIUSTAT(4))'>0 F S TIUI=$O(TIUSTAT(TIUI)) Q:+TIUI'>0 D
22 . S STATWORD=STATWORD_$S(TIUI=+TIUSTAT(1):" & ",1:", ")_$$UPPER^TIULS($P(TIUSTAT(TIUI),U,3))
23 I +$G(TIUSTAT(4))>0 S STATWORD=$S($P(TIUSTAT(4),U,4)="ALL":"ALL",1:STATWORD_", OTHER")
24 S STATUS("WORDS")=STATWORD
25DOCTYPE ; Select Document Type(s)
26 ; TIU207-If only 1 docytyp and have been to screen prompt then go back another level to avoid loop with next prompt.
27 I $G(TIUSC207)=1,$G(TIU1DOC)=1 D G STATUS
28 .S (TIUSC207,TIU1DOC)=0
29 S (TIUSC207,TIU1DOC)=0
30 N TIUDCL K TIUPICT
31 I $S(('$D(TIUQUIK)&'$D(ORVP)):1,($D(ORVP)&+$G(TIUCHVW)):1,1:0) D SELTYP^TIULA(TIUCLASS,.TIUTYP,"A","LAST","DOC",0,.TIUDCL,.TIUPICT)
32 S TIU1DOC=+$P($G(^TIU(8925.1,+TIUCLASS,10,0)),U,3)
33 ; SELTYP sets array ^TMP("TIUTYP",$J);
34 ; SELTYP used to set data into TIUTYP array
35 ; Now TIUTYP just ="^TMP("TIUTYP",$J)"
36 I $S($D(TIUQUIK):1,($D(ORVP)&'+$G(TIUCHVW)):1,1:0) D SELTYP^TIULA(TIUCLASS,.TIUTYP,"F","ALL","DOC",0)
37 I +$G(DIROUT) S VALMQUIT=1 Q
38 I +$G(@TIUTYP)'>0,'$D(TIUQUIK) G STATUS
39SCREEN ;
40 S TIUSC207=1
41 N TIUNAME,TIUOVER
42 S TIUNAME=$P($G(^VA(200,+DUZ,0)),U)
43 I $D(TIUQUIK) D I 1 ; all my unsigned TIUQUIK=1
44 . I $G(TIUQUIK)=3 S SCREEN(1)="ALL^ANY" Q
45 . S SCREEN(1)="AAU^"_DUZ_U_TIUNAME
46 . S:$G(TIUQUIK)=1 SCREEN(2)="ASUP^"_DUZ
47 . S SCREEN="ALL"
48 E I $D(ORVP),'+$G(TIUCHVW) S SCREEN(1)="APT^"_+ORVP_U_$P($G(^DPT(+ORVP,0)),U) I 1
49 S TIUOVER=""
50 E D SELCAT^TIULA1(.SCREEN,"A","AUTHOR",.TIUOVER)
51 I +$G(DIROUT) S VALMQUIT=1 Q
52 I $D(SCREEN)'>9 K @TIUTYP G DOCTYPE
53 I $D(@TIUTYP)'>9 W !,$C(7),"You must select one or more TITLES..." G SCREEN
54 I $G(SCREEN(1))="ALL^ANY",+$G(ORVP) S SCREEN(1)="APT^"_+$G(ORVP)_U_$P($G(^DPT(+$G(ORVP),0)),U)
55 D CHECKADD
56ERLY S TIUEDFLT=$S(TIUCLASS=3:"T-2",TIUCLASS=244:"T-30",1:"T-7")
57 S TIUDPRMT=$S(TIUCLASS=244:"Discharge",1:"Reference")
58 S TIUEDT=$S($D(TIUQUIK):1,$D(ORVP)&(+$G(TIUCHVW)'>0):$$FMADD^XLFDT(DT,$S($D(^DPT(+$G(ORVP),.1))'>0:-180,1:-30)),1:$P($$EDATE^TIULA(TIUDPRMT,"",TIUEDFLT),U))
59 I +$G(DIROUT) S VALMQUIT=1 Q
60 I TIUEDT'>0 G SCREEN
61 S TIULDT=$S($D(TIUQUIK):9999999,$D(ORVP)&(+$G(TIUCHVW)'>0):+$$NOW^XLFDT,1:$P($$LDATE^TIULA(TIUDPRMT),U))
62 I +$G(DIROUT) S VALMQUIT=1 Q
63 I TIULDT'>0 G ERLY
64 I TIUEDT>TIULDT D SWAP(.TIUEDT,.TIULDT)
65 I $L(TIULDT,".")=1 D EXPRANGE(.TIUEDT,.TIULDT)
66 ; -- Reset late date to NOW on rebuild:
67 S NOWFLAG=$S(TIULDT-$$NOW^XLFDT<.0001:1,1:0)
68 I '$G(TIURBLD) W !,"Searching for the documents."
69 D BUILD(TIUCLASS,.STATUS,.SCREEN,TIUEDT,TIULDT,NOWFLAG) ;11/30/00 removed param TIUTYP since BUILD uses global now.
70 ; -- If attaching ID note & changed view,
71 ; update video for line to be attached: --
72 I $G(TIUGLINK) D RESTOREG^TIULM(.TIUGLINK)
73 ;K @TIUTYP ;11/30/00 keep ^TMP("TIUTYP",$J) for rebuild
74 Q
75STAT() ; Determine status
76 N TIUY
77 I +$G(TIUQUIK) D G STATX
78 . S TIUY=$$SELSTAT^TIULA(.TIUSTAT,"F",$S(TIUQUIK=1:"UNSIGNED,UNCOSIGNED",TIUQUIK>1:"UNDICTATED,UNTRANSCRIBED"))
79 I $D(ORVP),'+$G(TIUCHVW) D G STATX
80 . S TIUY=$$SELSTAT^TIULA(.TIUSTAT,"F","COMPLETED")
81 S TIUY=$$SELSTAT^TIULA(.TIUSTAT,"A",$$DFLTSTAT^TIURM(DUZ))
82STATX Q TIUY
83CHECKADD ; Checks whether Addendum is included in the list of types
84 N TIUI,HIT,NUMTYPS
85 S (TIUI,HIT)=0
86 F S TIUI=$O(^TMP("TIUTYP",$J,TIUI)) Q:+TIUI'>0!+HIT I $$UP^XLFSTR(^TMP("TIUTYP",$J,TIUI))["ADDENDUM" S HIT=1
87 S NUMTYPS=^TMP("TIUTYP",$J)
88 I +HIT'>0 S ^TMP("TIUTYP",$J,NUMTYPS+1)=+^TMP("TIUTYP",$J,NUMTYPS)+1_U_"81^Addendum^NOT PICKED",^TMP("TIUTYP",$J)=^TMP("TIUTYP",$J)+1
89 Q
90 ;
91SWAP(TIUX,TIUY) ; Swap variables
92 N TIUTMP S TIUTMP=TIUX,TIUX=TIUY,TIUY=TIUTMP
93 Q
94EXPRANGE(TIUX,TIUY) ; Expand late date to include time
95 ;P74 If user entered date/time = T, then numerical date time is FIRST ^ PIECE ONLY of TIUX & TIUY.
96 I $P(TIUY,U)=DT S TIUY=$$NOW^XLFDT I 1
97 E S TIUY=$P(TIUY,U)_"."_235959 ;P74 Add seconds
98 Q
99BUILD(TIUCLASS,STATUS,SCREEN,EARLY,LATE,NOWFLAG) ; Build List.
100 ;11/30/00 - removed param TYPES. 12/3 added param TIUCLASS
101 ; BUILD (GATHER) uses docmt type info from ^TMP("TIUTYP",$J)
102 N TIUDT,TIUI,TIUK
103 N TIUT,TIUTP,XREF,TIUS,TIUPREF
104 S TIUPREF=$$PERSPRF^TIULE(DUZ),(TIUK,VALMCNT)=0
105 K ^TMP("TIUR",$J),^TMP("TIURIDX",$J),^TMP("TIUI",$J)
106 ; If user entered NOW at first build, update NOW for rebuild;
107 ; Save data in ^TMP("TIURIDX",$J,0) for rebuild:
108 I $G(TIURBLD),$G(NOWFLAG) S LATE=$$NOW^XLFDT
109 S ^TMP("TIURIDX",$J,0)=+EARLY_U_+LATE_U_$G(STATUS("IFNS"))_U_NOWFLAG
110 S ^TMP("TIUR",$J,"RTN")="TIUR"
111 S ^TMP("TIUR",$J,"TITLE OVERRIDE")=$G(TIUOVER)
112 I '$D(TIUPRM0) D SETPARM^TIULE
113 S EARLY=9999999-+$G(EARLY),LATE=9999999-$S(+$G(LATE):+$G(LATE),1:3333333)
114 F S TIUK=$O(SCREEN(TIUK)) Q:TIUK'>0 D
115 . I $G(SCREEN)'="ALL" S SCREEN=$G(TIUK)
116 . S XREF=$P(SCREEN(TIUK),U)
117 . I XREF'="ASUB" D
118 . . S TIUI=$S(XREF'="APRB":$P(SCREEN(TIUK),U,2),1:$$UPPER^TIULS($P(SCREEN(TIUK),U,3)))
119 . . D GATHER^TIUR1(TIUI,TIUPREF,TIUCLASS,STATUS("IFNS"),EARLY,LATE,XREF,SCREEN)
120 . I XREF="ASUB" D
121 . . S TIUI=$O(^TIU(8925,XREF,$P(SCREEN(TIUK),U,2)),-1)
122 . . F S TIUI=$O(^TIU(8925,XREF,TIUI)) Q:TIUI=""!(TIUI'[$P(SCREEN(TIUK),U,2)) D GATHER^TIUR1(TIUI,TIUPREF,TIUCLASS,STATUS("IFNS"),EARLY,LATE,XREF,SCREEN)
123 D PUTLIST^TIUR2(TIUPREF,TIUCLASS,.STATUS,.SCREEN)
124 K ^TMP("TIUI",$J)
125 Q
126 ;
127CLEAN ; Clean up your mess!
128 K ^TMP("TIUR",$J),^TMP("TIURIDX",$J) D CLEAN^VALM10,KILLRR^TIULRR
129 K VALMY
130 K ^TMP("TIUTYP",$J)
131 Q
132 ;
133RBLD ; Rebuild list after actions 11/30/00
134 N TIUEXP,TIUR0,TIURIDX0,TIUSCRN,TMP,TIUEDT,TIULDT,TIUSTAT
135 N TIURBLD,TIUI,TIUCLASS,NOWFLAG
136 S TIURBLD=1
137 D FIXLSTNW^TIULM ;restore video for elements added to end of list
138 I +$O(^TMP("TIUR",$J,"EXPAND",0)) D
139 . M TIUEXP=^TMP("TIUR",$J,"EXPAND")
140 S TIUR0=^TMP("TIUR",$J,0),TIURIDX0=^TMP("TIURIDX",$J,0)
141 S TIUSCRN=$P(TIUR0,U,3,99),TIUCLASS=^TMP("TIUR",$J,"CLASS")
142 S TIUI=1
143 F S TMP=$P(TIUSCRN,";",TIUI) Q:TMP="" D
144 . S TIUSCRN(TIUI)=TMP,TIUI=TIUI+1
145 S TIUSCRN=$L(TIUSCRN,";")
146 S STATUS("WORDS")=$P(TIUR0,U,2)
147 S STATUS("IFNS")=$P(TIURIDX0,U,3)
148 S TIUEDT=$P(TIURIDX0,U),TIULDT=$P(TIURIDX0,U,2),NOWFLAG=+$P(TIURIDX0,U,4)
149 D BUILD(TIUCLASS,.STATUS,.TIUSCRN,TIUEDT,TIULDT,NOWFLAG)
150 ; Reexpand previously expanded items:
151 D RELOAD^TIUROR1(.TIUEXP)
152 D BREATHE^TIUROR1(1)
153 Q
Note: See TracBrowser for help on using the repository browser.