source: ccr/trunk/p/C0CMED1.m@ 421

Last change on this file since 421 was 421, checked in by Sam Habiel, 15 years ago

Refactor of Med Routines, part 1
File size: 10.6 KB
Line 
1C0CMED1 ; WV/CCDCCR/SMH - CCR/CCD PROCESSING FOR MEDICATIONS ;01/10/09
2 ;;0.1;CCDCCR;;JUL 16,2008;
3 ;;Last modified Sat Jan 10 21:42:27 PST 2009
4 ; Copyright 2009 WorldVistA. Licensed under the terms of the GNU
5 ; General Public License See attached copy of the License.
6 ;
7 ; This program is free software; you can redistribute it and/or modify
8 ; it under the terms of the GNU General Public License as published by
9 ; the Free Software Foundation; either version 2 of the License, or
10 ; (at your option) any later version.
11 ;
12 ; This program is distributed in the hope that it will be useful,
13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 ; GNU General Public License for more details.
16 ;
17 ; You should have received a copy of the GNU General Public License along
18 ; with this program; if not, write to the Free Software Foundation, Inc.,
19 ; 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
20 ;
21 W "NO ENTRY FROM TOP",!
22 Q
23 ;
24EXTRACT(MINXML,DFN,OUTXML,MEDCOUNT) ; EXTRACT MEDICATIONS INTO PROVIDED XML TEMPLATE
25 ;
26 ; INXML AND OUTXML ARE PASSED BY NAME SO GLOBALS CAN BE USED
27 ; INXML WILL CONTAIN ONLY THE MEDICATIONS SECTION OF THE OVERALL TEMPLATE
28 ;
29 ; MEDS is return array from RPC.
30 ; MAP is a mapping variable map (store result) for each med
31 ; MED is holds each array element from MEDS(J), one medicine
32 ; MEDCOUNT is a counter passed by Reference.
33 ;
34 ; RX^PSO52API is a Pharmacy Re-Enginnering (PRE) API to get all
35 ; med data available.
36 ; http://www.va.gov/vdl/documents/Clinical/Pharm-Outpatient_Pharmacy/phar_1_api_r0807.pdf
37 ; Output of API is ^TMP($J,"SUBSCRIPT",DFN,RXIENS).
38 ; D PARY^C0CXPATH(MINXML)
39 N MEDS,MAP
40 K ^TMP($J,"CCDCCR") ; PLEASE DON'T KILL ALL OF ^TMP($J) HERE!!!!
41 D RX^PSO52API(DFN,"CCDCCR")
42 M MEDS=^TMP($J,"CCDCCR",DFN)
43 ; @(0) contains the number of meds or -1^NO DATA FOUND
44 ; If it is -1, we quit.
45 I $P(MEDS(0),U)=-1 S @OUTXML@(0)=0 QUIT
46 ZWRITE:$G(DEBUG) MEDS
47 N RXIEN S RXIEN=0
48 F S RXIEN=$O(MEDS(RXIEN)) Q:RXIEN="" D ; FOR EACH MEDICATION IN THE LIST
49 . S MEDCOUNT=MEDCOUNT+1
50 . W:$G(DEBUG) "RXIEN IS ",RXIEN,!
51 . S MAP=$NA(^TMP("C0CCCR",$J,"MEDMAP",MEDCOUNT))
52 . ; K @MAP DO NOT KILL HERE, WAS CLEARED IN C0CMED
53 . W:$G(DEBUG) "MAP= ",MAP,!
54 . N MED M MED=MEDS(RXIEN) ; PULL OUT MEDICATION FROM
55 . S @MAP@("MEDOBJECTID")="MED"_MEDCOUNT ; MEDCOUNT FOR ID
56 . ; S @MAP@("MEDOBJECTID")="MED"_MED(.01) ;Rx Number
57 . S @MAP@("MEDISSUEDATETXT")="Issue Date"
58 . S @MAP@("MEDISSUEDATE")=$$FMDTOUTC^C0CUTIL($P(MED(1),U))
59 . S @MAP@("MEDLASTFILLDATETXT")="Last Fill Date"
60 . S @MAP@("MEDLASTFILLDATE")=$$FMDTOUTC^C0CUTIL($P(MED(101),U))
61 . S @MAP@("MEDRXNOTXT")="Prescription Number"
62 . S @MAP@("MEDRXNO")=MED(.01)
63 . S @MAP@("MEDTYPETEXT")="Medication"
64 . S @MAP@("MEDDETAILUNADORNED")="" ; Leave blank, field has its uses
65 . S @MAP@("MEDSTATUSTEXT")=$P(MED(100),U,2)
66 . S @MAP@("MEDSOURCEACTORID")="ACTORPROVIDER_"_$P(MED(4),U)
67 . S @MAP@("MEDPRODUCTNAMETEXT")=$P(MED(6),U,2)
68 . ; 12/30/08: I will be using RxNorm for coding...
69 . ; 176.001 is the file for Concepts; 176.003 is the file for
70 . ; sources (i.e. for RxNorm Version)
71 . ;
72 . ; We need the VUID first for the National Drug File entry first
73 . ; We get the VUID of the drug, by looking up the VA Product entry
74 . ; (file 50.68) using the call NDF^PSS50, returned in node 22.
75 . ; Field 99.99 is the VUID.
76 . ;
77 . ; We use the VUID to look up the RxNorm in file 176.001; same idea.
78 . ; Get IEN first using $$FIND1^DIC, then get the RxNorm number by
79 . ; $$GET1^DIQ.
80 . ;
81 . ; I get the RxNorm name and version from the RxNorm Sources (file
82 . ; 176.003), by searching for "RXNORM", then get the data.
83 . N MEDIEN S MEDIEN=$P(MED(6),U)
84 . D NDF^PSS50(MEDIEN,,,,,"NDF")
85 . N NDFDATA M NDFDATA=^TMP($J,"NDF",MEDIEN)
86 . N NDFIEN S NDFIEN=$P(NDFDATA(20),U)
87 . N VAPROD S VAPROD=$P(NDFDATA(22),U)
88 . ;
89 . ; NDFIEN is not necessarily defined; it won't be if the drug
90 . ; is not matched to the national drug file (e.g. if the drug is
91 . ; new on the market, compounded, or is a fake drug [blue pill].
92 . ; To protect against failure, I will put an if/else block
93 . ;
94 . N VUID,RXNIEN,RXNORM,SRCIEN,RXNNAME,RXNVER
95 . I NDFIEN,$D(^C0CRXN) D ; $Data is for Systems that don't have our RxNorm file yet.
96 . . S VUID=$$GET1^DIQ(50.68,VAPROD,99.99)
97 . . S RXNIEN=$$FIND1^DIC(176.001,,,VUID,"VUID")
98 . . S RXNORM=$$GET1^DIQ(176.001,RXNIEN,.01)
99 . . S SRCIEN=$$FIND1^DIC(176.003,,"B","RXNORM")
100 . . S RXNNAME=$$GET1^DIQ(176.003,SRCIEN,6)
101 . . S RXNVER=$$GET1^DIQ(176.003,SRCIEN,7)
102 . ;
103 . E S (RXNORM,RXNNAME,RXNVER)=""
104 . ; End if/else block
105 . S @MAP@("MEDPRODUCTNAMECODEVALUE")=RXNORM
106 . S @MAP@("MEDPRODUCTNAMECODINGINGSYSTEM")=RXNNAME
107 . S @MAP@("MEDPRODUCTNAMECODEVERSION")=RXNVER
108 . ;
109 . S @MAP@("MEDBRANDNAMETEXT")=MED(6.5)
110 . D DOSE^PSS50(MEDIEN,,,,,"DOSE")
111 . N DOSEDATA M DOSEDATA=^TMP($J,"DOSE",MEDIEN)
112 . S @MAP@("MEDSTRENGTHVALUE")=DOSEDATA(901)
113 . S @MAP@("MEDSTRENGTHUNIT")=$P(DOSEDATA(902),U,2)
114 . ; Units, concentration, etc, come from another call
115 . ; $$CPRS^PSNAPIS which returns dosage-form^va class^strengh^unit
116 . ; This call takes nodes 1 and 3 of ^PSDRUG(D0,"ND") as parameters
117 . ; NDF Entry IEN, and VA Product IEN
118 . ; These can be obtained using NDF^PSS50 (IEN,,,,,"SUBSCRIPT")
119 . ; These have been collected above.
120 . N CONCDATA
121 . ; If a drug was not matched to NDF, then the NDFIEN is gonna be ""
122 . ; and this will crash the call. So...
123 . I NDFIEN="" S CONCDATA=""
124 . E S CONCDATA=$$CPRS^PSNAPIS(NDFIEN,VAPROD)
125 . S @MAP@("MEDFORMTEXT")=$P(CONCDATA,U,1)
126 . S @MAP@("MEDCONCVALUE")=$P(CONCDATA,U,3)
127 . S @MAP@("MEDCONCUNIT")=$P(CONCDATA,U,4)
128 . S @MAP@("MEDQUANTITYVALUE")=MED(7)
129 . ; Oddly, there is no easy place to find the dispense unit.
130 . ; It's not included in the original call, so we have to go to the drug file.
131 . ; That would be DATA^PSS50(IEN,,,,,"SUBSCRIPT")
132 . ; Node 14.5 is the Dispense Unit
133 . D DATA^PSS50(MEDIEN,,,,,"QTY")
134 . N QTYDATA M QTYDATA=^TMP($J,"QTY",MEDIEN)
135 . S @MAP@("MEDQUANTITYUNIT")=QTYDATA(14.5)
136 . ;
137 . ; --- START OF DIRECTIONS ---
138 . ; Sig data not in any API :-( Oh yes, you can get the whole thing, but...
139 . ; we want the compoenents.
140 . ; It's in node 6 of ^PSRX(IEN)
141 . ; So, here we go again
142 . ; ^PSRX(D0,6,D1,0)= (#.01) DOSAGE ORDERED [1F] ^ (#1) DISPENSE UNITS PER DOSE
143 . ; ==>[2N] ^ (#2) UNITS [3P:50.607] ^ (#3) NOUN [4F] ^ (#4)
144 . ; ==>DURATION [5F] ^ (#5) CONJUNCTION [6S] ^ (#6) ROUTE
145 . ; ==>[7P:51.2] ^ (#7) SCHEDULE [8F] ^ (#8) VERB [9F] ^
146 . ;
147 . N DIRNUM S DIRNUM=0 ; Sigline number
148 . S DIRCNT=0 ; COUNT OF MULTIPLE DIRECTIONS
149 . F S DIRNUM=$O(^PSRX(RXIEN,6,DIRNUM)) Q:DIRNUM="" D
150 . . S DIRCNT=DIRCNT+1 ; INCREMENT DIRECTIONS COUNT
151 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRECTIONDESCRIPTIONTEXT")="" ; This is reserved for systems not able to generate the sig in components.
152 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEINDICATOR")="1" ; means that we are specifying it. See E2369-05.
153 . . N SIGDATA S SIGDATA=^PSRX(RXIEN,6,DIRNUM,0)
154 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDELIVERYMETHOD")=$P(SIGDATA,U,9)
155 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEVALUE")=$P(SIGDATA,U,1)
156 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEUNIT")=@MAP@("MEDCONCUNIT")
157 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDRATEVALUE")="" ; For inpatient
158 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDRATEUNIT")="" ; For inpatient
159 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDVEHICLETEXT")="" ; For inpatient
160 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRECTIONROUTETEXT")=$$GET1^DIQ(51.2,$P(SIGDATA,U,7),.01)
161 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDFREQUENCYVALUE")=$P(SIGDATA,U,8)
162 . . ; Invervals... again another call.
163 . . ; In the wisdom of the original programmers, the schedule is a free text field
164 . . ; However, it gets translated by a call to the administration schedule file
165 . . ; to see if that schedule exists.
166 . . ; That's the same thing I am going to do.
167 . . ; The call is AP^PSS51P1(PSSPP,PSSFT,PSSWDIEN,PSSSTPY,LIST,PSSFREQ).
168 . . ; PSSPP is "PSJ" (for some reason, schedules are stored as PSJ, not PSO--
169 . . ; I looked), PSSFT is the name, and list is the ^TMP name to store the data in.
170 . . ; So...
171 . . D AP^PSS51P1("PSJ",$P(SIGDATA,U,8),,,"SCHEDULE")
172 . . N SCHEDATA M SCHEDATA=^TMP($J,"SCHEDULE")
173 . . N INTERVAL
174 . . I $P(SCHEDATA(0),U)=-1 S INTERVAL=""
175 . . E D
176 . . . N SUB S SUB=$O(SCHEDATA(0))
177 . . . S INTERVAL=SCHEDATA(SUB,2)
178 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDINTERVALVALUE")=INTERVAL
179 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDINTERVALUNIT")="Minute"
180 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONVALUE")=$P(SIGDATA,U,5)
181 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONUNIT")=""
182 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPRNFLAG")=$P(SIGDATA,U,8)["PRN"
183 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMOBJECTID")=""
184 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMTYPETXT")=""
185 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMDESCRIPTION")=""
186 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODEVALUE")=""
187 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODINGSYSTEM")=""
188 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODINGVERSION")=""
189 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMSOURCEACTORID")=""
190 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDSTOPINDICATOR")=""
191 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRSEQ")=DIRNUM
192 . . N DIRMOD S DIRMOD=$P(SIGDATA,U,6)
193 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDMULDIRMOD")=$S(DIRMOD="T":"THEN",DIRMOD="A":"AND",DIRMOD="X":"EXCEPT",1:"")
194 . ;
195 . ; --- END OF DIRECTIONS ---
196 . ;
197 . ; ^PSRX(22,"INS1",1,0)="FOR BLOOD PRESSURE"
198 . S @MAP@("MEDPTINSTRUCTIONS")=$G(^PSRX(RXIEN,"INS1",1,0))
199 . ; ^PSRX(22,"PRC",1,0)="Pharmacist: you must obey my command"
200 . S @MAP@("MEDFULLFILLMENTINSTRUCTIONS")=$G(^PSRX(RXIEN,"PRC",1,0))
201 . S @MAP@("MEDRFNO")=MED(9)
202 . N RESULT S RESULT=$NA(^TMP("C0CCCR",$J,"MAPPED"))
203 . K @RESULT
204 . D MAP^C0CXPATH(MINXML,MAP,RESULT)
205 . ; MAPPING DIRECTIONS
206 . N DIRXML1 S DIRXML1="MEDDIR1" ; VARIABLE AND NAME VARIABLE TEMPLATE
207 . N DIRXML2 S DIRXML2="MEDDIR2" ; VARIABLE AND NAME VARIABLE RESULT
208 . D QUERY^C0CXPATH(MINXML,"//Medications/Medication/Directions",DIRXML1)
209 . D REPLACE^C0CXPATH(RESULT,"","//Medications/Medication/Directions")
210 . ; N MDZ1,MDZNA
211 . I DIRCNT>0 D ; IF THERE ARE DIRCTIONS
212 . . F MDZ1=1:1:DIRCNT D ; FOR EACH DIRECTION
213 . . . S MDZNA=$NA(@MAP@("M","DIRECTIONS",MDZ1))
214 . . . D MAP^C0CXPATH(DIRXML1,MDZNA,DIRXML2)
215 . . . D INSERT^C0CXPATH(RESULT,DIRXML2,"//Medications/Medication")
216 . I MEDCOUNT=1 D CP^C0CXPATH(RESULT,OUTXML) ; First one is a copy
217 . E D INSINNER^C0CXPATH(OUTXML,RESULT) ; AFTER FIRST, INSERT INNER XML
218 N MEDTMP,MEDI
219 D MISSING^C0CXPATH(OUTXML,"MEDTMP") ; SEARCH XML FOR MISSING VARS
220 I MEDTMP(0)>0 D ; IF THERE ARE MISSING VARS - MARKED AS @@X@@
221 . W "MEDICATION MISSING ",!
222 . F MEDI=1:1:MEDTMP(0) W MEDTMP(MEDI),!
223 Q
224 ;
Note: See TracBrowser for help on using the repository browser.