source: WorldVistAEHR/trunk/r/TEXT_INTEGRATION_UTILITIES-GMRP-TIU/TIUR1.m@ 1078

Last change on this file since 1078 was 613, checked in by George Lilly, 15 years ago

initial load of WorldVistAEHR
File size: 3.6 KB
Line 
1TIUR1 ; SLC/JER - Integrated Document Review ;11/01/03
2 ;;1.0;TEXT INTEGRATION UTILITIES;**79,100,113,112**;Jun 20, 1997
3 ; 11/30/00 moved PUTLIST & ADDELMNT here from TIUR.
4 ; 12/12/00 moved PUTLIST, ADDELMNT, PARENT, EXPANDKD to TIUR2
5GATHER(TIUI,TIUPREF,CLASS,STATIFNS,EARLY,LATE,XREF,SCREEN) ; Find/sort
6 ; Uses title info from ^TMP("TIUTYP",$J) array, set in SELTYP^TIULA
7 N TIUT,TIUTP,TIUS,TIUSTAT,TIUSFLD,TIUD0,TIUD12,TIUD13,TIUD15
8 N TIUIFN,TIULD
9 S TIUSFLD=$P(TIUPREF,U,3)
10 S TIUSFLD=$S(TIUSFLD="P":".02",TIUSFLD="D":".01",TIUSFLD="S":".05",TIUSFLD="C":"1507",TIUSFLD="A":"1202",TIUSFLD="E":"1208",1:"1301")
11 S TIUT=0 F S TIUT=$O(^TMP("TIUTYP",$J,TIUT)) Q:+TIUT'>0 D
12 . S TIUTP=+$P($G(^TMP("TIUTYP",$J,TIUT)),U,2) Q:TIUTP'>0
13 . S TIUS=1 F S TIUSTAT=$P(STATIFNS,";",TIUS) Q:'TIUSTAT D
14 . . S TIUS=TIUS+1
15 . . S (TIUJ,TIULD)=LATE
16 . . F S TIUJ=$O(^TIU(8925,XREF,TIUI,TIUTP,TIUSTAT,TIUJ)) Q:+TIUJ'>0!(+TIUJ>EARLY) D
17 . . . S TIUIFN=0
18 . . . F S TIUIFN=$O(^TIU(8925,XREF,TIUI,TIUTP,TIUSTAT,TIUJ,TIUIFN)) Q:+TIUIFN'>0 D
19 . . . . I ($P(TIUPRM0,U,6)="S"),(+$$CANDO^TIULP(TIUIFN,"VIEW")'>0) Q
20 . . . . I +$G(ORVP),(+$P($G(^TIU(8925,+TIUIFN,0)),U,2)'=+$G(ORVP)) Q
21 . . . . I TIUTP=81,(^TMP("TIUTYP",$J)>1),($P(^TMP("TIUTYP",$J,TIUT),U,4)="NOT PICKED"),(+$P($G(^TIU(8925,+TIUIFN,0)),U,5)>6) Q
22 . . . . I TIUTP=81,(^TMP("TIUTYP",$J)>1),($P(^TMP("TIUTYP",$J,TIUT),U,4)="NOT PICKED"),'+$$DADINTYP(TIUIFN) Q
23 . . . . S TIUQ=$$RESOLVE(TIUIFN,TIUSFLD)
24 . . . . ; S ^TMP("TIUI",$J,TIUQ,TIUJ,TIUIFN)="",TIULD=TIUJ ; P113
25 . . . . ; TIUK=1: 1 search category chosen (SCREEN="")
26 . . . . ; TIUK>1: 2+ search categories chosen (SCREEN=1)
27 . . . . ; ALL my unsigned (SCREEN="ALL")
28 . . . . I SCREEN=1!(SCREEN="ALL") S ^TMP("TIUI",$J,TIUQ,TIUJ,TIUIFN)=1
29 . . . . E D
30 . . . . . I $D(^TMP("TIUI",$J,TIUQ,TIUJ,TIUIFN)),$G(^TMP("TIUI",$J,TIUQ,TIUJ,TIUIFN))=(SCREEN-1) S ^TMP("TIUI",$J,TIUQ,TIUJ,TIUIFN)=SCREEN
31 . . . . S TIULD=TIUJ
32 I +$G(TIUQUIK)=1,+$G(TIULD) D ADDSIGN(DUZ,CLASS,TIULD,TIUSFLD)
33 Q
34DADINTYP(TIUDA) ; addendum's parent belong? 12/1/00 Removed param TYPES
35 N TIUI,TIUDTYP,TIUY S (TIUI,TIUY)=0
36 S TIUDTYP=+$G(^TIU(8925,+$P($G(^TIU(8925,+TIUDA,0)),U,6),0))
37 F S TIUI=$O(^TMP("TIUTYP",$J,TIUI)) Q:+TIUI'>0!+TIUY D
38 . I +$P(^TMP("TIUTYP",$J,TIUI),U,2)=TIUDTYP S TIUY=1
39 Q TIUY
40RESOLVE(DA,DR) ; resolve sort field values
41 N TIUD0,TIUD12,TIUD13,TIUD15,TIUY
42 S TIUD0=$G(^TIU(8925,+DA,0)),TIUD12=$G(^TIU(8925,+DA,12))
43 S TIUD13=$G(^TIU(8925,+DA,13)),TIUD15=$G(^TIU(8925,+DA,15))
44 I DR=.01 S TIUY=$$PNAME^TIULC1(+TIUD0) G RESX
45 I DR=.02 S TIUY=$$PTNAME^TIULC1(+$P(TIUD0,U,2)) G RESX
46 I DR=.05 S TIUY=$P(TIUD0,U,5) G RESX
47 I DR=1202 S TIUY=$$PERSNAME^TIULC1(+$P(TIUD12,U,2)) S:TIUY="UNKNOWN" TIUY="" G RESX
48 I DR=1208 S TIUY=$$PERSNAME^TIULC1(+$P(TIUD12,U,8)) S:TIUY="UNKNOWN" TIUY="" G RESX
49 I DR=1301 S TIUY=$P(TIUD13,U) G RESX
50 ;I DR=1507,($P(TIUD0,U,5)=7),(+$P(TIUD15,U,7)'>0) S DR=1501
51 I DR=1507,(($P(TIUD0,U,5)=7)!($P(TIUD0,U,5)=8)),(+$P(TIUD15,U,7)'>0) S DR=1501 ;TIU*1*100 amended notes were sorting at top w sortval=ZZZZEMPTY for sortfld=complete, even tho they had sign date and displayed it.
52 I DR=1501 S TIUY=$P(TIUD15,U) G RESX
53 I DR=1507 S TIUY=$P(TIUD15,U,7)
54RESX I $G(TIUY)']"" S TIUY="ZZZZEMPTY"
55 Q TIUY
56 ;
57ADDSIGN(USER,CLASS,DATE,SORTBY) ; Get documents for which the user is the additional signer
58 N TIUI,TIUY S TIUI=0
59 D NEEDSIG^TIULX(.TIUY,USER,CLASS)
60 F S TIUI=$O(@TIUY@(TIUI)) Q:+TIUI'>0 D
61 . N TIUDA,TIUD13,TIUQ,TIUJ
62 . S TIUDA=+$G(@TIUY@(TIUI)),TIUD13=$G(^TIU(8925,TIUDA,13))
63 . S TIUQ=$$RESOLVE(TIUDA,SORTBY),TIUJ=9999999-+TIUD13
64 . ; S ^TMP("TIUI",$J,TIUQ,TIUJ,TIUDA)="" ; P113
65 . S ^TMP("TIUI",$J,TIUQ,TIUJ,TIUDA)=1
66 K @TIUY
67 Q
Note: See TracBrowser for help on using the repository browser.