| 1 | C0CENC ; CCDCCR/GPL - CCR/CCD PROCESSING FOR ENCOUNTERS ; 05/21/10
|
|---|
| 2 | ;;1.0;C0C;;May 21, 2010;
|
|---|
| 3 | ;Copyright 2010 George Lilly, University of Minnesota and others.
|
|---|
| 4 | ;Licensed under the terms of the GNU General Public License.
|
|---|
| 5 | ;See attached copy of the License.
|
|---|
| 6 | ;
|
|---|
| 7 | ;This program is free software; you can redistribute it and/or modify
|
|---|
| 8 | ;it under the terms of the GNU General Public License as published by
|
|---|
| 9 | ;the Free Software Foundation; either version 2 of the License, or
|
|---|
| 10 | ;(at your option) any later version.
|
|---|
| 11 | ;
|
|---|
| 12 | ;This program is distributed in the hope that it will be useful,
|
|---|
| 13 | ;but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 14 | ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 15 | ;GNU General Public License for more details.
|
|---|
| 16 | ;
|
|---|
| 17 | ;You should have received a copy of the GNU General Public License along
|
|---|
| 18 | ;with this program; if not, write to the Free Software Foundation, Inc.,
|
|---|
| 19 | ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
|
|---|
| 20 | ;
|
|---|
| 21 | W "NO ENTRY FROM TOP",!
|
|---|
| 22 | Q
|
|---|
| 23 | ;
|
|---|
| 24 | EXTRACT(ENCXML,DFN,ENCOUT) ; EXTRACT ENCOUNTERS INTO XML TEMPLATE
|
|---|
| 25 | ; ENCXML AND ENCOUT ARE PASSED BY NAME SO GLOBALS CAN BE USED
|
|---|
| 26 | ;
|
|---|
| 27 | D SETVARS^C0CPROC ; SET UP VARIABLES FOR PROCEDUCRES, ENCOUNTERS, AND NOTES
|
|---|
| 28 | I '$D(@C0CENC) D TIUGET(DFN,C0CENC,C0CPRC,C0CNTE) ; GET VARS IF NOT THERE
|
|---|
| 29 | D MAP(ENCXML,C0CENC,ENCOUT) ;MAP RESULTS FOR ENCOUNTERS
|
|---|
| 30 | Q
|
|---|
| 31 | ;
|
|---|
| 32 | TIUGET(DFN,C0CENC,C0CPRC,C0CNTE) ; CALLS ENTRY^C0CCPT TO GET PROCEDURES,
|
|---|
| 33 | ; ENCOUNTERS AND NOTES. RETURNS THEM IN RNF2 ARRAYS PASSED BY NAME
|
|---|
| 34 | ; C0CENC: ENCOUNTERS, C0CPRC: PROCEDURES, C0CNTE: NOTES
|
|---|
| 35 | ; READY TO BE MAPPED TO XML BY MAP^C0CENC, MAP^C0CPROC, AND MAP^C0CCMT
|
|---|
| 36 | ; THESE RETURN ARRAYS ARE NOT INITIALIZED, BUT ARE ADDED TO IF THEY
|
|---|
| 37 | ; EXIST. THIS IS SO THAT ADDITIONAL PROCEDURES CAN BE OBTAINED FROM
|
|---|
| 38 | ; THE SURGERY PACKGE AND ADDITIONAL COMMENTS FROM OTHER CCR SECTIONS
|
|---|
| 39 | ;
|
|---|
| 40 | ;K VISIT,LST,NOTE
|
|---|
| 41 | I '$D(C0CPRC) D SETVARS^C0CPROC ; INITIALIZE WORK AREAS IF NOT ALREADY THERE
|
|---|
| 42 | I '$D(VISIT) D ENTRY^C0CCPT(DFN,,,1) ; RETURNS VISIT LOCAL VARIABLE
|
|---|
| 43 | ; NEED TO ADD START AND END DATES FROM PARAMETERS
|
|---|
| 44 | N ZI S ZI=""
|
|---|
| 45 | N PREVCPT,PREVDT S (PREVCPT,PREVDT)=""
|
|---|
| 46 | F S ZI=$O(VISIT(ZI),-1) Q:ZI="" D ; REVERSE TIME ORDER - MOST RECENT FIRST
|
|---|
| 47 | . N ZDATE
|
|---|
| 48 | . S ZDATE=$$DATE(VISIT(ZI,"DATE",0))
|
|---|
| 49 | . S ZPRVARY=$NA(VISIT(ZI,"PRV"))
|
|---|
| 50 | . N ZPRV
|
|---|
| 51 | . S ZPRV=$$PRV(ZPRVARY) ; THE PRIMARY PROVIDER OBJECT IN THE FORM
|
|---|
| 52 | . ; ACTORPROVIDER_IEN WHERE IEN IS THE PROVIDER IEN IN NEW PERSON
|
|---|
| 53 | . ; ENCOBJECTID - ENCOUNTER OBJECT ID
|
|---|
| 54 | . ; ENCDATETIME - ENCOUNTER DATE TIME
|
|---|
| 55 | . ; ENCTYPETXT - ENCOUNTER TYPE (PLANNING TO USE ADMINISTRATIVE CPT IF AVAIL)
|
|---|
| 56 | . ; ENCTYPECODE - CODE OF TYPE - PLANNING CPT CODE
|
|---|
| 57 | . ; ENCTYPECODESYS - CODING SYSTEM OF TYPE - CPT-4
|
|---|
| 58 | . ; ENCDESCTXT - ENCOUNTER DESCRIPTION TEXT
|
|---|
| 59 | . ; ENCDESCCODE - ENCOUNTER DESCRIPTION CODE
|
|---|
| 60 | . ; ENCDESCCODESYS - ENCOUNTER DESCRIPTION CODE SYSTEM
|
|---|
| 61 | . ; ENCLOCACTORID - ENCOUNTER LOCATION ACTOR ID
|
|---|
| 62 | . ; ENCPRVACTORID - ENCOUNTER PRACTIONER ACTOR ID
|
|---|
| 63 | . ; ENCINDTXT - ENCOUNTER INDICATION TEXT
|
|---|
| 64 | . ; ENCINDCODE - ENCOUNTER INDICATION CODE
|
|---|
| 65 | . ; ENCINDCODESYS - ENCOUNTER INDICATION CODE SYSTEM
|
|---|
| 66 | . ; ENCACTORID - ENCOUNTER SOURCE ACTOR ID
|
|---|
| 67 | . ; ENCCOMMENTID - ENCOUNTER COMMENT ID - POINTER TO NOTE IN COMMENT SECTION
|
|---|
| 68 | . S ZRNF("ENCOBJECTID")="ENCOUNTER_"_ZI
|
|---|
| 69 | . S ZRNF("ENCDATETIME")=ZDATE ; ENCOUNTER DATE TIME
|
|---|
| 70 | . S ZRNF("ENCTYPETXT")=""
|
|---|
| 71 | . S ZRNF("ENCTYPECODE")=""
|
|---|
| 72 | . S ZRNF("ENCTYPECODESYS")=""
|
|---|
| 73 | . S ZRNF("ENCDESCTXT")=""
|
|---|
| 74 | . S ZRNF("ENCDESCCODE")=""
|
|---|
| 75 | . S ZRNF("ENCDESCCODESYS")=""
|
|---|
| 76 | . N TYPTXT,TYPCDE,TYPSYS ; WILL BE UPDATED BY GETTYPE CALL
|
|---|
| 77 | . I $$GETTYPE("VISIT(ZI)",.TYPTXT,.TYPCDE,.TYPSYS) D ; RETURNS FALSE IF NO TYPE
|
|---|
| 78 | . . S ZRNF("ENCTYPETXT")=TYPTXT
|
|---|
| 79 | . . S ZRNF("ENCTYPECODE")=TYPCDE
|
|---|
| 80 | . . S ZRNF("ENCTYPECODESYS")=TYPSYS
|
|---|
| 81 | . . S ZRNF("ENCDESCTXT")=TYPTXT ; FOR NOW, DESCRIPTION IS SAME AS TYPE
|
|---|
| 82 | . . S ZRNF("ENCDESCCODE")=TYPCDE ; DESCRIPTION IS REQUIRED (TYPE IS NOT)
|
|---|
| 83 | . . S ZRNF("ENCDESCCODESYS")=TYPSYS ; NEED TO CLARIFY FOR VISTA
|
|---|
| 84 | . S ZRNF("ENCLOCACTORID")="ACTORORGANIZATION_1"
|
|---|
| 85 | . S ZRNF("ENCPRVACTORID")=ZPRV ; PRIMARY PROVIDER LISTED FOR THE ENCOUNTER
|
|---|
| 86 | . S ZRNF("ENCINDTXT")="" ; WE WILL PUT POINTERS TO PROBLEMS HERE
|
|---|
| 87 | . S ZRNF("ENCINDCODE")=""
|
|---|
| 88 | . S ZRNF("ENCINDCODESYS")=""
|
|---|
| 89 | . S ZRNF("ENCACTORID")=ZPRV ; SOURCE WILL BE PRIMARY PROVIDER
|
|---|
| 90 | . S ZRNF("ENCCOMMENTID")=""
|
|---|
| 91 | . I $G(VISIT(ZI,"TEXT",1))'="" D ; THERE IS A NOTE
|
|---|
| 92 | . . M @C0CNTE@(ZI,"TEXT")=VISIT(ZI,"TEXT") ; COPY THE TEXT OF THE NOTE
|
|---|
| 93 | . . S @C0CNTE@(ZI,"COMMENTOBJECTID")="NOTE_"_ZI
|
|---|
| 94 | . . S @C0CNTE@(ZI,"CMTDATETIME")=ZDATE ; DATE OF THE NOTE
|
|---|
| 95 | . . S @C0CNTE@(ZI,"ACTORSOURCEID")=ZPRV ; SOURCE OF THE NOTE
|
|---|
| 96 | . . S ZRNF("ENCCOMMENTID")="NOTE_"_ZI ; POINT TO THE NOTE FROM THE ENCOUNTER
|
|---|
| 97 | . D RNF1TO2^C0CRNF(C0CENC,"ZRNF") ; ADD THIS ROW TO THE ARRAY
|
|---|
| 98 | . ;S PREVCPT=ZCPT
|
|---|
| 99 | . ;S PREVDT=ZDATE
|
|---|
| 100 | N ZRIM S ZRIM=$NA(^TMP("C0CRIM","VARS",DFN,"ENCOUNTERS"))
|
|---|
| 101 | M @ZRIM=@C0CENC@("V")
|
|---|
| 102 | K VISIT,LST,NOTE
|
|---|
| 103 | Q
|
|---|
| 104 | ;
|
|---|
| 105 | GETTYPE(ZARY,ZTXT,ZCDE,ZSYS) ; EXTRINSIC WHICH RETURNS FALSE IF NO ENCOUNTER TYPE
|
|---|
| 106 | ; UPDATES ZTXT WITH ENCOUNTER TYPE TEXT, ZCDE WITH ENCOUNTER TYPE CODE
|
|---|
| 107 | ; AND ZSYS WITH ENCOUNTER TYPE CODING SYSTEM
|
|---|
| 108 | ; THIS ROUTINE SHOULD BE UPDATED TO SEARCH FOR AN ADMINISTRATIVE CPT CODE
|
|---|
| 109 | ; INSTEAD OF JUST THE FIRST ONE IN THE LIST - GPL 1/23/10
|
|---|
| 110 | N ZS,ZC
|
|---|
| 111 | S ZC=$O(@ZARY@("CPT","")) ; FIRST CPT IN THE VISIT
|
|---|
| 112 | S ZS=$G(@ZARY@("CPT",ZC)) ; PIECES OF THE FIRST CPT
|
|---|
| 113 | I ZS="" Q 0 ; OOPS NO TEXT FOR THE TYPE QUIT
|
|---|
| 114 | S ZTXT=$P(ZS,U,3) ; TEXT OF THE FIRST CPT
|
|---|
| 115 | I ZTXT="" Q 0 ; NO ENCOUNTER TYPE FOUND
|
|---|
| 116 | S ZCDE=$P($$CPT^C0CPROC(ZS),U,1) ; CPT CODE FOR ENCOUTER
|
|---|
| 117 | S ZSYS=""
|
|---|
| 118 | I ZCDE'="" S ZSYS="CPT-4" ; ONLY HAVE A CODING SYSTEM IF THERE IS A CODE
|
|---|
| 119 | Q 1 ; SUCCESS
|
|---|
| 120 | ;
|
|---|
| 121 | PRV(IARY) ; RETURNS THE PRIMARY PROVIDER FROM THE "PRV" ARRAY PASSED BY NAME
|
|---|
| 122 | N ZI,ZR,ZRTN S ZI="" S ZR="" S ZRTN=""
|
|---|
| 123 | F S ZI=$O(@IARY@(ZI)) Q:ZI="" D ; FOR EACH PRV SEG
|
|---|
| 124 | . I ZR'="" Q ;ONLY WANT THE FIRST PRIMARY PROVIDER
|
|---|
| 125 | . I $P(@IARY@(ZI),U,5)=1 S ZR=$P(@IARY@(ZI),U,1)
|
|---|
| 126 | I ZR'="" S ZRTN="ACTORPROVIDER_"_ZR
|
|---|
| 127 | Q ZRTN
|
|---|
| 128 | ;
|
|---|
| 129 | DATE(ISTR) ; EXTRINSIC TO RETURN THE DATE IN CCR FORMAT
|
|---|
| 130 | Q $$FMDTOUTC^C0CUTIL(ISTR,"DT")
|
|---|
| 131 | ;
|
|---|
| 132 | CPT(ISTR) ; EXTRINSIC THAT SEARCHES FOR CPT CODES AND RETURNS
|
|---|
| 133 | ; CPT^CATEGORY^TEXT
|
|---|
| 134 | N Z1,Z2,Z3,ZRTN
|
|---|
| 135 | S Z1=$P(ISTR,U,1)
|
|---|
| 136 | I Z1="" D ;
|
|---|
| 137 | . I ISTR["(CPT-4 " S Z1=$P($P(ISTR,"(CPT-4 ",2),")",1)
|
|---|
| 138 | I Z1'="" D ; IF THERE IS A CPT CODE IN THERE
|
|---|
| 139 | . ;S Z1=$P(ISTR,U,1)
|
|---|
| 140 | . S Z2=$P(ISTR,U,2)
|
|---|
| 141 | . S Z3=$P(ISTR,U,3)
|
|---|
| 142 | . S ZRTN=Z1_U_Z2_U_Z3
|
|---|
| 143 | E S ZRTN=""
|
|---|
| 144 | Q ZRTN
|
|---|
| 145 | ;
|
|---|
| 146 | MAP(ENCXML,C0CENC,ENCOUT) ; MAP PROCEDURES XML
|
|---|
| 147 | ;
|
|---|
| 148 | N ZTEMP S ZTEMP=$NA(^TMP("C0CCCR",$J,DFN,"ENCTEMP")) ;WORK AREA FOR TEMPLATE
|
|---|
| 149 | K @ZTEMP
|
|---|
| 150 | N ZBLD
|
|---|
| 151 | S ZBLD=$NA(^TMP("C0CCCR",$J,DFN,"ENCBLD")) ; BUILD LIST AREA
|
|---|
| 152 | D QUEUE^C0CXPATH(ZBLD,ENCXML,1,1) ; FIRST LINE
|
|---|
| 153 | N ZINNER
|
|---|
| 154 | D QUERY^C0CXPATH(ENCXML,"//Encounters/Encounter","ZINNER") ;ONE ENCOUNTER
|
|---|
| 155 | N ZTMP,ZVAR,ZI
|
|---|
| 156 | S ZI=""
|
|---|
| 157 | F S ZI=$O(@C0CENC@("V",ZI)) Q:ZI="" D ;FOR EACH ENCOUNTER
|
|---|
| 158 | . S ZTMP=$NA(@ZTEMP@(ZI)) ;THIS ENCOUNTER XML
|
|---|
| 159 | . S ZVAR=$NA(@C0CENC@("V",ZI)) ;THIS ENCOUNTER VARIABLES
|
|---|
| 160 | . D MAP^C0CXPATH("ZINNER",ZVAR,ZTMP) ; MAP THE PROCEDURE
|
|---|
| 161 | . D QUEUE^C0CXPATH(ZBLD,ZTMP,1,@ZTMP@(0)) ;QUE FOR BUILD
|
|---|
| 162 | D QUEUE^C0CXPATH(ZBLD,ENCXML,@ENCXML@(0),@ENCXML@(0))
|
|---|
| 163 | N ZZTMP
|
|---|
| 164 | D BUILD^C0CXPATH(ZBLD,ENCOUT) ;BUILD FINAL XML
|
|---|
| 165 | K @ZTEMP,@ZBLD,@C0CENC
|
|---|
| 166 | Q
|
|---|
| 167 | ; |
|---|
