source: ccr/trunk/p/C0CCCR.m@ 773

Last change on this file since 773 was 768, checked in by George Lilly, 15 years ago

incorporate UUID for CCRDocumentObjectID
File size: 10.8 KB
Line 
1C0CCCR ; CCDCCR/GPL - CCR MAIN PROCESSING; 6/6/08
2 ;;1.0;C0C;;May 19, 2009;
3 ;Copyright 2008,2009 George Lilly, University of Minnesota.
4 ;Licensed under the terms of the GNU General Public License.
5 ;See attached copy of the License.
6 ;
7 ;This program is free software; you can redistribute it and/or modify
8 ;it under the terms of the GNU General Public License as published by
9 ;the Free Software Foundation; either version 2 of the License, or
10 ;(at your option) any later version.
11 ;
12 ;This program is distributed in the hope that it will be useful,
13 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 ;GNU General Public License for more details.
16 ;
17 ;You should have received a copy of the GNU General Public License along
18 ;with this program; if not, write to the Free Software Foundation, Inc.,
19 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
20 ;
21 ; EXPORT A CCR
22 ;
23EXPORT ; EXPORT ENTRY POINT FOR CCR
24 ; Select a patient.
25 S DIC=2,DIC(0)="AEMQ" D ^DIC
26 I Y<1 Q ; EXIT
27 S DFN=$P(Y,U,1) ; SET THE PATIENT
28 D XPAT(DFN) ; EXPORT TO A FILE
29 Q
30 ;
31XPAT(DFN,XPARMS,DIR,FN) ; EXPORT ONE PATIENT TO A FILE
32 ; DIR IS THE DIRECTORY, DEFAULTS IF NULL TO ^TMP("C0CCCR","ODIR")
33 ; FN IS FILE NAME, DEFAULTS IF NULL
34 N CCRGLO,UDIR,UFN
35 S C0CNRPC=1 ; FLAG FOR NOT AN RPC CALL - FOR DEBUGGING THE RPC
36 I '$D(DIR) S UDIR=""
37 E S UDIR=DIR
38 I '$D(FN) S UFN="" ; IF FILENAME IS NOT PASSED
39 E S UFN=FN
40 I '$D(XPARMS) S XPARMS=""
41 N C0CRTN ; RETURN ARRAY
42 D CCRRPC(.C0CRTN,DFN,XPARMS,"CCR")
43 S OARY=$NA(^TMP("C0CCCR",$J,DFN,"CCR",1))
44 S ONAM=UFN
45 I UFN="" S ONAM="PAT_"_DFN_"_CCR_V1_0_0.xml"
46 S ODIRGLB=$NA(^TMP("C0CCCR","ODIR"))
47 S ^TMP("C0CCCR","FNAME",DFN)=ONAM ; FILE NAME FOR BATCH USE
48 I $D(^TMP("GPLCCR","ODIR")) S @ODIRGLB=^TMP("GPLCCR","ODIR")
49 I '$D(@ODIRGLB) D ; IF NOT ODIR HAS BEEN SET
50 . W "Warning.. please set ^TMP(""C0CCCR"",""ODIR"")=""output path""",! Q
51 . ;S @ODIRGLB="/home/glilly/CCROUT"
52 . ;S @ODIRGLB="/home/cedwards/"
53 . S @ODIRGLB="/opt/wv/p/"
54 S ODIR=UDIR
55 I UDIR="" S ODIR=@ODIRGLB
56 N ZY
57 S ZY=$$OUTPUT^C0CXPATH(OARY,ONAM,ODIR)
58 W !,$P(ZY,U,2),!
59 Q
60 ;
61DCCR(DFN) ; DISPLAY A CCR THAT HAS JUST BEEN EXTRACTED
62 ;
63 N G1
64 S G1=$NA(^TMP("C0CCCR",$J,DFN,"CCR"))
65 I $D(@G1@(0)) D ; CCR EXISTS
66 . D PARY^C0CXPATH(G1)
67 E W "CCR NOT CREATED, RUN D XPAT^C0CCCR(DFN,"""","""") FIRST",!
68 Q
69 ;
70CCRRPC(CCRGRTN,DFN,CCRPARMS,CCRPART) ;RPC ENTRY POINT FOR CCR OUTPUT
71 ; CCRGRTN IS RETURN ARRAY PASSED BY REFERENCE
72 ; DFN IS PATIENT IEN
73 ; CCRPART IS "CCR" FOR ENTIRE CCR, OR SECTION NAME FOR A PART
74 ; OF THE CCR BODY.. PARTS INCLUDE "PROBLEMS" "VITALS" ETC
75 ; CCRPARMS ARE PARAMETERS THAT AFFECT THE EXTRACTION
76 ; IN THE FORM "PARM1:VALUE1^PARM2:VALUE2"
77 ; EXAMPLE: "LABLIMIT:T-60" TO LIMIT LAB EXTRACTION TO THE LAST 60 DAYS
78 ; SEE C0CPARMS FOR A COMPLETE LIST OF SUPPORTED PARAMETERS
79 K ^TMP("C0CCCR",$J) ; CLEAN UP THE GLOBAL BEFORE WE USE IT
80 I '$D(DEBUG) S DEBUG=0
81 S CCD=0 ; NEED THIS FLAG TO DISTINGUISH FROM CCD
82 I '$D(CCRPARMS) S CCRPARMS=""
83 I '$D(CCRPART) S CCRPART="CCR"
84 I '$D(C0CNRPC) S ^TMP("C0CRPC",$H,"CALL",DFN)=""
85 D SET^C0CPARMS(CCRPARMS) ;SET PARAMETERS WITH CCRPARMS AS OVERRIDES
86 I '$D(TESTVIT) S TESTVIT=0 ; FLAG FOR TESTING VITALS
87 I '$D(TESTLAB) S TESTLAB=0 ; FLAG FOR TESTING RESULTS SECTION
88 I '$D(TESTALERT) S TESTALERT=1 ; FLAG FOR TESTING ALERTS SECTION
89 I '$D(TESTMEDS) S TESTMEDS=0 ; FLAG FOR TESTING C0CMED SECTION
90 S TGLOBAL=$NA(^TMP("C0CCCR",$J,"TEMPLATE")) ; GLOBAL FOR STORING TEMPLATE
91 S CCRGLO=$NA(^TMP("C0CCCR",$J,DFN,"CCR")) ; GLOBAL FOR BUILDING THE CCR
92 S ACTGLO=$NA(^TMP("C0CCCR",$J,DFN,"ACTORS")) ; GLOBAL FOR ALL ACTORS
93 ; TO GET PART OF THE CCR RETURNED, PASS CCRPART="PROBLEMS" ETC
94 ;M CCRGRTN=^TMP("C0CCCR",$J,DFN,CCRPART) ; RTN GLOBAL OF PART OR ALL
95 D LOAD^C0CCCR0(TGLOBAL) ; LOAD THE CCR TEMPLATE
96 D CP^C0CXPATH(TGLOBAL,CCRGLO) ; COPY THE TEMPLATE TO CCR GLOBAL
97 ;
98 ; DELETE THE BODY, ACTORS AND SIGNATURES SECTIONS FROM GLOBAL
99 ; THESE WILL BE POPULATED AFTER CALLS TO THE XPATH ROUTINES
100 D REPLACE^C0CXPATH(CCRGLO,"","//ContinuityOfCareRecord/Body")
101 D REPLACE^C0CXPATH(CCRGLO,"","//ContinuityOfCareRecord/Actors")
102 D REPLACE^C0CXPATH(CCRGLO,"","//ContinuityOfCareRecord/Signatures")
103 I DEBUG F I=1:1:@CCRGLO@(0) W @CCRGLO@(I),!
104 ;
105 D HDRMAP(CCRGLO,DFN) ; MAP HEADER VARIABLES
106 ;
107 K ^TMP("C0CCCR",$J,"CCRSTEP") ; KILL GLOBAL PRIOR TO ADDING TO IT
108 S CCRXTAB=$NA(^TMP("C0CCCR",$J,"CCRSTEP")) ; GLOBAL TO STORE CCR STEPS
109 D INITSTPS(CCRXTAB) ; INITIALIZED CCR PROCESSING STEPS
110 N PROCI,XI,TAG,RTN,CALL,XPATH,IXML,OXML,INXML,CCRBLD
111 F PROCI=1:1:@CCRXTAB@(0) D ; PROCESS THE CCR BODY SECTIONS
112 . S XI=@CCRXTAB@(PROCI) ; CALL COPONENTS TO PARSE
113 . S RTN=$P(XI,";",2) ; NAME OF ROUTINE TO CALL
114 . S TAG=$P(XI,";",1) ; LABEL INSIDE ROUTINE TO CALL
115 . S XPATH=$P(XI,";",3) ; XPATH TO XML TO PASS TO ROUTINE
116 . D QUERY^C0CXPATH(TGLOBAL,XPATH,"INXML") ; EXTRACT XML TO PASS
117 . S IXML="INXML"
118 . S OXML=$P(XI,";",4) ; ARRAY FOR SECTION VALUES
119 . ; K @OXML ; KILL EXPECTED OUTPUT ARRAY
120 . ; W OXML,!
121 . S CALL="D "_TAG_"^"_RTN_"(IXML,DFN,OXML)" ; SETUP THE CALL
122 . W "RUNNING ",CALL,!
123 . X CALL
124 . ; NOW INSERT THE RESULTS IN THE CCR BUFFER
125 . I $G(@OXML@(0))>0 D ; THERE IS A RESULT
126 . . D INSERT^C0CXPATH(CCRGLO,OXML,"//ContinuityOfCareRecord/Body")
127 . . I DEBUG F C0CI=1:1:@OXML@(0) W @OXML@(C0CI),!
128 N ACTT,ATMP,ACTT2,ATMP2 ; TEMPORARY ARRAY SYMBOLS FOR ACTOR PROCESSING
129 D ACTLST^C0CCCR(CCRGLO,ACTGLO) ; GEN THE ACTOR LIST
130 D QUERY^C0CXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","ACTT")
131 D EXTRACT^C0CACTOR("ACTT",ACTGLO,"ACTT2")
132 D INSINNER^C0CXPATH(CCRGLO,"ACTT2","//ContinuityOfCareRecord/Actors")
133 N TRIMI,J,DONE S DONE=0
134 F TRIMI=0:0 D Q:DONE ; DELETE UNTIL ALL EMPTY ELEMENTS ARE GONE
135 . S J=$$TRIM^C0CXPATH(CCRGLO) ; DELETE EMPTY ELEMENTS
136 . I DEBUG W "TRIMMED",J,!
137 . I J=0 S DONE=1 ; DONE WHEN TRIM RETURNS FALSE
138 ;S CCRGRTN=$NA(^TMP("C0CCCR",$J,DFN,CCRPART)) ; RTN GLOBAL OF PART OR ALL
139 M CCRGRTN=^TMP("C0CCCR",$J,DFN,CCRPART) ; RTN GLOBAL OF PART OR ALL
140 I '$D(C0CNRPC) S ^TMP("C0CRPC",$H,"RESULT",CCRGRTN(0))=""
141 ;K ^TMP("C0CCCR",$J) ; BEGIN TO CLEAN UP
142 Q
143 ;
144INITSTPS(TAB) ; INITIALIZE CCR PROCESSING STEPS
145 ; TAB IS PASSED BY NAME
146 I DEBUG W "TAB= ",TAB,!
147 ; ORDER FOR CCR IS PROBLEMS,FAMILYHISTORY,SOCIALHISTORY,MEDICATIONS,VITALSIGNS,RESULTS,HEALTHCAREPROVIDERS
148 D PUSH^C0CXPATH(TAB,"EXTRACT;C0CPROBS;//ContinuityOfCareRecord/Body/Problems;^TMP(""C0CCCR"",$J,DFN,""PROBLEMS"")")
149 I TESTALERT D PUSH^C0CXPATH(TAB,"EXTRACT;C0CALERT;//ContinuityOfCareRecord/Body/Alerts;^TMP(""C0CCCR"",$J,DFN,""ALERTS"")")
150 D PUSH^C0CXPATH(TAB,"EXTRACT;C0CMED;//ContinuityOfCareRecord/Body/Medications;^TMP(""C0CCCR"",$J,DFN,""MEDICATIONS"")")
151 D PUSH^C0CXPATH(TAB,"MAP;C0CIMMU;//ContinuityOfCareRecord/Body/Immunizations;^TMP(""C0CCCR"",$J,DFN,""IMMUNE"")")
152 I TESTVIT D PUSH^C0CXPATH(TAB,"EXTRACT;C0CVIT2;//ContinuityOfCareRecord/Body/VitalSigns;^TMP(""C0CCCR"",$J,DFN,""VITALS"")")
153 E D PUSH^C0CXPATH(TAB,"EXTRACT;C0CVITAL;//ContinuityOfCareRecord/Body/VitalSigns;^TMP(""C0CCCR"",$J,DFN,""VITALS"")")
154 D PUSH^C0CXPATH(TAB,"MAP;C0CLABS;//ContinuityOfCareRecord/Body/Results;^TMP(""C0CCCR"",$J,DFN,""RESULTS"")")
155 D PUSH^C0CXPATH(TAB,"EXTRACT;C0CPROC;//ContinuityOfCareRecord/Body/Procedures;^TMP(""C0CCCR"",$J,DFN,""PROCEDURES"")")
156 Q
157 ;
158HDRMAP(CXML,DFN) ; MAP HEADER VARIABLES: FROM, TO ECT
159 N VMAP S VMAP=$NA(^TMP("C0CCCR",$J,DFN,"HEADER"))
160 ; K @VMAP
161 S @VMAP@("DATETIME")=$$FMDTOUTC^C0CUTIL($$NOW^XLFDT,"DT")
162 ; I IHDR="" D ; HEADER ARRAY IS NOT PROVIDED, USE DEFAULTS
163 D ; ALWAYS MAP THESE VARIABLES
164 . S @VMAP@("CCRDOCOBJECTID")=$$UUID^C0CUTIL ; UUID FOR THIS CCR
165 . S @VMAP@("ACTORPATIENT")="ACTORPATIENT_"_DFN
166 . S @VMAP@("ACTORFROM")="ACTORPROVIDER_"_DUZ ; FROM DUZ - FROM PROVIDER
167 . ;S @VMAP@("ACTORFROM")="ACTORORGANIZATION_"_DUZ ; FROM DUZ - ???
168 . S @VMAP@("ACTORFROM2")="ACTORSYSTEM_1" ; SECOND FROM IS THE SYSTEM
169 . S @VMAP@("ACTORTO")="ACTORPATIENT_"_DFN ; FOR TEST PURPOSES
170 . S @VMAP@("PURPOSEDESCRIPTION")="CEND PHR" ; FOR TEST PURPOSES
171 . S @VMAP@("ACTORTOTEXT")="Patient" ; FOR TEST PURPOSES
172 . ; THIS IS THE USE CASE FOR THE PHR WHERE "TO" IS THE PATIENT
173 ;I IHDR'="" D ; HEADER VALUES ARE PROVIDED
174 ;. D CP^C0CXPATH(IHDR,VMAP) ; COPY HEADER VARIABLES TO MAP ARRAY
175 N CTMP
176 D MAP^C0CXPATH(CXML,VMAP,"CTMP")
177 D CP^C0CXPATH("CTMP",CXML)
178 N HRIMVARS ;
179 S HRIMVARS=$NA(^TMP("C0CRIM","VARS",DFN,"HEADER")) ; TO PERSIST VARS
180 M @HRIMVARS@(1)=@VMAP ; PERSIST THE HEADER VARIABLES IN RIM TABLE
181 S @HRIMVARS@(0)=1 ; ONLY ONE SET OF HEADERS PER PATIENT
182 Q
183 ;
184ACTLST(AXML,ACTRTN) ; RETURN THE ACTOR LIST FOR THE XML IN AXML
185 ; AXML AND ACTRTN ARE PASSED BY NAME
186 ; EACH ACTOR RECORD HAS 3 PARTS - IE IF OBJECTID=ACTORPATIENT_2
187 ; P1= OBJECTID - ACTORPATIENT_2
188 ; P2= OBJECT TYPE - PATIENT OR PROVIDER OR SOFTWARE
189 ;OR INSTITUTION
190 ; OR PERSON(IN PATIENT FILE IE NOK)
191 ; P3= IEN RECORD NUMBER FOR ACTOR - 2
192 N I,J,K,L
193 K @ACTRTN ; CLEAR RETURN ARRAY
194 F I=1:1:@AXML@(0) D ; FIRST FIX MISSING LINKS
195 . I @AXML@(I)?.E1"_<".E D ;
196 . . N ZA,ZB
197 . . S ZA=$P(@AXML@(I),">",1)_">"
198 . . S ZB="<"_$P(@AXML@(I),"<",3)
199 . . S @AXML@(I)=ZA_"ACTORORGANIZATION_1"_ZB
200 F I=1:1:@AXML@(0) D ; SCAN ALL LINES
201 . I @AXML@(I)?.E1"<ActorID>".E D ; THERE IS AN ACTOR THIS LINE
202 . . S J=$P($P(@AXML@(I),"<ActorID>",2),"</ActorID>",1)
203 . . I $G(LINKDEBUG) W "<ActorID>=>",J,!
204 . . I J'="" S K(J)="" ; HASHING ACTOR
205 . I @AXML@(I)?.E1"<LinkID>".E D ; THERE IS AN ACTOR THIS LINE
206 . . S J=$P($P(@AXML@(I),"<LinkID>",2),"</LinkID>",1)
207 . . I $G(LINKDEBUG) W "<LinkID>=>",J,!
208 . . I J'="" S K(J)="" ; HASHING ACTOR
209 . . ; TO GET RID OF DUPLICATES
210 S I="" ; GOING TO $O THROUGH THE HASH
211 F J=0:0 D Q:$O(K(I))=""
212 . S I=$O(K(I)) ; WALK THROUGH THE HASH OF ACTORS
213 . S $P(L,U,1)=I ; FIRST PIECE IS THE OBJECT ID
214 . S $P(L,U,2)=$P($P(I,"ACTOR",2),"_",1) ; ACTOR TYPE
215 . S $P(L,U,3)=$P(I,"_",2) ; IEN RECORD NUMBER FOR ACTOR
216 . D PUSH^C0CXPATH(ACTRTN,L) ; ADD THE ACTOR TO THE RETURN ARRAY
217 Q
218 ;
219TEST ; RUN ALL THE TEST CASES
220 D TESTALL^C0CUNIT("C0CCCR")
221 Q
222 ;
223ZTEST(WHICH) ; RUN ONE SET OF TESTS
224 N ZTMP
225 D ZLOAD^C0CUNIT("ZTMP","C0CCCR")
226 D ZTEST^C0CUNIT(.ZTMP,WHICH)
227 Q
228 ;
229TLIST ; LIST THE TESTS
230 N ZTMP
231 D ZLOAD^C0CUNIT("ZTMP","C0CCCR")
232 D TLIST^C0CUNIT(.ZTMP)
233 Q
234 ;
235 ;;><TEST>
236 ;;><PROBLEMS>
237 ;;>>>K C0C S C0C=""
238 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","PROBLEMS","")
239 ;;>>?@C0C@(@C0C@(0))["</Problems>"
240 ;;><VITALS>
241 ;;>>>K C0C S C0C=""
242 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","VITALS","")
243 ;;>>?@C0C@(@C0C@(0))["</VitalSigns>"
244 ;;><CCR>
245 ;;>>>K C0C S C0C=""
246 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","CCR","")
247 ;;>>?@C0C@(@C0C@(0))["</ContinuityOfCareRecord>"
248 ;;><ACTLST>
249 ;;>>>K C0C S C0C=""
250 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","CCR","")
251 ;;>>>D ACTLST^C0CCCR(C0C,"ACTTEST")
252 ;;><ACTORS>
253 ;;>>>D ZTEST^C0CCCR("ACTLST")
254 ;;>>>D QUERY^C0CXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","G2")
255 ;;>>>D EXTRACT^C0CACTOR("G2","ACTTEST","G3")
256 ;;>>?G3(G3(0))["</Actors>"
257 ;;><TRIM>
258 ;;>>>D ZTEST^C0CCCR("CCR")
259 ;;>>>W $$TRIM^C0CXPATH(CCRGLO)
260 ;;><ALERTS>
261 ;;>>>S TESTALERT=1
262 ;;>>>K C0C S C0C=""
263 ;;>>>D CCRRPC^C0CCCR(.C0C,"2","ALERTS","")
264 ;;>>?@C0C@(@C0C@(0))["</Alerts>"
265
266
Note: See TracBrowser for help on using the repository browser.