source: WorldVistAEHR/trunk/r/TEXT_INTEGRATION_UTILITIES-GMRP-TIU/TIURD1.m@ 1013

Last change on this file since 1013 was 613, checked in by George Lilly, 15 years ago

initial load of WorldVistAEHR
File size: 8.6 KB
Line 
1TIURD1 ; SLC/JER - Reassign actions ;4/18/03
2 ;;1.0;TEXT INTEGRATION UTILITIES;**1,7,61,113**;Jun 20, 1997
3MOVEADD(TIUDA) ; Move an addendum to another document
4 N DFN,TIUDAT,TIUSCRN,TIUMOVE,TIUTYP,TIUODA
5 S TIUTYP=$$CLINDOC^TIULC1(+$G(^TIU(8925,+$P($G(^TIU(8925,+TIUDA,0)),U,6),0)))
6 I +TIUTYP'>0 S TIUTYP=38
7 S TIUTYP(1)="1^"_TIUTYP_U_$P(^TIU(8925.1,+TIUTYP,0),U)
8 S DFN=+$$PATIENT^TIULA
9 I +DFN'>0 D Q
10 . W !!,"No PATIENT Selected: Aborting Transaction, No Harm Done...",!
11 . I $$READ^TIUU("EA","Press RETURN to continue...") ; pause
12 . S TIUOUT=1
13 ; --- If moving to different pt, keep retracted original ---
14 I +$G(DFN)'=$P(TIUD0(0),U,2),(+$P(TIUD0(0),U,5)>5) D
15 . W !,"Moving signed document to another Patient...A RETRACTED copy will be retained."
16 . S TIUODA=TIUDA,TIUDA=+$$RETRACT^TIURD2(TIUDA)
17 Q:+TIUDA'>0
18 D SELPAT^TIULA2(.TIUDAT,TIUTYP,DFN)
19 I +$G(TIUDAT)'>0,($D(TIUDAT)'>9) S TIUOUT=1 G ABORT
20 S TIUDAT=+$G(TIUDAT(1))
21 I +$$ISADDNDM^TIULC1(TIUDAT) D G ABORT
22 . W !!,$C(7),"You may not assign an addendum to an addendum...",!
23 . W:$$READ^TIUU("EA","Press RETURN to continue...") ""
24 . S TIUOUT=1
25 D FROMTO^TIURD4(TIUDA,TIUDAT)
26 I +$G(TIUDAT)>0,$$READ^TIUU("YO","Is this Correct","YES") D Q
27 . N TIUDD0,TIUDD12,TIUDD14
28 . S TIUDD0=$G(^TIU(8925,+TIUDAT,0)),TIUDD12=$G(^(12)),TIUDD14=$G(^(14))
29 . S DR=".02////"_$P(TIUDD0,U,2)_";.03////"_$P(TIUDD0,U,3)_";.06////"_+TIUDAT_";.07////"_$P(TIUDD0,U,7)_";.08////"_$S(+$P(TIUDD0,U,8):$P(TIUDD0,U,8),1:"@")_";.13////"_$P(TIUDD0,U,13)
30 . S DR=DR_";1401////"_$P(TIUDD14,U)_";1402////"_$P(TIUDD14,U,2)_";1404////"_$P(TIUDD14,U,4)_";1205////"_$P(TIUDD12,U,5)_";1211////"_$P(TIUDD12,U,11)_";1212////"_$P(TIUDD12,U,12)
31 . S DIE=8925,DA=+TIUDA D ^DIE
32 . K DR N TIUTYP
33 . S DR=".05///"_$$STATUS^TIULC(+TIUDA) D ^DIE
34 . S TIUD0(1)=$G(^TIU(8925,TIUDA,0)),TIUD12(1)=$G(^(12))
35 . D AUDREASS^TIURB1(TIUDA,.TIUD0,.TIUD12)
36 . I +$G(TIUODA) D AUDREASS^TIURB1(TIUODA,.TIUD0,.TIUD12)
37 . D SEND^TIUALRT(TIUDA)
38 . W "." S TIUCHNG=1
39ABORT ; Recover on abort
40 W !!,"Okay...No Harm done!"
41 I +$G(TIUODA),+$G(TIUDA),$D(TIUD0(0)) D RECOVER^TIURD4(TIUODA,TIUDA,.TIUD0)
42 S TIUCHNG=0
43 Q
44PROMOTE(TIUDA) ; Promote addendum
45 N DA,DR,DIE,TIUADD0,TIUTYPE,TIUPTYPE,TIUOUT,TIUVTYPE,TIUODA
46 S TIUADD0=$G(^TIU(8925,+TIUDA,0))
47 S TIUTYPE=+$G(^TIU(8925,+$P(TIUADD0,U,6),0)),TIUPTYPE=$P($G(^(0)),U,4),TIUVTYPE=$P($G(^(0)),U,13)
48 S DR=".01////"_TIUTYPE_";.04////"_TIUPTYPE_";.06///@;.13////"_TIUVTYPE
49 S DA=+TIUDA,DIE=8925
50 D ^DIE K DA,DR,DIE
51 D REASSIGO^TIURD3
52 I +$G(TIUOUT)>0 D Q
53 . N DIE,DA,DR
54 . I +$G(TIUODA),+$G(TIUDA),$D(TIUD0(0)) D RECOVER^TIURD4(TIUODA,TIUDA,.TIUD0)
55 . W !!,"Restoring Addendum to original state..."
56 . S DIE=8925,DA=$S(+$G(TIUODA):TIUODA,1:TIUDA)
57 . S DR=".01////^S X=+TIUADD0;.04////^S X=$P(TIUADD0,U,4);.06////^S X=$P(TIUADD0,U,6)"
58 . S DR=DR_";.07////^S X=$P(TIUADD0,U,7);.08////^S X=$S(+$P(TIUADD0,U,8):+$P(TIUADD0,U,8),1:""@"")"
59 . D ^DIE
60 ; If promotion successful & addendum retracted, reset 0-node of retracted record
61 I +$G(TIUODA) D
62 . N DIE,DA,DR
63 . S DIE=8925,DA=TIUODA
64 . S DR=".01////^S X=+TIUADD0;.04////^S X=$P(TIUADD0,U,4);.06////^S X=$P(TIUADD0,U,6)"
65 . D ^DIE
66 D SEND^TIUALRT(TIUDA)
67 W !!,"ADDENDUM Promoted to be an ORIGINAL ",$$PNAME^TIULC1(TIUTYPE) H 2
68 S TIUCHNG=1,VALMBCK="Q"
69 Q
70REPLACE(TIUDA) ; Replace original with addendum
71 N TIUODA,TIUCONT,TIUOS,TIUAS,TIUOODA,TIUOD0
72 W !!,$C(7),"This is an IRREVERSIBLE action..."
73 S TIUCONT=$$READ^TIUU("YA","Are you SURE you wish to continue? ","NO")
74 I '+TIUCONT S TIUCHNG=0 W !,"No changes made." Q
75 W !,"Okay, here we go then..."
76 S TIUODA=+$P(^TIU(8925,TIUDA,0),U,6) Q:+TIUODA'>0
77 S TIUOD0=$G(^TIU(8925,TIUODA,0))
78 I +$P(TIUOD0,U,5)>5 D
79 . W !!,"A RETRACTED copy of the signed ORIGINAL will be retained.",!
80 . S TIUOODA=TIUODA,TIUODA=$$RETRACT^TIURD2(TIUODA,"",+$P(TIUOD0,U,5),"",1)
81 ; Load Signature
82 D LOADSB^TIURD4(TIUODA,TIUDA,.TIUOS,.TIUAS)
83 ; Move non-WP flds from add to orig
84 D SWAPFLDS(TIUODA,TIUDA,0)
85 ; Move original into ^TIU(8925,+TIUODA,"TEMP")
86 D BUFFER^TIUEDIU(TIUODA) W "."
87 ; Replace ^TIU(8925,+TIUODA,"TEMP") w ^TIU(8925,+TIUDA,"TEXT")
88 K ^TIU(8925,+TIUODA,"TEMP")
89 M ^TIU(8925,+TIUODA,"TEMP")=^TIU(8925,+TIUDA,"TEXT") W "."
90 ; File changes
91 K ^TIU(8925,+TIUODA,"TEXT")
92 D MERGTEXT^TIUEDI1(TIUODA) W "."
93 K ^TIU(8925,+TIUODA,"TEMP")
94 ; Swap signatures
95 D SWAPSB^TIURD4(TIUODA,TIUDA,.TIUOS,.TIUAS)
96 ; Update status of new original
97 D UPDSTAT^TIURD4(TIUODA)
98 ; Resend alerts
99 D SEND^TIUALRT(TIUODA)
100 ; Delete Addendum Record
101 D DELETE^TIUEDIT(TIUDA,0,"",1) W "...Done."
102 S TIUCHNG=2 S:+$G(TIUOODA) TIUCHNG=TIUCHNG_U_TIUODA
103 Q
104SWAPADD(TIUDA) ; Swap addendum with original
105 N TIUODA,TIUCONT K ^TMP("TIUSWAP",$J)
106 N TIUOS,TIUAS
107 W !!,$C(7),"Don't worry...This is a REVERSIBLE action."
108 S TIUCONT=$$READ^TIUU("YA","Even so, are you SURE you wish to continue? ","NO")
109 I '+TIUCONT S TIUCHNG=0 W !,"No changes made." Q
110 W !,"Okay, you can always swap 'em back"
111 S TIUODA=+$P(^TIU(8925,TIUDA,0),U,6) Q:+TIUODA'>0
112 D LOADSB^TIURD4(TIUODA,TIUDA,.TIUOS,.TIUAS)
113 ; Swap the non-WP flds
114 D SWAPFLDS(TIUODA,TIUDA,1)
115 ; Move original into ^TIU(8925,+TIUODA,"TEMP")
116 D BUFFER^TIUEDIU(TIUODA) W "."
117 ; Move ^TIU(8925,+TIUODA,"TEMP") into ^TMP("TIUSWAP",$J)
118 M ^TMP("TIUSWAP",$J)=^TIU(8925,+TIUODA,"TEMP") W "."
119 ; Replace ^TIU(8925,+TIUODA,"TEMP") with ^TIU(8925,+TIUDA,"TEXT")
120 K ^TIU(8925,+TIUODA,"TEMP")
121 M ^TIU(8925,+TIUODA,"TEMP")=^TIU(8925,+TIUDA,"TEXT") W "."
122 ; File changes to orig
123 K ^TIU(8925,+TIUODA,"TEXT")
124 D MERGTEXT^TIUEDI1(TIUODA) W "."
125 K ^TIU(8925,+TIUODA,"TEMP")
126 ; Merge ^TMP("TIUSWAP",$J) into ^TIU(8925,+TIUDA,"TEMP")
127 K ^TIU(8925,+TIUDA,"TEMP")
128 M ^TIU(8925,+TIUDA,"TEMP")=^TMP("TIUSWAP",$J) W "."
129 ; File changes to add
130 K ^TIU(8925,+TIUDA,"TEXT")
131 D MERGTEXT^TIUEDI1(TIUDA) W "."
132 ; Swap signatures
133 D SWAPSB^TIURD4(TIUODA,TIUDA,.TIUOS,.TIUAS)
134 ; Update status of each record
135 D UPDSTAT^TIURD4(TIUODA),UPDSTAT^TIURD4(TIUDA)
136 ; Resend alerts
137 D SEND^TIUALRT(TIUDA),SEND^TIUALRT(TIUODA)
138 ; Clean up ^TIU(8925,+TIUDA,"TEMP" and ^TMP("TIUSWAP",$J)
139 K ^TIU(8925,+TIUDA,"TEMP"),^TMP("TIUSWAP",$J) W "...Done." S TIUCHNG=1
140 Q
141SWAPFLDS(TIUODA,TIUADA,SWAP) ; Move Identifier fields
142 N DA,DR,DIE,TIUOD12,TIUAD12,TIUOD13,TIUAD13,TIUOD15,TIUAD15
143 S TIUOD12=$G(^TIU(8925,TIUODA,12)),TIUOD13=$G(^(13)),TIUOD15=$G(^(15))
144 S TIUAD12=$G(^TIU(8925,TIUADA,12)),TIUAD13=$G(^(13)),TIUAD15=$G(^(15))
145 S DR="1201////"_$S(+TIUAD12>0:+TIUAD12,1:"@")_";1202////"_$P(TIUAD12,U,2)
146 S DR=DR_";1204////"_$P(TIUAD12,U,4)_";1208////"_$S($P(TIUAD12,U,8)]"":$P(TIUAD12,U,8),1:"@")_";1209////"_$S($P(TIUAD12,U,9)]"":$P(TIUAD12,U,9),1:"@")
147 S DA=TIUODA,DIE="^TIU(8925," D ^DIE K DR
148 S DR="1302////"_$P(TIUAD13,U,2)_";1303////"_$P(TIUAD13,U,3)_";1304////"_$S($P(TIUAD13,U,4)]"":$P(TIUAD13,U,4),1:"@")
149 S DR=DR_";1305////"_$S($P(TIUAD13,U,5)]"":$P(TIUAD13,U,5),1:"@")_";1306////"_$S($P(TIUAD13,U,6)]"":$P(TIUAD13,U,6),1:"@")_";1307////"_$S($P(TIUAD13,U,7)]"":$P(TIUAD13,U,7),1:"@")
150 S DA=TIUODA,DIE="^TIU(8925," D ^DIE K DR
151 S DR="1501////"_$S($P(TIUAD15,U)]"":$P(TIUAD15,U),1:"@")_";1502////"_$S($P(TIUAD15,U,2)]"":$P(TIUAD15,U,2),1:"@")
152 S DR=DR_";1505////"_$S($P(TIUAD15,U,5)]"":$P(TIUAD15,U,5),1:"@")_";1506////"_$S($P(TIUAD15,U,6)]"":$P(TIUAD15,U,6),1:"@")
153 S DA=TIUODA,DIE="^TIU(8925," D ^DIE K DR
154 S DR="1507////"_$S($P(TIUAD15,U,7)]"":$P(TIUAD15,U,7),1:"@")_";1508////"_$S($P(TIUAD15,U,8)]"":$P(TIUAD15,U,8),1:"@")
155 S DR=DR_";1511////"_$S($P(TIUAD15,U,11)]"":$P(TIUAD15,U,11),1:"@")_";1512////"_$S($P(TIUAD15,U,12)]"":$P(TIUAD15,U,12),1:"@")_";1513////"_$S($P(TIUAD15,U,13)]"":$P(TIUAD15,U,13),1:"@")
156 S DA=TIUODA,DIE="^TIU(8925," D ^DIE K DR
157 I '+$G(SWAP) Q
158 S DR="1201////"_$S(+TIUOD12>0:+TIUOD12,1:"@")_";1202////"_$P(TIUOD12,U,2)
159 S DR=DR_";1204////"_$P(TIUOD12,U,4)_";1208////"_$S($P(TIUOD12,U,8)]"":$P(TIUOD12,U,8),1:"@")_";1209////"_$S($P(TIUOD12,U,9)]"":$P(TIUOD12,U,9),1:"@")
160 S DA=TIUADA,DIE="^TIU(8925," D ^DIE K DR
161 S DR="1302////"_$P(TIUOD13,U,2)_";1303////"_$P(TIUOD13,U,3)_";1304////"_$S($P(TIUOD13,U,4)]"":$P(TIUOD13,U,4),1:"@")
162 S DR=DR_";1305////"_$S($P(TIUOD13,U,5)]"":$P(TIUOD13,U,5),1:"@")_";1306////"_$S($P(TIUOD13,U,6)]"":$P(TIUOD13,U,6),1:"@")_";1307////"_$S($P(TIUOD13,U,7)]"":$P(TIUOD13,U,7),1:"@")
163 S DA=TIUADA,DIE="^TIU(8925," D ^DIE K DR
164 S DR="1501////"_$S($P(TIUOD15,U)]"":$P(TIUOD15,U),1:"@")_";1502////"_$S($P(TIUOD15,U,2)]"":$P(TIUOD15,U,2),1:"@")
165 S DR=DR_";1505////"_$S($P(TIUOD15,U,5)]"":$P(TIUOD15,U,5),1:"@")_";1506////"_$S($P(TIUOD15,U,6)]"":$P(TIUOD15,U,6),1:"@")
166 S DA=TIUADA,DIE="^TIU(8925," D ^DIE K DR
167 S DR="1507////"_$S($P(TIUOD15,U,7)]"":$P(TIUOD15,U,7),1:"@")_";1508////"_$S($P(TIUOD15,U,8)]"":$P(TIUOD15,U,8),1:"@")
168 S DR=DR_";1511////"_$S($P(TIUOD15,U,11)]"":$P(TIUOD15,U,11),1:"@")_";1512////"_$S($P(TIUOD15,U,12)]"":$P(TIUOD15,U,12),1:"@")_";1513////"_$S($P(TIUOD15,U,13)]"":$P(TIUOD15,U,13),1:"@")
169 S DA=TIUADA,DIE="^TIU(8925," D ^DIE K DR
170 Q
Note: See TracBrowser for help on using the repository browser.