source: ccr/trunk/p/C0CCCR.m@ 699

Last change on this file since 699 was 690, checked in by Christopher Edwards, 15 years ago

Added kill to temporary global
File size: 10.1 KB
Line 
1C0CCCR ; CCDCCR/GPL - CCR MAIN PROCESSING; 6/6/08
2 ;;1.0;C0C;;May 19, 2009;
3 ;Copyright 2008,2009 George Lilly, University of Minnesota.
4 ;Licensed under the terms of the GNU General Public License.
5 ;See attached copy of the License.
6 ;
7 ;This program is free software; you can redistribute it and/or modify
8 ;it under the terms of the GNU General Public License as published by
9 ;the Free Software Foundation; either version 2 of the License, or
10 ;(at your option) any later version.
11 ;
12 ;This program is distributed in the hope that it will be useful,
13 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 ;GNU General Public License for more details.
16 ;
17 ;You should have received a copy of the GNU General Public License along
18 ;with this program; if not, write to the Free Software Foundation, Inc.,
19 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
20 ;
21 ; EXPORT A CCR
22 ;
23EXPORT ; EXPORT ENTRY POINT FOR CCR
24 ; Select a patient.
25 S DIC=2,DIC(0)="AEMQ" D ^DIC
26 I Y<1 Q ; EXIT
27 S DFN=$P(Y,U,1) ; SET THE PATIENT
28 D XPAT(DFN) ; EXPORT TO A FILE
29 Q
30 ;
31XPAT(DFN,XPARMS,DIR,FN) ; EXPORT ONE PATIENT TO A FILE
32 ; DIR IS THE DIRECTORY, DEFAULTS IF NULL TO ^TMP("C0CCCR","ODIR")
33 ; FN IS FILE NAME, DEFAULTS IF NULL
34 N CCRGLO,UDIR,UFN
35 S C0CNRPC=1 ; FLAG FOR NOT AN RPC CALL - FOR DEBUGGING THE RPC
36 I '$D(DIR) S UDIR=""
37 E S UDIR=DIR
38 I '$D(FN) S UFN="" ; IF FILENAME IS NOT PASSED
39 E S UFN=FN
40 I '$D(XPARMS) S XPARMS=""
41 N C0CRTN ; RETURN ARRAY
42 D CCRRPC(.C0CRTN,DFN,XPARMS,"CCR")
43 S OARY=$NA(^TMP("C0CCCR",$J,DFN,"CCR",1))
44 S ONAM=UFN
45 I UFN="" S ONAM="PAT_"_DFN_"_CCR_V1_0_0.xml"
46 S ODIRGLB=$NA(^TMP("C0CCCR","ODIR"))
47 S ^TMP("C0CCCR","FNAME",DFN)=ONAM ; FILE NAME FOR BATCH USE
48 I $D(^TMP("GPLCCR","ODIR")) S @ODIRGLB=^TMP("GPLCCR","ODIR")
49 I '$D(@ODIRGLB) D ; IF NOT ODIR HAS BEEN SET
50 . W "Warning.. please set ^TMP(""C0CCCR"",""ODIR"")=""output path""",! Q
51 . ;S @ODIRGLB="/home/glilly/CCROUT"
52 . ;S @ODIRGLB="/home/cedwards/"
53 . S @ODIRGLB="/opt/wv/p/"
54 S ODIR=UDIR
55 I UDIR="" S ODIR=@ODIRGLB
56 N ZY
57 S ZY=$$OUTPUT^C0CXPATH(OARY,ONAM,ODIR)
58 W !,$P(ZY,U,2),!
59 Q
60 ;
61DCCR(DFN) ; DISPLAY A CCR THAT HAS JUST BEEN EXTRACTED
62 ;
63 N G1
64 S G1=$NA(^TMP("C0CCCR",$J,DFN,"CCR"))
65 I $D(@G1@(0)) D ; CCR EXISTS
66 . D PARY^C0CXPATH(G1)
67 E W "CCR NOT CREATED, RUN D XPAT^C0CCCR(DFN,"""","""") FIRST",!
68 Q
69 ;
70CCRRPC(CCRGRTN,DFN,CCRPARMS,CCRPART) ;RPC ENTRY POINT FOR CCR OUTPUT
71 ; CCRGRTN IS RETURN ARRAY PASSED BY REFERENCE
72 ; DFN IS PATIENT IEN
73 ; CCRPART IS "CCR" FOR ENTIRE CCR, OR SECTION NAME FOR A PART
74 ; OF THE CCR BODY.. PARTS INCLUDE "PROBLEMS" "VITALS" ETC
75 ; CCRPARMS ARE PARAMETERS THAT AFFECT THE EXTRACTION
76 ; IN THE FORM "PARM1:VALUE1^PARM2:VALUE2"
77 ; EXAMPLE: "LABLIMIT:T-60" TO LIMIT LAB EXTRACTION TO THE LAST 60 DAYS
78 ; SEE C0CPARMS FOR A COMPLETE LIST OF SUPPORTED PARAMETERS
79 K ^TMP("C0CCCR",$J) ; CLEAN UP THE GLOBAL BEFORE WE USE IT
80 I '$D(DEBUG) S DEBUG=0
81 S CCD=0 ; NEED THIS FLAG TO DISTINGUISH FROM CCD
82 I '$D(CCRPARMS) S CCRPARMS=""
83 I '$D(CCRPART) S CCRPART="CCR"
84 I '$D(C0CNRPC) S ^TMP("C0CRPC",$H,"CALL",DFN)=""
85 D SET^C0CPARMS(CCRPARMS) ;SET PARAMETERS WITH CCRPARMS AS OVERRIDES
86 I '$D(TESTLAB) S TESTLAB=0 ; FLAG FOR TESTING RESULTS SECTION
87 I '$D(TESTALERT) S TESTALERT=1 ; FLAG FOR TESTING ALERTS SECTION
88 I '$D(TESTMEDS) S TESTMEDS=0 ; FLAG FOR TESTING C0CMED SECTION
89 S TGLOBAL=$NA(^TMP("C0CCCR",$J,"TEMPLATE")) ; GLOBAL FOR STORING TEMPLATE
90 S CCRGLO=$NA(^TMP("C0CCCR",$J,DFN,"CCR")) ; GLOBAL FOR BUILDING THE CCR
91 S ACTGLO=$NA(^TMP("C0CCCR",$J,DFN,"ACTORS")) ; GLOBAL FOR ALL ACTORS
92 ; TO GET PART OF THE CCR RETURNED, PASS CCRPART="PROBLEMS" ETC
93 ;M CCRGRTN=^TMP("C0CCCR",$J,DFN,CCRPART) ; RTN GLOBAL OF PART OR ALL
94 D LOAD^C0CCCR0(TGLOBAL) ; LOAD THE CCR TEMPLATE
95 D CP^C0CXPATH(TGLOBAL,CCRGLO) ; COPY THE TEMPLATE TO CCR GLOBAL
96 ;
97 ; DELETE THE BODY, ACTORS AND SIGNATURES SECTIONS FROM GLOBAL
98 ; THESE WILL BE POPULATED AFTER CALLS TO THE XPATH ROUTINES
99 D REPLACE^C0CXPATH(CCRGLO,"","//ContinuityOfCareRecord/Body")
100 D REPLACE^C0CXPATH(CCRGLO,"","//ContinuityOfCareRecord/Actors")
101 D REPLACE^C0CXPATH(CCRGLO,"","//ContinuityOfCareRecord/Signatures")
102 I DEBUG F I=1:1:@CCRGLO@(0) W @CCRGLO@(I),!
103 ;
104 D HDRMAP(CCRGLO,DFN) ; MAP HEADER VARIABLES
105 ;
106 K ^TMP("C0CCCR",$J,"CCRSTEP") ; KILL GLOBAL PRIOR TO ADDING TO IT
107 S CCRXTAB=$NA(^TMP("C0CCCR",$J,"CCRSTEP")) ; GLOBAL TO STORE CCR STEPS
108 D INITSTPS(CCRXTAB) ; INITIALIZED CCR PROCESSING STEPS
109 N PROCI,XI,TAG,RTN,CALL,XPATH,IXML,OXML,INXML,CCRBLD
110 F PROCI=1:1:@CCRXTAB@(0) D ; PROCESS THE CCR BODY SECTIONS
111 . S XI=@CCRXTAB@(PROCI) ; CALL COPONENTS TO PARSE
112 . S RTN=$P(XI,";",2) ; NAME OF ROUTINE TO CALL
113 . S TAG=$P(XI,";",1) ; LABEL INSIDE ROUTINE TO CALL
114 . S XPATH=$P(XI,";",3) ; XPATH TO XML TO PASS TO ROUTINE
115 . D QUERY^C0CXPATH(TGLOBAL,XPATH,"INXML") ; EXTRACT XML TO PASS
116 . S IXML="INXML"
117 . S OXML=$P(XI,";",4) ; ARRAY FOR SECTION VALUES
118 . ; K @OXML ; KILL EXPECTED OUTPUT ARRAY
119 . ; W OXML,!
120 . S CALL="D "_TAG_"^"_RTN_"(IXML,DFN,OXML)" ; SETUP THE CALL
121 . W "RUNNING ",CALL,!
122 . X CALL
123 . ; NOW INSERT THE RESULTS IN THE CCR BUFFER
124 . I $G(@OXML@(0))>0 D ; THERE IS A RESULT
125 . . D INSERT^C0CXPATH(CCRGLO,OXML,"//ContinuityOfCareRecord/Body")
126 . . I DEBUG F C0CI=1:1:@OXML@(0) W @OXML@(C0CI),!
127 N ACTT,ATMP,ACTT2,ATMP2 ; TEMPORARY ARRAY SYMBOLS FOR ACTOR PROCESSING
128 D ACTLST^C0CCCR(CCRGLO,ACTGLO) ; GEN THE ACTOR LIST
129 D QUERY^C0CXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","ACTT")
130 D EXTRACT^C0CACTOR("ACTT",ACTGLO,"ACTT2")
131 D INSINNER^C0CXPATH(CCRGLO,"ACTT2","//ContinuityOfCareRecord/Actors")
132 N TRIMI,J,DONE S DONE=0
133 F TRIMI=0:0 D Q:DONE ; DELETE UNTIL ALL EMPTY ELEMENTS ARE GONE
134 . S J=$$TRIM^C0CXPATH(CCRGLO) ; DELETE EMPTY ELEMENTS
135 . I DEBUG W "TRIMMED",J,!
136 . I J=0 S DONE=1 ; DONE WHEN TRIM RETURNS FALSE
137 ;S CCRGRTN=$NA(^TMP("C0CCCR",$J,DFN,CCRPART)) ; RTN GLOBAL OF PART OR ALL
138 M CCRGRTN=^TMP("C0CCCR",$J,DFN,CCRPART) ; RTN GLOBAL OF PART OR ALL
139 I '$D(C0CNRPC) S ^TMP("C0CRPC",$H,"RESULT",CCRGRTN(0))=""
140 ;K ^TMP("C0CCCR",$J) ; BEGIN TO CLEAN UP
141 Q
142 ;
143INITSTPS(TAB) ; INITIALIZE CCR PROCESSING STEPS
144 ; TAB IS PASSED BY NAME
145 I DEBUG W "TAB= ",TAB,!
146 ; ORDER FOR CCR IS PROBLEMS,FAMILYHISTORY,SOCIALHISTORY,MEDICATIONS,VITALSIGNS,RESULTS,HEALTHCAREPROVIDERS
147 D PUSH^C0CXPATH(TAB,"EXTRACT;C0CPROBS;//ContinuityOfCareRecord/Body/Problems;^TMP(""C0CCCR"",$J,DFN,""PROBLEMS"")")
148 I TESTALERT D PUSH^C0CXPATH(TAB,"EXTRACT;C0CALERT;//ContinuityOfCareRecord/Body/Alerts;^TMP(""C0CCCR"",$J,DFN,""ALERTS"")")
149 D PUSH^C0CXPATH(TAB,"EXTRACT;C0CMED;//ContinuityOfCareRecord/Body/Medications;^TMP(""C0CCCR"",$J,DFN,""MEDICATIONS"")")
150 D PUSH^C0CXPATH(TAB,"MAP;C0CIMMU;//ContinuityOfCareRecord/Body/Immunizations;^TMP(""C0CCCR"",$J,DFN,""IMMUNE"")")
151 D PUSH^C0CXPATH(TAB,"EXTRACT;C0CVITAL;//ContinuityOfCareRecord/Body/VitalSigns;^TMP(""C0CCCR"",$J,DFN,""VITALS"")")
152 D PUSH^C0CXPATH(TAB,"MAP;C0CLABS;//ContinuityOfCareRecord/Body/Results;^TMP(""C0CCCR"",$J,DFN,""RESULTS"")")
153 D PUSH^C0CXPATH(TAB,"EXTRACT;C0CPROC;//ContinuityOfCareRecord/Body/Procedures;^TMP(""C0CCCR"",$J,DFN,""PROCEDURES"")")
154 Q
155 ;
156HDRMAP(CXML,DFN) ; MAP HEADER VARIABLES: FROM, TO ECT
157 N VMAP S VMAP=$NA(^TMP("C0CCCR",$J,DFN,"HEADER"))
158 ; K @VMAP
159 S @VMAP@("DATETIME")=$$FMDTOUTC^C0CUTIL($$NOW^XLFDT,"DT")
160 ; I IHDR="" D ; HEADER ARRAY IS NOT PROVIDED, USE DEFAULTS
161 D ; ALWAYS MAP THESE VARIABLES
162 . S @VMAP@("ACTORPATIENT")="ACTORPATIENT_"_DFN
163 . S @VMAP@("ACTORFROM")="ACTORORGANIZATION_"_DUZ ; FROM DUZ - ???
164 . S @VMAP@("ACTORFROM2")="ACTORSYSTEM_1" ; SECOND FROM IS THE SYSTEM
165 . S @VMAP@("ACTORTO")="ACTORPATIENT_"_DFN ; FOR TEST PURPOSES
166 . S @VMAP@("PURPOSEDESCRIPTION")="CEND PHR" ; FOR TEST PURPOSES
167 . S @VMAP@("ACTORTOTEXT")="Patient" ; FOR TEST PURPOSES
168 . ; THIS IS THE USE CASE FOR THE PHR WHERE "TO" IS THE PATIENT
169 ;I IHDR'="" D ; HEADER VALUES ARE PROVIDED
170 ;. D CP^C0CXPATH(IHDR,VMAP) ; COPY HEADER VARIABLES TO MAP ARRAY
171 N CTMP
172 D MAP^C0CXPATH(CXML,VMAP,"CTMP")
173 D CP^C0CXPATH("CTMP",CXML)
174 N HRIMVARS ;
175 S HRIMVARS=$NA(^TMP("C0CRIM","VARS",DFN,"HEADER")) ; TO PERSIST VARS
176 M @HRIMVARS@(1)=@VMAP ; PERSIST THE HEADER VARIABLES IN RIM TABLE
177 S @HRIMVARS@(0)=1 ; ONLY ONE SET OF HEADERS PER PATIENT
178 Q
179 ;
180ACTLST(AXML,ACTRTN) ; RETURN THE ACTOR LIST FOR THE XML IN AXML
181 ; AXML AND ACTRTN ARE PASSED BY NAME
182 ; EACH ACTOR RECORD HAS 3 PARTS - IE IF OBJECTID=ACTORPATIENT_2
183 ; P1= OBJECTID - ACTORPATIENT_2
184 ; P2= OBJECT TYPE - PATIENT OR PROVIDER OR SOFTWARE
185 ;OR INSTITUTION
186 ; OR PERSON(IN PATIENT FILE IE NOK)
187 ; P3= IEN RECORD NUMBER FOR ACTOR - 2
188 N I,J,K,L
189 K @ACTRTN ; CLEAR RETURN ARRAY
190 F I=1:1:@AXML@(0) D ; SCAN ALL LINES
191 . I @AXML@(I)?.E1"<ActorID>".E D ; THERE IS AN ACTOR THIS LINE
192 . . S J=$P($P(@AXML@(I),"<ActorID>",2),"</ActorID>",1)
193 . . I DEBUG W "<ActorID>=>",J,!
194 . . I J'="" S K(J)="" ; HASHING ACTOR
195 . . ; TO GET RID OF DUPLICATES
196 S I="" ; GOING TO $O THROUGH THE HASH
197 F J=0:0 D Q:$O(K(I))=""
198 . S I=$O(K(I)) ; WALK THROUGH THE HASH OF ACTORS
199 . S $P(L,U,1)=I ; FIRST PIECE IS THE OBJECT ID
200 . S $P(L,U,2)=$P($P(I,"ACTOR",2),"_",1) ; ACTOR TYPE
201 . S $P(L,U,3)=$P(I,"_",2) ; IEN RECORD NUMBER FOR ACTOR
202 . D PUSH^C0CXPATH(ACTRTN,L) ; ADD THE ACTOR TO THE RETURN ARRAY
203 Q
204 ;
205TEST ; RUN ALL THE TEST CASES
206 D TESTALL^C0CUNIT("C0CCCR")
207 Q
208 ;
209ZTEST(WHICH) ; RUN ONE SET OF TESTS
210 N ZTMP
211 D ZLOAD^C0CUNIT("ZTMP","C0CCCR")
212 D ZTEST^C0CUNIT(.ZTMP,WHICH)
213 Q
214 ;
215TLIST ; LIST THE TESTS
216 N ZTMP
217 D ZLOAD^C0CUNIT("ZTMP","C0CCCR")
218 D TLIST^C0CUNIT(.ZTMP)
219 Q
220 ;
221 ;;><TEST>
222 ;;><PROBLEMS>
223 ;;>>>K C0C S C0C=""
224 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","PROBLEMS","")
225 ;;>>?@C0C@(@C0C@(0))["</Problems>"
226 ;;><VITALS>
227 ;;>>>K C0C S C0C=""
228 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","VITALS","")
229 ;;>>?@C0C@(@C0C@(0))["</VitalSigns>"
230 ;;><CCR>
231 ;;>>>K C0C S C0C=""
232 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","CCR","")
233 ;;>>?@C0C@(@C0C@(0))["</ContinuityOfCareRecord>"
234 ;;><ACTLST>
235 ;;>>>K C0C S C0C=""
236 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","CCR","")
237 ;;>>>D ACTLST^C0CCCR(C0C,"ACTTEST")
238 ;;><ACTORS>
239 ;;>>>D ZTEST^C0CCCR("ACTLST")
240 ;;>>>D QUERY^C0CXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","G2")
241 ;;>>>D EXTRACT^C0CACTOR("G2","ACTTEST","G3")
242 ;;>>?G3(G3(0))["</Actors>"
243 ;;><TRIM>
244 ;;>>>D ZTEST^C0CCCR("CCR")
245 ;;>>>W $$TRIM^C0CXPATH(CCRGLO)
246 ;;><ALERTS>
247 ;;>>>S TESTALERT=1
248 ;;>>>K C0C S C0C=""
249 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","ALERTS","")
250 ;;>>?@C0C@(@C0C@(0))["</Alerts>"
251
252
Note: See TracBrowser for help on using the repository browser.