source: ccr/trunk/p/C0CMED6.m@ 1736

Last change on this file since 1736 was 1586, checked in by Sam Habiel, 12 years ago

Changed license to AGPL. Some clean-up for XINDEX
  • Property svn:mergeinfo set to (toggle deleted branches)
    /ccr/branches/ohum/o-old/p/C0CMED6.m1290
    /ccr/branches/ohum/p/C0CMED6.m1291-1543
    /ccr/branches/ohum/p/p/C0CMED6.m1287-1289
File size: 15.2 KB
Line 
1C0CMED6 ; WV/CCDCCR/SMH - Meds from RPMS: Outpatient Meds;01/10/09
2 ;;1.2;CCD/CCR GENERATION UTILITIES;;Oct 30, 2012;Build 50
3 ; Copyright 2008 WorldVistA.
4 ;
5 ; This program is free software: you can redistribute it and/or modify
6 ; it under the terms of the GNU Affero General Public License as
7 ; published by the Free Software Foundation, either version 3 of the
8 ; License, or (at your option) any later version.
9 ;
10 ; This program is distributed in the hope that it will be useful,
11 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
12 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
13 ; GNU Affero General Public License for more details.
14 ;
15 ; You should have received a copy of the GNU Affero General Public License
16 ; along with this program. If not, see <http://www.gnu.org/licenses/>.
17 ;
18 W "NO ENTRY FROM TOP",!
19 Q
20 ;
21EXTRACT(MINXML,DFN,OUTXML,MEDCOUNT,FLAGS) ; EXTRACT MEDICATIONS INTO PROVIDED XML TEMPLATE
22 ;
23 ; MINXML and OUTXML are passed by name so globals can be used
24 ; MINXML will contain only the medications skeleton of the overall template
25 ; MEDCOUNT is a counter passed by Reference.
26 ; FLAGS are: MEDALL(bool)^MEDLIMIT(int)^MEDACTIVE(bool)^MEDPENDING(bool)
27 ; FLAGS are set-up in C0CMED.
28 ;
29 ; MEDS is return array from RPC.
30 ; MAP is a mapping variable map (store result) for each med
31 ; MED is holds each array element from MEDS(J), one medicine
32 ; J is a counter.
33 ;
34 ; GETRXS^BEHORXFN(ARRAYNAME,DFN,DAYS) will be the the API used.
35 ; This API has been developed by Medsphere for IHS for getting
36 ; Medications from RPMS. It has most of what we need.
37 ; API written by Doug Martin when he worked for Medsphere (thanks Doug!)
38 ; -- ARRAYNAME is passed by name (required)
39 ; -- DFN is passed by value (required)
40 ; -- DAYS is passed by value (optional; if not passed defaults to 365)
41 ;
42 ; Return:
43 ; ~Type^PharmID^Drug^InfRate^StopDt^RefRem^TotDose^UnitDose^OrderID
44 ; ^Status^LastFill^Chronic^Issued^Rx #^Provider^
45 ; Status Reason^DEA Handling
46 ;
47 N MEDS,MEDS1,MAP
48 D GETRXS^BEHORXFN("MEDS1",DFN,$P($P(FLAGS,U,2),"-",2)) ; 2nd piece of FLAGS is # of days to retrieve, which comes in the form "T-360"
49 N ALL S ALL=+FLAGS
50 N ACTIVE S ACTIVE=$P(FLAGS,U,3)
51 N PENDING S PENDING=$P(FLAGS,U,4)
52 S @OUTXML@(0)=0 ;By default, no meds
53 ; If MEDS1 is not defined, then no meds
54 I '$D(MEDS1) QUIT
55 ;I DEBUG ZWR MEDS1,MINXML
56 N MEDCNT S MEDCNT=0 ; Med Count
57 ; The next line is a super line. It goes through the array return
58 ; and if the first characters are ~OP, it grabs the line.
59 ; This means that line is for a dispensed Outpatient Med.
60 ; That line has the metadata about the med that I need.
61 ; The next lines, however many, are the med and the sig.
62 ; I won't be using those because I have to get the sig parsed exactly.
63 N J S J="" F S J=$O(MEDS1(J)) Q:J="" I $E(MEDS1(J),1,3)="~OP" S MEDCNT=MEDCNT+1 S MEDS(MEDCNT)=MEDS1(J)
64 K MEDS1
65 S MEDCNT="" ; Initialize for $Order
66 F S MEDCNT=$O(MEDS(MEDCNT)) Q:MEDCNT="" D ; for each medication in the list
67 . I 'ALL,ACTIVE,$P(MEDS(MEDCNT),U,10)'="ACTIVE" QUIT
68 . I 'ALL,PENDING,$P(MEDS(MEDCNT),U,10)'="PENDING" QUIT
69 . I DEBUG W "MEDCNT IS ",MEDCNT,!
70 . S MAP=$NA(^TMP("C0CCCR",$J,"MEDMAP",MEDCNT))
71 . ; K @MAP DO NOT KILL HERE, WAS CLEARED IN C0CMED
72 . I DEBUG W "MAP= ",MAP,!
73 . S @MAP@("MEDOBJECTID")="MED"_MEDCNT ; MEDCNT FOR ID
74 . S @MAP@("MEDISSUEDATETXT")="Issue Date"
75 . S @MAP@("MEDISSUEDATE")=$$FMDTOUTC^C0CUTIL($P(MEDS(MEDCNT),U,15),"DT")
76 . S @MAP@("MEDLASTFILLDATETXT")="Last Fill Date"
77 . S @MAP@("MEDLASTFILLDATE")=$$FMDTOUTC^C0CUTIL($P(MEDS(MEDCNT),U,11),"DT")
78 . S @MAP@("MEDRXNOTXT")="Prescription Number"
79 . S @MAP@("MEDRXNO")=$P(MEDS(MEDCNT),U,14)
80 . S @MAP@("MEDTYPETEXT")="Medication"
81 . S @MAP@("MEDDETAILUNADORNED")="" ; Leave blank, field has its uses
82 . S @MAP@("MEDSTATUSTEXT")=$P(MEDS(MEDCNT),U,10)
83 . ; Provider only provided in API as text, not DUZ.
84 . ; We need to get DUZ from filman file 52 (Prescription)
85 . ; Field 4; IEN is Piece 2 of Meds stripped of trailing characters.
86 . ; Note that I will use RXIEN several times later
87 . N RXIEN S RXIEN=+$P(MEDS(MEDCNT),U,2)
88 . S @MAP@("MEDSOURCEACTORID")="ACTORPROVIDER_"_$$GET1^DIQ(52,RXIEN,4,"I")
89 . S @MAP@("MEDPRODUCTNAMETEXT")=$P(MEDS(MEDCNT),U,3)
90 . ; --- RxNorm Stuff
91 . ; 176.001 is the file for Concepts; 176.003 is the file for
92 . ; sources (i.e. for RxNorm Version)
93 . ;
94 . ; I use 176.001 for the Vista version of this routine (files 1-3)
95 . ; Since IHS does not have VUID's, I will be getting RxNorm codes
96 . ; using NDCs. My specially crafted index (sounds evil) named "NDC"
97 . ; is in file 176.002. The file is called RxNorm NDC to VUID.
98 . ; Except that I don't need the VUID, but it's there if I need it.
99 . ;
100 . ; We obviously need the NDC. That is easily obtained from the prescription.
101 . ; Field 27 in file 52
102 . N NDC S NDC=$$GET1^DIQ(52,RXIEN,27,"I")
103 . ; I discovered that file 176.002 might give you two codes for the NDC
104 . ; One for the Clinical Drug, and one for the ingredient.
105 . ; So the plan is to get the two RxNorm codes, and then find from
106 . ; file 176.001 which one is the Clinical Drug.
107 . ; ... I refactored this into GETRXN
108 . N RXNORM,SRCIEN,RXNNAME,RXNVER
109 . I +NDC,$D(^C0CRXN) D ; $Data is for Systems that don't have our RxNorm file yet.
110 . . S RXNORM=$$GETRXN(NDC)
111 . . S SRCIEN=$$FIND1^DIC(176.003,,,"RXNORM","B")
112 . . S RXNNAME=$$GET1^DIQ(176.003,SRCIEN,6)
113 . . S RXNVER=$$GET1^DIQ(176.003,SRCIEN,7)
114 . ;
115 . E S (RXNORM,RXNNAME,RXNVER)=""
116 . ; End if/else block
117 . S @MAP@("MEDPRODUCTNAMECODEVALUE")=RXNORM
118 . S @MAP@("MEDPRODUCTNAMECODINGINGSYSTEM")=RXNNAME
119 . S @MAP@("MEDPRODUCTNAMECODEVERSION")=RXNVER
120 . ; --- End RxNorm section
121 . ;
122 . ; Brand name is 52 field 6.5
123 . S @MAP@("MEDBRANDNAMETEXT")=$$GET1^DIQ(52,RXIEN,6.5)
124 . ;
125 . ; Next I need Med Form (tab, cap etc), strength (250mg)
126 . ; concentration for liquids (250mg/mL)
127 . ; Since IHS does not have any of the new calls that
128 . ; Vista has, I will be doing a crosswalk:
129 . ; File 52, field 6 is Drug IEN in file 50
130 . ; File 50, field 22 is VA Product IEN in file 50.68
131 . ; In file 50.68, I will get the following:
132 . ; -- 1: Dosage Form
133 . ; -- 2: Strength
134 . ; -- 3: Units
135 . ; -- 8: Dispense Units
136 . ; -- Conc is 2 concatenated with 3
137 . ;
138 . ; *** If Drug is not matched to NDF, then VA Product will be "" ***
139 . ;
140 . N MEDIEN S MEDIEN=$$GET1^DIQ(52,RXIEN,6,"I") ; Drug IEN in 50
141 . N VAPROD S VAPROD=$$GET1^DIQ(50,MEDIEN,22,"I") ; VA Product in file 50.68
142 . I +VAPROD D
143 . . S @MAP@("MEDSTRENGTHVALUE")=$$GET1^DIQ(50.68,VAPROD,2)
144 . . S @MAP@("MEDSTRENGTHUNIT")=$$GET1^DIQ(50.68,VAPROD,3)
145 . . S @MAP@("MEDFORMTEXT")=$$GET1^DIQ(50.68,VAPROD,1)
146 . . S @MAP@("MEDCONCVALUE")=@MAP@("MEDSTRENGTHVALUE")
147 . . S @MAP@("MEDCONCUNIT")=@MAP@("MEDSTRENGTHUNIT")
148 . E D
149 . . S @MAP@("MEDSTRENGTHVALUE")=""
150 . . S @MAP@("MEDSTRENGTHUNIT")=""
151 . . S @MAP@("MEDFORMTEXT")=""
152 . . S @MAP@("MEDCONCVALUE")=""
153 . . S @MAP@("MEDCONCUNIT")=""
154 . ; End Strengh/Conc stuff
155 . ;
156 . ; Quantity is in the prescription, field 7
157 . S @MAP@("MEDQUANTITYVALUE")=$$GET1^DIQ(52,RXIEN,7)
158 . ; Dispense unit is in the drug file, field 14.5
159 . S @MAP@("MEDQUANTITYUNIT")=$$GET1^DIQ(50,MEDIEN,14.5)
160 . ;
161 . ; --- START OF DIRECTIONS ---
162 . ; Sig data not in any API :-( Oh yes, you can get the whole thing, but...
163 . ; we want the components.
164 . ; It's in multiple 113 in the Prescription File (52)
165 . ; #.01 DOSAGE ORDERED [1F] "20"
166 . ; #1 DISPENSE UNITS PER DOSE [2N] "1"
167 . ; #2 UNITS [3P:50.607] "MG"
168 . ; #3 NOUN [4F] "TABLET"
169 . ; #4 DURATION [5F] "10D"
170 . ; #5 CONJUNCTION [6S] "AND"
171 . ; #6 ROUTE [7P:51.2] "ORAL"
172 . ; #7 SCHEDULE [8F] "BID"
173 . ; #8 VERB [9F] "TAKE"
174 . ;
175 . ; Will use GETS^DIQ to get fields.
176 . ; Data comes out like this:
177 . ; SAMINS(52.0113,"1,23,",.01)=20
178 . ; SAMINS(52.0113,"1,23,",1)=1
179 . ; SAMINS(52.0113,"1,23,",2)="MG"
180 . ; SAMINS(52.0113,"1,23,",3)="TABLET"
181 . ; SAMINS(52.0113,"1,23,",4)="5D"
182 . ; SAMINS(52.0113,"1,23,",5)="THEN"
183 . ;
184 . N RAWDATA
185 . D GETS^DIQ(52,RXIEN,"113*",,"RAWDATA","DIERR")
186 . D:$D(DIERR) ^%ZTER ; Log if there's an error in retrieving sig field
187 . ; none the less, continue; some parts are retrievable.
188 . N FMSIG M FMSIG=RAWDATA(52.0113) ; Merge into subfile...
189 . K RAWDATA
190 . N FMSIGNUM S FMSIGNUM="" ; Sigline number in fileman.
191 . ; FMSIGNUM gets outputted as "IEN,RXIEN,".
192 . ; DIRCNT is the proper Sigline numer.
193 . ; SIGDATA is the simplfied array.
194 . F S FMSIGNUM=$O(FMSIG(FMSIGNUM)) Q:FMSIGNUM="" D
195 . . N DIRCNT S DIRCNT=$P(FMSIGNUM,",")
196 . . N SIGDATA M SIGDATA=FMSIG(FMSIGNUM)
197 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRECTIONDESCRIPTIONTEXT")="" ; This is reserved for systems not able to generate the sig in components.
198 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEINDICATOR")="1" ; means that we are specifying it. See E2369-05.
199 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDELIVERYMETHOD")=$G(SIGDATA(8))
200 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEVALUE")=$G(SIGDATA(.01))
201 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEUNIT")=$G(SIGDATA(2))
202 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDRATEVALUE")="" ; For inpatient
203 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDRATEUNIT")="" ; For inpatient
204 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDVEHICLETEXT")="" ; For inpatient
205 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRECTIONROUTETEXT")=$G(SIGDATA(6))
206 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDFREQUENCYVALUE")=$G(SIGDATA(7))
207 . . ; Invervals... again another call.
208 . . ; In the wisdom of the original programmers, the schedule is a free text field
209 . . ; However, it gets translated by a call to the administration schedule file
210 . . ; to see if that schedule exists.
211 . . ; That's the same thing I am going to do.
212 . . ; Search B index of 51.1 (Admin Schedule) with schedule
213 . . ; First, remove "PRN" if it exists (don't ask, that's how the file
214 . . ; works; I wouldn't do it that way).
215 . . N SCHNOPRN S SCHNOPRN=$G(SIGDATA(7))
216 . . I SCHNOPRN["PRN" S SCHNOPRN=$E(SCHNOPRN,1,$F(SCHNOPRN,"PRN")-5)
217 . . ; Super call below:
218 . . ; 1=File 51.1 3=Field 2 (Frequency in Minutes)
219 . . ; 4=Packed format, Exact Match 5=Lookup Value
220 . . ; 6=# of entries to return 7=Index 10=Return Array
221 . . ;
222 . . ; I do not account for the fact that two schedules can be
223 . . ; spelled identically (ie duplicate entry). In that case,
224 . . ; I get the first. That's just a bad pharmacy pkg maintainer.
225 . . N C0C515
226 . . D FIND^DIC(51.1,,"@;2","PX",SCHNOPRN,1,"B",,,"C0C515")
227 . . N INTERVAL S INTERVAL="" ; Default
228 . . ; If there are entries found, get it
229 . . I +$G(C0C515("DILIST",0)) S INTERVAL=$P(C0C515("DILIST",1,0),U,2)
230 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDINTERVALVALUE")=INTERVAL
231 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDINTERVALUNIT")="Minute"
232 . . ; Duration is 10M minutes, 10H hours, 10D for Days
233 . . ; 10W for weeks, 10L for months. I smell $Select
234 . . ; But we don't need to do that if there isn't a duration
235 . . I +$G(SIGDATA(4)) D
236 . . . N DURUNIT S DURUNIT=$E(SIGDATA(4),$L(SIGDATA(4))) ; get last char
237 . . . N DURTXT S DURTXT=$S(DURUNIT="M":"Minutes",DURUNIT="H":"Hours",DURUNIT="D":"Days",DURUNIT="W":"Weeks",DURUNIT="L":"Months",1:"Days")
238 . . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONVALUE")=+SIGDATA(4)
239 . . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONUNIT")=DURTXT
240 . . E D
241 . . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONVALUE")=""
242 . . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONUNIT")=""
243 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPRNFLAG")=$G(SIGDATA(4))["PRN"
244 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMOBJECTID")="" ; when avail
245 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMTYPETXT")=""
246 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMDESCRIPTION")=""
247 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODEVALUE")=""
248 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODINGSYSTEM")=""
249 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODINGVERSION")=""
250 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMSOURCEACTORID")=""
251 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDSTOPINDICATOR")="" ; not stored
252 . . ; Another confusing line; I am pretty bad:
253 . . ; If there is another entry in the FMSIG array (i.e. another line
254 . . ; in the sig), set the direction count indicator.
255 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRSEQ")="" ; Default
256 . . S:+$O(FMSIG(FMSIGNUM)) @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRSEQ")=DIRCNT
257 . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDMULDIRMOD")=$G(SIGDATA(5))
258 . ;
259 . ; --- END OF DIRECTIONS ---
260 . ;
261 . ; Med instructions is a WP field, thus the acrobatics
262 . ; Notice buffer overflow protection set at 10,000 chars
263 . ; -- 1. Med Patient Instructions
264 . N MEDPTIN1 S MEDPTIN1=$$GET1^DIQ(52,RXIEN,115,,"MEDPTIN1")
265 . N MEDPTIN2,J S (MEDPTIN2,J)=""
266 . I $L(MEDPTIN1) F S J=$O(@MEDPTIN1@(J)) Q:J="" Q:$L(MEDPTIN2)>10000 S MEDPTIN2=MEDPTIN2_@MEDPTIN1@(J)_" "
267 . S @MAP@("MEDPTINSTRUCTIONS")=MEDPTIN2
268 . K J
269 . ; -- 2. Med Provider Instructions
270 . N MEDPVIN1 S MEDPVIN1=$$GET1^DIQ(52,RXIEN,39,,"MEDPVIN1")
271 . N MEDPVIN2,J S (MEDPVIN2,J)=""
272 . I $L(MEDPVIN1) F S J=$O(@MEDPVIN1@(J)) Q:J="" Q:$L(MEDPVIN2)>10000 S MEDPVIN2=MEDPVIN2_@MEDPVIN1@(J)_" "
273 . S @MAP@("MEDFULLFILLMENTINSTRUCTIONS")=MEDPVIN2
274 . ;
275 . ; Remaining refills
276 . S @MAP@("MEDRFNO")=$P(MEDS(MEDCNT),U,6)
277 . ; ------ END OF MAPPING
278 . ;
279 . ; ------ BEGIN XML INSERTION
280 . N RESULT S RESULT=$NA(^TMP("C0CCCR",$J,"MAPPED"))
281 . K @RESULT
282 . D MAP^C0CXPATH(MINXML,MAP,RESULT)
283 . ; D PARY^C0CXPATH(RESULT)
284 . ; MAPPING DIRECTIONS
285 . N MEDDIR1,DIRXML1 S DIRXML1="MEDDIR1" ; VARIABLE AND NAME VARIABLE TEMPLATE
286 . N MEDDIR2,DIRXML2 S DIRXML2="MEDDIR2" ; VARIABLE AND NAME VARIABLE RESULT
287 . D QUERY^C0CXPATH(MINXML,"//Medications/Medication/Directions",DIRXML1)
288 . D REPLACE^C0CXPATH(RESULT,"","//Medications/Medication/Directions")
289 . ; N MDZ1,MDZNA
290 . N DIRCNT S DIRCNT=""
291 . I +$O(@MAP@("M","DIRECTIONS",DIRCNT)) D ; IF THERE ARE DIRCTIONS
292 . . F DIRCNT=$O(@MAP@("M","DIRECTIONS",DIRCNT)) D ; FOR EACH DIRECTION
293 . . . S MDZNA=$NA(@MAP@("M","DIRECTIONS",DIRCNT))
294 . . . D MAP^C0CXPATH(DIRXML1,MDZNA,DIRXML2)
295 . . . D INSERT^C0CXPATH(RESULT,DIRXML2,"//Medications/Medication")
296 . D:MEDCNT=1 CP^C0CXPATH(RESULT,OUTXML) ; First one is a copy
297 . D:MEDCNT>1 INSINNER^C0CXPATH(OUTXML,RESULT) ; AFTER THE FIRST, INSERT INNER XML
298 . S MEDCOUNT=MEDCNT
299 N MEDTMP,MEDI
300 D MISSING^C0CXPATH(OUTXML,"MEDTMP") ; SEARCH XML FOR MISSING VARS
301 I MEDTMP(0)>0 D ; IF THERE ARE MISSING VARS - MARKED AS @@X@@
302 . W "MEDICATION MISSING ",!
303 . F MEDI=1:1:MEDTMP(0) W MEDTMP(MEDI),!
304 Q
305 ;
306GETRXN(NDC) ; Extrinsic Function; PUBLIC; NDC to RxNorm
307 ;; Get RxNorm Concept Number for a Given NDC
308 ;
309 S NDC=$TR(NDC,"-") ; Remove dashes
310 N RXNORM,C0CZRXN,DIERR
311 D FIND^DIC(176.002,,"@;.01","PX",NDC,"*","NDC",,,"C0CZRXN","DIERR")
312 I $D(DIERR) S $EC=",U1,"
313 S RXNORM(0)=+C0CZRXN("DILIST",0) ; RxNorm(0) will be # of entries
314 N I S I=0
315 F S I=$O(C0CZRXN("DILIST",I)) Q:I="" S RXNORM(I)=$P(C0CZRXN("DILIST",I,0),U,2)
316 ; At this point, RxNorm(0) is # of entries; RxNorm(1...) are the entries
317 ; If RxNorm(0) is 1, then we only have one entry, and that's it.
318 I RXNORM(0)=1 QUIT RXNORM(1) ; RETURN RXNORM(1)
319 ; Otherwise, we need to find out which one is the semantic
320 ; clinical drug. I built an index on 176.001 (RxNorm Concepts)
321 ; for that purpose.
322 I RXNORM(0)>1 D
323 . S I=0
324 . F S I=$O(RXNORM(I)) Q:I="" D Q:$G(RXNORM)
325 . . N RXNIEN S RXNIEN=$$FIND1^DIC(176.001,,,RXNORM(I),"SCD")
326 . . I +$G(RXNIEN)=0 QUIT ; try the next entry...
327 . . E S RXNORM=RXNORM(I) QUIT ; We found the right code
328 QUIT +$G(RXNORM) ; RETURN RXNORM; if we couldn't find a clnical drug, return with 0
Note: See TracBrowser for help on using the repository browser.