source: ccr/trunk/p/C0CDIC.m@ 298

Last change on this file since 298 was 298, checked in by George Lilly, 15 years ago

fixes to GET and FIELD to handle duplicate field titles
File size: 9.2 KB
Line 
1C0CDIC ; CCDCCR/GPL - CCR Dictionary utilities; 6/1/08
2 ;;0.1;CCDCCR;nopatch;noreleasedate
3 ;Copyright 2008 WorldVistA. Licensed under the terms of the GNU
4 ;General Public License See attached copy of the License.
5 ;
6 ;This program is free software; you can redistribute it and/or modify
7 ;it under the terms of the GNU General Public License as published by
8 ;the Free Software Foundation; either version 2 of the License, or
9 ;(at your option) any later version.
10 ;
11 ;This program is distributed in the hope that it will be useful,
12 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 ;GNU General Public License for more details.
15 ;
16 ;You should have received a copy of the GNU General Public License along
17 ;with this program; if not, write to the Free Software Foundation, Inc.,
18 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
19 ;
20 W "This is the CCR Dictionary Utility Library ",!
21 W !
22 Q
23 ;
24GVARS(C0CVARS,C0CT) ; Get the CCR variables from the CCR template
25 ; and return them in C0CVARS, which is passed by name
26 ; FIRST PIECE OF C0CVARS(x) IS THE VARIABLE NAME, SECOND PIECE
27 ; IS THE LINE NUMBER OF THE VARIABLE IN THE TEMPLATE
28 ; C0CT IS RETURNED AS THE CCR TEMPLATE
29 N C0CTVARS ; ARRAY FOR THE TEMPLATE AND ARRAY FOR THE VARS
30 D LOAD^GPLCCR0(C0CT) ; LOAD THE CCR TEMPLATE
31 D XVARS^GPLXPATH("C0CTVARS",C0CT) ; PULL OUT THE VARS
32 N C0CI,C0CX
33 S @C0CVARS@(0)=C0CTVARS(0) ; SAME COUNT
34 F C0CI=1:1:C0CTVARS(0) D ; FOR EVERY LINE IN THE ARRAY
35 . S C0CX=C0CTVARS(C0CI) ; THE VARIABLE - 3 PIECES, FIRST ONE NULL
36 . S @C0CVARS@(C0CI)=$P(C0CX,"^",2)_"^"_$P(C0CX,"^",3) ; VAR NAME^LINE NUMBER
37 ;D PARY^GPLXPATH("C0CVARS")
38 Q
39 ;
40GXPATH(C0CPVARS,C0CPT) ; LOAD THE CCR TEMPLATE INTO C0CPT, PULL OUT VARIABLES
41 ; AND THE XPATH TO THE VARIABLES INTO C0CPVARS
42 ; BY INDEXING THE TEMPLATE C0CT AND MATCHING THE XPATH TO THE VARIABLE
43 ; BOTH ARE PASSED BY NAME
44 ; C0CPVARS(x) IS VAR^LINENUM^XPATH SORTED BY LINENUM
45 ; C0CPVARS(0) IS NUMBER OF VARIABLES
46 ; C0CPT(0) IS NUMBER OF LINES IN THE TEMPLATE
47 D GVARS(C0CPVARS,C0CPT) ; GET THE VARIABLES AND LINE NUMBERS
48 ;N C0CTVARS ; HASH TABLE FOR VARIABLE BY LINE NUMBER
49 D HASHV ; PUT THE VARIABLES IN A LINE NUMBER HASH FOR MATCHING TO XPATHS
50 ; NOW GO GET THE XPATH INDEXES
51 D INDEX^GPLXPATH(C0CPT) ; ADD THE XPATH INDEXES TO THE TEMPLATE ARRAY
52 S C0CI="" ; GOING TO LOOP THROUGH THE WHOLE ARRAY LOOKING AT XPATHS
53 F S C0CI=$O(@C0CPT@(C0CI)) Q:C0CI="" D ; VISIT EVERY LINE
54 . I +C0CI'=0 Q ; SKIP EVERYTHING BUT THE XPATH INDEX
55 . I C0CI=0 Q ; SKIP THE ZERO NODE
56 . S C0CX=@C0CPT@(C0CI) ; PULL OUT THE LINE NUMBERS X^Y
57 . S C0CY=$P(C0CX,"^",1) ; STARTING LINE NUMBER
58 . S C0CZ=$P(C0CX,"^",2) ; ENDING LINE NUMBER
59 . I C0CY=C0CZ D ; THIS IS AN XPATH END NODE, HAS A VARIABLE (WE HOPE)
60 . . ; W "FOUND ",C0CI,!
61 . . I $D(C0CTVARS(C0CY)) D ; IF THERE IS A VARIABLE THERE
62 . . . S $P(C0CTVARS(C0CY),"^",3)=C0CI ; INSERT THE XPATH FOR THE VAR
63 D SORTV ; SORT THE ARRAY BY LINE NUMBER
64 Q
65 ;
66HASHV ; INTERNAL ROUTINE TO PUT VARIABLE NAMES IN A LINE NUMBER HASH
67 ;N C0CI,C0CTVARS,C0CX,C0CY
68 F C0CI=1:1:@C0CPVARS@(0) D ; FOR THE ENTIRE ARRAY
69 . S C0CX=$P(@C0CPVARS@(C0CI),"^",2) ; LINE NUMBER
70 . S C0CY=$P(@C0CPVARS@(C0CI),"^",1) ; VARIABLE NAME
71 . S C0CTVARS(C0CX)=C0CY ; BUILD HASH OF VARIABLES BY LINE NUMBER
72 Q
73 ;
74SORTV ; INTERNAL ROUTINE TO OUTPUT VARIABLES (AND XPATHS) IN LINE NUMBER ORDER
75 ;N C0CV2 ; SCRACTH SPACE FOR BUILDING SORTED ARRAY
76 S C0CI="" ;
77 F S C0CI=$O(C0CTVARS(C0CI)) Q:C0CI="" D ; BY LINE NUMBER
78 . S C0CX=C0CTVARS(C0CI) ;VARIABLE NAME
79 . S $P(C0CX,"^",2)=C0CI ; LINE NUMBER IS SECOND PIECE
80 . D PUSH^GPLXPATH("C0C2",C0CX) ; PUT ONTO ARRAY
81 K @C0CPVARS
82 M @C0CPVARS=C0C2
83 Q
84 ;
85LOAD ; LOAD VARIABLE NAMES AND XPATH IN ^C0CDIC(170
86 ; INITIAL LOAD OF THE CCR DICTIONARY
87 ;
88 N C0CDIC,C0CARY,C0CXML,C0CFDA,C0CI
89 S C0CDIC="^C0CDIC(170," ; ROOT OF THE CCR DICTIONARY
90 D GXPATH("C0CARY","C0CXML") ; FETCH THE VARIABLES AND XPATH INTO C0CARY
91 ; C0CXML WILL CONTAIN THE TEMPLATE - NOT NEEDED FOR LOAD
92 D PARY^GPLXPATH("C0CARY") ;TEST
93 F C0CI=1:1:C0CARY(0) D ; LOAD EACH VARIABLE
94 . S C0CFDA(170,"+"_C0CI_",",.01)=$P(C0CARY(C0CI),"^",1) ; VAR NAME
95 . S C0CFDA(170,"+"_C0CI_",",2)=$P(C0CARY(C0CI),"^",3) ; XPATH
96 . D UPDATE^DIE("","C0CFDA")
97 . I $D(^TMP("DIERR",$J)) U $P BREAK
98 . W "LOADING:",C0CI," ",C0CARY(C0CI),!
99 Q
100 ;
101FIELDS(C0CFRTN,C0CF) ; RETURNS AN ARRAY OF THE FIELDS IN FILE C0CF,
102 ; C0CFRTN IS PASSED BY NAME, C0CF IS PASSED BY VALUE
103 ;
104 N C0CFI,C0CFJ ;INNER LOOP, OUTER LOOP
105 N C0CFN ; FIELD NAME
106 S C0CFI=0 S C0CFJ=C0CF
107 K @C0CFRTN ; CLEAR THE RETURN ARRAY
108 F Q:C0CFJ'[C0CF D ; FOR THE C0CF FILE AND ALL SUBFILES INCLUSIVE
109 . ;W "1: "_C0CFJ," ",C0CFI,!
110 . F S C0CFI=$O(^DD(C0CFJ,C0CFI)) Q:+C0CFI=0 D ; EVERY FIELD
111 . . ;W "2: "_C0CFJ," ",C0CFI,!
112 . . S C0CFN=$P(^DD(C0CFJ,C0CFI,0),"^",1) ;PULL FIELD NAME FROM ^DD
113 . . ;W "N: ",C0CFN,!
114 . . ;I C0CFN="STR" W C0CFN," ",C0CFJ,!
115 . . I $D(@C0CFRTN@(C0CFN)) D ; IS THIS A DUPLICATE?
116 . . . W "DUPLICATE FOUND! ",C0CFJ," ",C0CFI," ",C0CFN,!,@C0CFRTN@(C0CFN),!
117 . . . S @C0CFRTN@(C0CFN_"_"_C0CFJ)=C0CFJ_"^"_C0CFI
118 . . E S @C0CFRTN@(C0CFN)=C0CFJ_"^"_C0CFI
119 . S C0CFJ=$O(^DD(C0CFJ)) ; NEXT SUBFILE
120 Q
121 ;
122GET(GRTN,GFILE,GIEN,GNN) ; RETURN THE DICTIONARY RECORD GIEN IN ARRAY GRTN, PASSED
123 ; BY NAME
124 ;
125 ;N C0CTMP,C0CI,C0CJ,C0CREF,C0CNAME
126 I $D(GNN) I GNN="ALL" S C0CNN=0 ; NOT NON-NULL (ALL FIELDS TO BE RETURNED)
127 E S C0CNN=1 ; NON-NULL IS TRUE (ONLY POPULATED FIELDS RETURNED)
128 S C0CREF=GIEN_"," ; OPEN ROOT REFERENCE INTO FILE
129 D GETS^DIQ(GFILE,C0CREF,"**","","C0CTMP")
130 D FIELDS(GRTN,GFILE) ;GET ALL THE FIELD NAMES FOR THE FILE
131 S (C0CI,C0CJ)=""
132 F S C0CJ=$O(C0CTMP(C0CJ)) Q:C0CJ="" D ; FOR ALL SUBFILES
133 . S C0CREF=$O(C0CTMP(C0CJ,"")) ; RECORD REFERENCE
134 . F S C0CI=$O(C0CTMP(C0CJ,C0CREF,C0CI)) Q:C0CI="" D ; ARRAY OF FIELDS
135 . . ;W C0CJ," ",C0CI,!
136 . . S C0CNAME=$P(^DD(C0CJ,C0CI,0),"^",1) ;PULL THE FIELD NAME
137 . . S C0CVALUE=C0CTMP(C0CJ,C0CREF,C0CI) ;
138 . . I C0CVALUE["C0CTMP" S C0CVALUE=C0CTMP(C0CJ,C0CREF,C0CI,1) ;1ST LINE OF WP
139 . . S $P(@GRTN@(C0CNAME),"^",3)=C0CVALUE ;RETURN VALUE IN P3
140 I C0CNN D ; IF ONLY NON-NULL VALUES ARE TO BE RETURNED
141 . S C0CI=""
142 . F S C0CI=$O(@GRTN@(C0CI)) Q:C0CI="" D ; GO THROUGH THE WHOLE ARRAY
143 . . I $P(@GRTN@(C0CI),"^",3)="" K @GRTN@(C0CI) ; KILL THE NULL ENTRIES
144 Q
145 ;
146INIT ; INITIALIZE CCR DICTIONARY BASED ON VARIABLE NAMES
147 ;
148 ; CHEAT SHEET FOR VARIABLE NAMES IN ^C0CDIC(170.xx,
149 ; THIS IS WHAT WILL BE IN C0CA FOR EACH DICTIONARY ENTRY
150 ;G1("CODING")="170^8"
151 ;G1("DATA ELEMENT")="170^7"
152 ;G1("DESCRIPTION")="170^3"
153 ;G1("ID")="170^1"
154 ;G1("M","170^8","CODING")="170.08^.01"
155 ;G1("MAPPING METHOD")="170.08^1"
156 ;G1("SECTION")="170^10"
157 ;G1("SOURCE")="170^4"
158 ;G1("STATUS")="170^9"
159 ;G1("TYPE")="170^6"
160 ;G1("VARIABLE")="170^.01"
161 ;G1("XPATH")="170^2"
162 ;
163 N C0CZA,C0CZX,C0CN,C0CSTAT
164 S C0CZX=0
165 S C0CSTAT=0 ; INIT STATUS SET FLAG
166 F S C0CZX=$O(^C0CDIC(170,C0CZX)) Q:+C0CZX=0 D ; FOR EACH DICT ENTRY
167 . ;W C0CZX,!
168 . K C0CA ; CLEAR OUT THE LAST ONE
169 . D GET("C0CA",170,C0CZX) ; GET VARIABLE HASH
170 . S C0CN=$$ZVALUE("VARIABLE") ;NAME OF THE VARIABLE
171 . I $E(C0CN,1,5)="ACTOR" D SETFDA("SECTION","ACTORS") ;
172 . I $E(C0CN,1,6)="SOCIAL" D ;
173 . . D SETFDA("SECTION","SOCIAL HISTORY") ;
174 . . D SETFDA("STATUS","X") ;SOCIAL HISTORY NOT IMPLEMENTED
175 . . S C0CSTAT=1
176 . I $E(C0CN,1,6)="FAMILY" D ;
177 . . D SETFDA("SECTION","FAMILY HISTORY") ;
178 . . D SETFDA("STATUS","X") ;FAMILY HISTORY NOT IMPLEMENTED
179 . . S C0CSTAT=1
180 . I $E(C0CN,1,5)="ALERT" D SETFDA("SECTION","ALERTS")
181 . I $E(C0CN,1,5)="VITAL" D SETFDA("SECTION","VIT")
182 . I $E(C0CN,1,7)="PROBLEM" D SETFDA("SECTION","PROBLEMS")
183 . I $E(C0CN,1,10)="RESULTTEST" D SETFDA("SECTION","TEST")
184 . E I $E(C0CN,1,6)="RESULT" D SETFDA("SECTION","LABS")
185 . I C0CN["CODEVALUE" D SETFDA("TYPE","CD") ;CODES
186 . I C0CN["CODEVERSION" D SETFDA("TYPE","CV") ; CODE VERSION
187 . I C0CN["CODINGSYSTEM" D SETFDA("TYPE","CS") ;CODING SYSTEM
188 . I $$ZVALUE("STATUS")=""!'C0CSTAT D SETFDA("STATUS","N") ;BLANK STATUS TO N
189 . I $$ZVALUE("XPATH")["/Medication/Directions/" D ; MEDS DIRECTIONS VAR
190 . . D SETFDA("SECTION","DIRECTIONS") ; SPECIAL SECTION FOR DIRECTIONS
191 . E I $$ZVALUE("XPATH")["/Medications/Medication/" D ; ALL OTHER MEDS
192 . . D SETFDA("SECTION","MEDS") ; A MEDS VAR
193 . I $E(C0CN,($L(C0CN)-1),$L(C0CN))="ID" D SETFDA("TYPE","ID") ;CATCH THE IDS
194 . I C0CN["DATETIME" D SETFDA("TYPE","DT") ; DATE/TIME VARIABLE
195 . W "VARIABLE: ",C0CZX," ",C0CA("VARIABLE"),!
196 . ;ZWR C0CFDA
197 . I $D(C0CFDA) D ; WE HAVE CHANGES ON THIS VARIABLE
198 . . ZWR C0CFDA
199 . . D UPDATE^DIE("","C0CFDA(C0CZX)")
200 . . I $D(^TMP("DIERR",$J)) U $P BREAK
201 ; ZWR C0CFDA
202 Q
203 ;
204SETFDA(C0CSN,C0CSV) ; INTERNAL ROUTINE TO MAKE AN FDA ENTRY FOR FIELD C0CSN
205 ; TO SET TO VALUE C0CSV.
206 ; C0CFDA,C0CA,C0CZX ARE ASSUMED FROM THE CALLING ROUTINE
207 ; C0CSN,C0CSV ARE PASSED BY VALUE
208 ;
209 N C0CSI,C0CSJ
210 S C0CSI=$$ZFILE(C0CSN) ; FILE NUMBER
211 S C0CSJ=$$ZFIELD(C0CSN) ; FIELD NUMBER
212 S C0CFDA(C0CZX,C0CSI,C0CZX_",",C0CSJ)=C0CSV
213 Q
214ZFILE(ZFN) ; INTERNAL EXTRINSIC TO RETURN FILE NUMBER FOR FIELD NAME PASSED
215 ; BY VALUE IN ZFN. FILE NUMBER IS PIECE 1 OF C0CA(ZFN)
216 Q $P(C0CA(ZFN),"^",1)
217ZFIELD(ZFN) ;INTERNAL EXTRINSIC TO RETURN FIELD NUMBER FOR FIELD NAME PASSED
218 ; BY VALUE IN ZFN. FILE NUMBER IS PIECE 2 OF C0CA(ZFN)
219 Q $P(C0CA(ZFN),"^",2)
220ZVALUE(ZFN) ;INTERNAL EXTRINSIC TO RETURN VALUE FOR FIELD NAME PASSED
221 ; BY VALUE IN ZFN. FILE NUMBER IS PIECE 3 OF C0CA(ZFN)
222 Q $P(C0CA(ZFN),"^",3)
223 ;
Note: See TracBrowser for help on using the repository browser.