| 1 | C0CMED6 ; WV/CCDCCR/SMH - Meds from RPMS: Outpatient Meds;01/10/09
|
|---|
| 2 | ;;1.0;C0C;;May 19, 2009;
|
|---|
| 3 | ; Copyright 2008 WorldVistA. Licensed under the terms of the GNU
|
|---|
| 4 | ; General Public License See attached copy of the License.
|
|---|
| 5 | ;
|
|---|
| 6 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 7 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 8 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 9 | ; (at your option) any later version.
|
|---|
| 10 | ;
|
|---|
| 11 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 12 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 13 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 14 | ; GNU General Public License for more details.
|
|---|
| 15 | ;
|
|---|
| 16 | ; You should have received a copy of the GNU General Public License along
|
|---|
| 17 | ; with this program; if not, write to the Free Software Foundation, Inc.,
|
|---|
| 18 | ; 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
|
|---|
| 19 | ;
|
|---|
| 20 | W "NO ENTRY FROM TOP",!
|
|---|
| 21 | Q
|
|---|
| 22 | ;
|
|---|
| 23 | EXTRACT(MINXML,DFN,OUTXML,FLAGS) ; EXTRACT MEDICATIONS INTO PROVIDED XML TEMPLATE
|
|---|
| 24 | ;
|
|---|
| 25 | ; MINXML and OUTXML are passed by name so globals can be used
|
|---|
| 26 | ; MINXML will contain only the medications skeleton of the overall template
|
|---|
| 27 | ; FLAGS are: MEDALL(bool)^MEDLIMIT(int)^MEDACTIVE(bool)^MEDPENDING(bool)
|
|---|
| 28 | ; FLAGS are set-up in C0CMED.
|
|---|
| 29 | ;
|
|---|
| 30 | ; MEDS is return array from RPC.
|
|---|
| 31 | ; MAP is a mapping variable map (store result) for each med
|
|---|
| 32 | ; MED is holds each array element from MEDS(J), one medicine
|
|---|
| 33 | ; J is a counter.
|
|---|
| 34 | ;
|
|---|
| 35 | ; GETRXS^BEHORXFN(ARRAYNAME,DFN,DAYS) will be the the API used.
|
|---|
| 36 | ; This API has been developed by Medsphere for IHS for getting
|
|---|
| 37 | ; Medications from RPMS. It has most of what we need.
|
|---|
| 38 | ; API written by Doug Martin when he worked for Medsphere (thanks Doug!)
|
|---|
| 39 | ; -- ARRAYNAME is passed by name (required)
|
|---|
| 40 | ; -- DFN is passed by value (required)
|
|---|
| 41 | ; -- DAYS is passed by value (optional; if not passed defaults to 365)
|
|---|
| 42 | ;
|
|---|
| 43 | ; Return:
|
|---|
| 44 | ; ~Type(1)^PharmID(2)^Drug(3)^InfRate(4)^StopDt(5)^RefRem(6)^
|
|---|
| 45 | ; TotDose(7)^UnitDose(8)^OrderID(9)^Status(10)^LastFill(11)^
|
|---|
| 46 | ; Days Supply(12)^Quantity(13)^Chronic(14)^Issued(15)^
|
|---|
| 47 | ; Rx #(16)^Provider(17)^Status Reason(18)^DEA Handling(19)^
|
|---|
| 48 | ; Pharmacy Site(20)
|
|---|
| 49 | ;
|
|---|
| 50 | N MEDS,MEDS1,MAP
|
|---|
| 51 | D GETRXS^BEHORXFN("MEDS1",DFN,$P($P(FLAGS,U,2),"-",2)) ; 2nd piece of FLAGS is # of days to retrieve, which comes in the form "T-360"
|
|---|
| 52 | N ALL S ALL=+FLAGS
|
|---|
| 53 | N ACTIVE S ACTIVE=$P(FLAGS,U,3)
|
|---|
| 54 | N PENDING S PENDING=$P(FLAGS,U,4)
|
|---|
| 55 | S @OUTXML@(0)=0 ;By default, no meds
|
|---|
| 56 | ; If MEDS1 is not defined, then no meds
|
|---|
| 57 | I '$D(MEDS1) QUIT
|
|---|
| 58 | I DEBUG ZWR MEDS1,MINXML
|
|---|
| 59 | N MEDCNT S MEDCNT=0 ; Med Count
|
|---|
| 60 | ; The next line is a super line. It goes through the array return
|
|---|
| 61 | ; and if the first characters are ~OP, it grabs the line.
|
|---|
| 62 | ; This means that line is for a dispensed Outpatient Med.
|
|---|
| 63 | ; That line has the metadata about the med that I need.
|
|---|
| 64 | ; The next lines, however many, are the med and the sig.
|
|---|
| 65 | ; I won't be using those because I have to get the sig parsed exactly.
|
|---|
| 66 | N J S J="" F S J=$O(MEDS1(J)) Q:J="" I $E(MEDS1(J),1,3)="~OP" S MEDCNT=MEDCNT+1 S MEDS(MEDCNT)=MEDS1(J)
|
|---|
| 67 | K MEDS1
|
|---|
| 68 | S MEDCNT="" ; Initialize for $Order
|
|---|
| 69 | F S MEDCNT=$O(MEDS(MEDCNT)) Q:MEDCNT="" D ; for each medication in the list
|
|---|
| 70 | . I 'ALL,ACTIVE,$P(MEDS(MEDCNT),U,10)'="ACTIVE" QUIT
|
|---|
| 71 | . I 'ALL,PENDING,$P(MEDS(MEDCNT),U,10)'="PENDING" QUIT
|
|---|
| 72 | . I DEBUG W "MEDCNT IS ",MEDCNT,!
|
|---|
| 73 | . S MAP=$NA(^TMP("C0CCCR",$J,"MEDMAP",MEDCNT))
|
|---|
| 74 | . ; K @MAP DO NOT KILL HERE, WAS CLEARED IN C0CMED
|
|---|
| 75 | . I DEBUG W "MAP= ",MAP,!
|
|---|
| 76 | . S @MAP@("MEDOBJECTID")="MED"_MEDCNT ; MEDCNT FOR ID
|
|---|
| 77 | . S @MAP@("MEDISSUEDATETXT")="Issue Date"
|
|---|
| 78 | . S @MAP@("MEDISSUEDATE")=$$FMDTOUTC^C0CUTIL($P(MEDS(MEDCNT),U,15))
|
|---|
| 79 | . S @MAP@("MEDLASTFILLDATETXT")="Last Fill Date"
|
|---|
| 80 | . S @MAP@("MEDLASTFILLDATE")=$$FMDTOUTC^C0CUTIL($P(MEDS(MEDCNT),U,11))
|
|---|
| 81 | . S @MAP@("MEDRXNOTXT")="Prescription Number"
|
|---|
| 82 | . S @MAP@("MEDRXNO")=$P(MEDS(MEDCNT),U,16)
|
|---|
| 83 | . S @MAP@("MEDTYPETEXT")="Medication"
|
|---|
| 84 | . S @MAP@("MEDDETAILUNADORNED")="" ; Leave blank, field has its uses
|
|---|
| 85 | . S @MAP@("MEDSTATUSTEXT")=$P(MEDS(MEDCNT),U,10)
|
|---|
| 86 | . ; Provider only provided in API as text, not DUZ.
|
|---|
| 87 | . ; We need to get DUZ from filman file 52 (Prescription)
|
|---|
| 88 | . ; Field 4; IEN is Piece 2 of Meds stripped of trailing characters.
|
|---|
| 89 | . ; Note that I will use RXIEN several times later
|
|---|
| 90 | . N RXIEN S RXIEN=+$P(MEDS(MEDCNT),U,2)
|
|---|
| 91 | . S @MAP@("MEDSOURCEACTORID")="ACTORPROVIDER_"_$$GET1^DIQ(52,RXIEN,4,"I")
|
|---|
| 92 | . S @MAP@("MEDPRODUCTNAMETEXT")=$P(MEDS(MEDCNT),U,3)
|
|---|
| 93 | . ; --- RxNorm Stuff
|
|---|
| 94 | . ; 176.001 is the file for Concepts; 176.003 is the file for
|
|---|
| 95 | . ; sources (i.e. for RxNorm Version)
|
|---|
| 96 | . ;
|
|---|
| 97 | . ; I use 176.001 for the Vista version of this routine (files 1-3)
|
|---|
| 98 | . ; Since IHS does not have VUID's, I will be getting RxNorm codes
|
|---|
| 99 | . ; using NDCs. My specially crafted index (sounds evil) named "NDC"
|
|---|
| 100 | . ; is in file 176.002. The file is called RxNorm NDC to VUID.
|
|---|
| 101 | . ; Except that I don't need the VUID, but it's there if I need it.
|
|---|
| 102 | . ;
|
|---|
| 103 | . ; We obviously need the NDC. That is easily obtained from the prescription.
|
|---|
| 104 | . ; Field 27 in file 52
|
|---|
| 105 | . N NDC S NDC=$$GET1^DIQ(52,RXIEN,27,"I")
|
|---|
| 106 | . ; I discovered that file 176.002 might give you two codes for the NDC
|
|---|
| 107 | . ; One for the Clinical Drug, and one for the ingredient.
|
|---|
| 108 | . ; So the plan is to get the two RxNorm codes, and then find from
|
|---|
| 109 | . ; file 176.001 which one is the Clinical Drug.
|
|---|
| 110 | . ; ... I refactored this into GETRXN
|
|---|
| 111 | . N RXNORM,SRCIEN,RXNNAME,RXNVER
|
|---|
| 112 | . I +NDC,$D(^C0CRXN) D ; $Data is for Systems that don't have our RxNorm file yet.
|
|---|
| 113 | . . S RXNORM=$$GETRXN(NDC)
|
|---|
| 114 | . . S SRCIEN=$$FIND1^DIC(176.003,,,"RXNORM","B")
|
|---|
| 115 | . . S RXNNAME=$$GET1^DIQ(176.003,SRCIEN,6)
|
|---|
| 116 | . . S RXNVER=$$GET1^DIQ(176.003,SRCIEN,7)
|
|---|
| 117 | . ;
|
|---|
| 118 | . E S (RXNORM,RXNNAME,RXNVER)=""
|
|---|
| 119 | . ; End if/else block
|
|---|
| 120 | . S @MAP@("MEDPRODUCTNAMECODEVALUE")=RXNORM
|
|---|
| 121 | . S @MAP@("MEDPRODUCTNAMECODINGINGSYSTEM")=RXNNAME
|
|---|
| 122 | . S @MAP@("MEDPRODUCTNAMECODEVERSION")=RXNVER
|
|---|
| 123 | . ; --- End RxNorm section
|
|---|
| 124 | . ;
|
|---|
| 125 | . ; Brand name is 52 field 6.5
|
|---|
| 126 | . S @MAP@("MEDBRANDNAMETEXT")=$$GET1^DIQ(52,RXIEN,6.5)
|
|---|
| 127 | . ;
|
|---|
| 128 | . ; Next I need Med Form (tab, cap etc), strength (250mg)
|
|---|
| 129 | . ; concentration for liquids (250mg/mL)
|
|---|
| 130 | . ; Since IHS does not have any of the new calls that
|
|---|
| 131 | . ; Vista has, I will be doing a crosswalk:
|
|---|
| 132 | . ; File 52, field 6 is Drug IEN in file 50
|
|---|
| 133 | . ; File 50, field 22 is VA Product IEN in file 50.68
|
|---|
| 134 | . ; In file 50.68, I will get the following:
|
|---|
| 135 | . ; -- 1: Dosage Form
|
|---|
| 136 | . ; -- 2: Strength
|
|---|
| 137 | . ; -- 3: Units
|
|---|
| 138 | . ; -- 8: Dispense Units
|
|---|
| 139 | . ; -- Conc is 2 concatenated with 3
|
|---|
| 140 | . ;
|
|---|
| 141 | . ; *** If Drug is not matched to NDF, then VA Product will be "" ***
|
|---|
| 142 | . ;
|
|---|
| 143 | . N MEDIEN S MEDIEN=$$GET1^DIQ(52,RXIEN,6,"I") ; Drug IEN in 50
|
|---|
| 144 | . N VAPROD S VAPROD=$$GET1^DIQ(50,MEDIEN,22,"I") ; VA Product in file 50.68
|
|---|
| 145 | . I +VAPROD D
|
|---|
| 146 | . . S @MAP@("MEDSTRENGTHVALUE")=$$GET1^DIQ(50.68,VAPROD,2)
|
|---|
| 147 | . . S @MAP@("MEDSTRENGTHUNIT")=$$GET1^DIQ(50.68,VAPROD,3)
|
|---|
| 148 | . . S @MAP@("MEDFORMTEXT")=$$GET1^DIQ(50.68,VAPROD,1)
|
|---|
| 149 | . . S @MAP@("MEDCONCVALUE")=@MAP@("MEDSTRENGTHVALUE")
|
|---|
| 150 | . . S @MAP@("MEDCONCUNIT")=@MAP@("MEDSTRENGTHUNIT")
|
|---|
| 151 | . E D
|
|---|
| 152 | . . S @MAP@("MEDSTRENGTHVALUE")=""
|
|---|
| 153 | . . S @MAP@("MEDSTRENGTHUNIT")=""
|
|---|
| 154 | . . S @MAP@("MEDFORMTEXT")=""
|
|---|
| 155 | . . S @MAP@("MEDCONCVALUE")=""
|
|---|
| 156 | . . S @MAP@("MEDCONCUNIT")=""
|
|---|
| 157 | . ; End Strengh/Conc stuff
|
|---|
| 158 | . ;
|
|---|
| 159 | . ; Quantity is in the prescription, field 7
|
|---|
| 160 | . S @MAP@("MEDQUANTITYVALUE")=$$GET1^DIQ(52,RXIEN,7)
|
|---|
| 161 | . ; Dispense unit is in the drug file, field 14.5
|
|---|
| 162 | . S @MAP@("MEDQUANTITYUNIT")=$$GET1^DIQ(50,MEDIEN,14.5)
|
|---|
| 163 | . ;
|
|---|
| 164 | . ; --- START OF DIRECTIONS ---
|
|---|
| 165 | . ; Sig data not in any API :-( Oh yes, you can get the whole thing, but...
|
|---|
| 166 | . ; we want the components.
|
|---|
| 167 | . ; It's in multiple 113 in the Prescription File (52)
|
|---|
| 168 | . ; #.01 DOSAGE ORDERED [1F] "20"
|
|---|
| 169 | . ; #1 DISPENSE UNITS PER DOSE [2N] "1"
|
|---|
| 170 | . ; #2 UNITS [3P:50.607] "MG"
|
|---|
| 171 | . ; #3 NOUN [4F] "TABLET"
|
|---|
| 172 | . ; #4 DURATION [5F] "10D"
|
|---|
| 173 | . ; #5 CONJUNCTION [6S] "AND"
|
|---|
| 174 | . ; #6 ROUTE [7P:51.2] "ORAL"
|
|---|
| 175 | . ; #7 SCHEDULE [8F] "BID"
|
|---|
| 176 | . ; #8 VERB [9F] "TAKE"
|
|---|
| 177 | . ;
|
|---|
| 178 | . ; Will use GETS^DIQ to get fields.
|
|---|
| 179 | . ; Data comes out like this:
|
|---|
| 180 | . ; SAMINS(52.0113,"1,23,",.01)=20
|
|---|
| 181 | . ; SAMINS(52.0113,"1,23,",1)=1
|
|---|
| 182 | . ; SAMINS(52.0113,"1,23,",2)="MG"
|
|---|
| 183 | . ; SAMINS(52.0113,"1,23,",3)="TABLET"
|
|---|
| 184 | . ; SAMINS(52.0113,"1,23,",4)="5D"
|
|---|
| 185 | . ; SAMINS(52.0113,"1,23,",5)="THEN"
|
|---|
| 186 | . ;
|
|---|
| 187 | . N RAWDATA
|
|---|
| 188 | . D GETS^DIQ(52,RXIEN,"113*",,"RAWDATA","DIERR")
|
|---|
| 189 | . D:$D(DIERR) ^%ZTER ; Log if there's an error in retrieving sig field
|
|---|
| 190 | . ; none the less, continue; some parts are retrievable.
|
|---|
| 191 | . N FMSIG M FMSIG=RAWDATA(52.0113) ; Merge into subfile...
|
|---|
| 192 | . K RAWDATA
|
|---|
| 193 | . N FMSIGNUM S FMSIGNUM="" ; Sigline number in fileman.
|
|---|
| 194 | . ; FMSIGNUM gets outputted as "IEN,RXIEN,".
|
|---|
| 195 | . ; DIRCNT is the proper Sigline numer.
|
|---|
| 196 | . ; SIGDATA is the simplfied array.
|
|---|
| 197 | . F S FMSIGNUM=$O(FMSIG(FMSIGNUM)) Q:FMSIGNUM="" D
|
|---|
| 198 | . . N DIRCNT S DIRCNT=$P(FMSIGNUM,",")
|
|---|
| 199 | . . N SIGDATA M SIGDATA=FMSIG(FMSIGNUM)
|
|---|
| 200 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRECTIONDESCRIPTIONTEXT")="" ; This is reserved for systems not able to generate the sig in components.
|
|---|
| 201 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEINDICATOR")="1" ; means that we are specifying it. See E2369-05.
|
|---|
| 202 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDELIVERYMETHOD")=$G(SIGDATA(8))
|
|---|
| 203 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEVALUE")=$G(SIGDATA(.01))
|
|---|
| 204 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEUNIT")=$G(SIGDATA(2))
|
|---|
| 205 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDRATEVALUE")="" ; For inpatient
|
|---|
| 206 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDRATEUNIT")="" ; For inpatient
|
|---|
| 207 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDVEHICLETEXT")="" ; For inpatient
|
|---|
| 208 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRECTIONROUTETEXT")=$G(SIGDATA(6))
|
|---|
| 209 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDFREQUENCYVALUE")=$G(SIGDATA(7))
|
|---|
| 210 | . . ; Invervals... again another call.
|
|---|
| 211 | . . ; In the wisdom of the original programmers, the schedule is a free text field
|
|---|
| 212 | . . ; However, it gets translated by a call to the administration schedule file
|
|---|
| 213 | . . ; to see if that schedule exists.
|
|---|
| 214 | . . ; That's the same thing I am going to do.
|
|---|
| 215 | . . ; Search B index of 51.1 (Admin Schedule) with schedule
|
|---|
| 216 | . . ; First, remove "PRN" if it exists (don't ask, that's how the file
|
|---|
| 217 | . . ; works; I wouldn't do it that way).
|
|---|
| 218 | . . N SCHNOPRN S SCHNOPRN=$G(SIGDATA(7))
|
|---|
| 219 | . . I SCHNOPRN["PRN" S SCHNOPRN=$E(SCHNOPRN,1,$F(SCHNOPRN,"PRN")-5)
|
|---|
| 220 | . . ; Super call below:
|
|---|
| 221 | . . ; 1=File 51.1 3=Field 2 (Frequency in Minutes)
|
|---|
| 222 | . . ; 4=Packed format, Exact Match 5=Lookup Value
|
|---|
| 223 | . . ; 6=# of entries to return 7=Index 10=Return Array
|
|---|
| 224 | . . ;
|
|---|
| 225 | . . ; I do not account for the fact that two schedules can be
|
|---|
| 226 | . . ; spelled identically (ie duplicate entry). In that case,
|
|---|
| 227 | . . ; I get the first. That's just a bad pharmacy pkg maintainer.
|
|---|
| 228 | . . N C0C515
|
|---|
| 229 | . . D FIND^DIC(51.1,,"@;2","PX",SCHNOPRN,1,"B",,,"C0C515")
|
|---|
| 230 | . . N INTERVAL S INTERVAL="" ; Default
|
|---|
| 231 | . . ; If there are entries found, get it
|
|---|
| 232 | . . I +$G(C0C515("DILIST",0)) S INTERVAL=$P(C0C515("DILIST",1,0),U,2)
|
|---|
| 233 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDINTERVALVALUE")=INTERVAL
|
|---|
| 234 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDINTERVALUNIT")="Minute"
|
|---|
| 235 | . . ; Duration is 10M minutes, 10H hours, 10D for Days
|
|---|
| 236 | . . ; 10W for weeks, 10L for months. I smell $Select
|
|---|
| 237 | . . ; But we don't need to do that if there isn't a duration
|
|---|
| 238 | . . I +$G(SIGDATA(4)) D
|
|---|
| 239 | . . . N DURUNIT S DURUNIT=$E(SIGDATA(4),$L(SIGDATA(4))) ; get last char
|
|---|
| 240 | . . . N DURTXT S DURTXT=$S(DURUNIT="M":"Minutes",DURUNIT="H":"Hours",DURUNIT="D":"Days",DURUNIT="W":"Weeks",DURUNIT="L":"Months",1:"Days")
|
|---|
| 241 | . . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONVALUE")=+SIGDATA(4)
|
|---|
| 242 | . . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONUNIT")=DURTXT
|
|---|
| 243 | . . E D
|
|---|
| 244 | . . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONVALUE")=""
|
|---|
| 245 | . . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONUNIT")=""
|
|---|
| 246 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPRNFLAG")=$G(SIGDATA(4))["PRN"
|
|---|
| 247 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMOBJECTID")="" ; when avail
|
|---|
| 248 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMTYPETXT")=""
|
|---|
| 249 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMDESCRIPTION")=""
|
|---|
| 250 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODEVALUE")=""
|
|---|
| 251 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODINGSYSTEM")=""
|
|---|
| 252 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODINGVERSION")=""
|
|---|
| 253 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMSOURCEACTORID")=""
|
|---|
| 254 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDSTOPINDICATOR")="" ; not stored
|
|---|
| 255 | . . ; Another confusing line; I am pretty bad:
|
|---|
| 256 | . . ; If there is another entry in the FMSIG array (i.e. another line
|
|---|
| 257 | . . ; in the sig), set the direction count indicator.
|
|---|
| 258 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRSEQ")="" ; Default
|
|---|
| 259 | . . S:+$O(FMSIG(FMSIGNUM)) @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRSEQ")=DIRCNT
|
|---|
| 260 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDMULDIRMOD")=$G(SIGDATA(5))
|
|---|
| 261 | . ;
|
|---|
| 262 | . ; --- END OF DIRECTIONS ---
|
|---|
| 263 | . ;
|
|---|
| 264 | . ; Med instructions is a WP field, thus the acrobatics
|
|---|
| 265 | . ; Notice buffer overflow protection set at 10,000 chars
|
|---|
| 266 | . ; -- 1. Med Patient Instructions
|
|---|
| 267 | . N MEDPTIN1 S MEDPTIN1=$$GET1^DIQ(52,RXIEN,115,,"MEDPTIN1")
|
|---|
| 268 | . N MEDPTIN2,J S (MEDPTIN2,J)=""
|
|---|
| 269 | . I $L(MEDPTIN1) F S J=$O(@MEDPTIN1@(J)) Q:J="" Q:$L(MEDPTIN2)>10000 S MEDPTIN2=MEDPTIN2_@MEDPTIN1@(J)_" "
|
|---|
| 270 | . S @MAP@("MEDPTINSTRUCTIONS")=MEDPTIN2
|
|---|
| 271 | . K J
|
|---|
| 272 | . ; -- 2. Med Provider Instructions
|
|---|
| 273 | . N MEDPVIN1 S MEDPVIN1=$$GET1^DIQ(52,RXIEN,39,,"MEDPVIN1")
|
|---|
| 274 | . N MEDPVIN2,J S (MEDPVIN2,J)=""
|
|---|
| 275 | . I $L(MEDPVIN1) F S J=$O(@MEDPVIN1@(J)) Q:J="" Q:$L(MEDPVIN2)>10000 S MEDPVIN2=MEDPVIN2_@MEDPVIN1@(J)_" "
|
|---|
| 276 | . S @MAP@("MEDFULLFILLMENTINSTRUCTIONS")=MEDPVIN2
|
|---|
| 277 | . ;
|
|---|
| 278 | . ; Remaining refills
|
|---|
| 279 | . S @MAP@("MEDRFNO")=$P(MEDS(MEDCNT),U,6)
|
|---|
| 280 | . ; ------ END OF MAPPING
|
|---|
| 281 | . ;
|
|---|
| 282 | . ; ------ BEGIN XML INSERTION
|
|---|
| 283 | . N RESULT S RESULT=$NA(^TMP("C0CCCR",$J,"MAPPED"))
|
|---|
| 284 | . K @RESULT
|
|---|
| 285 | . D MAP^C0CXPATH(MINXML,MAP,RESULT)
|
|---|
| 286 | . ; D PARY^C0CXPATH(RESULT)
|
|---|
| 287 | . ; MAPPING DIRECTIONS
|
|---|
| 288 | . N MEDDIR1,DIRXML1 S DIRXML1="MEDDIR1" ; VARIABLE AND NAME VARIABLE TEMPLATE
|
|---|
| 289 | . N MEDDIR2,DIRXML2 S DIRXML2="MEDDIR2" ; VARIABLE AND NAME VARIABLE RESULT
|
|---|
| 290 | . D QUERY^C0CXPATH(MINXML,"//Medications/Medication/Directions",DIRXML1)
|
|---|
| 291 | . D REPLACE^C0CXPATH(RESULT,"","//Medications/Medication/Directions")
|
|---|
| 292 | . ; N MDZ1,MDZNA
|
|---|
| 293 | . N DIRCNT S DIRCNT=""
|
|---|
| 294 | . I +$O(@MAP@("M","DIRECTIONS",DIRCNT)) D ; IF THERE ARE DIRCTIONS
|
|---|
| 295 | . . F DIRCNT=$O(@MAP@("M","DIRECTIONS",DIRCNT)) D ; FOR EACH DIRECTION
|
|---|
| 296 | . . . S MDZNA=$NA(@MAP@("M","DIRECTIONS",DIRCNT))
|
|---|
| 297 | . . . D MAP^C0CXPATH(DIRXML1,MDZNA,DIRXML2)
|
|---|
| 298 | . . . D INSERT^C0CXPATH(RESULT,DIRXML2,"//Medications/Medication")
|
|---|
| 299 | . D:MEDCNT=1 CP^C0CXPATH(RESULT,OUTXML) ; First one is a copy
|
|---|
| 300 | . D:MEDCNT>1 INSINNER^C0CXPATH(OUTXML,RESULT) ; AFTER THE FIRST, INSERT INNER XML
|
|---|
| 301 | N MEDTMP,MEDI
|
|---|
| 302 | D MISSING^C0CXPATH(OUTXML,"MEDTMP") ; SEARCH XML FOR MISSING VARS
|
|---|
| 303 | I MEDTMP(0)>0 D ; IF THERE ARE MISSING VARS - MARKED AS @@X@@
|
|---|
| 304 | . W "MEDICATION MISSING ",!
|
|---|
| 305 | . F MEDI=1:1:MEDTMP(0) W MEDTMP(MEDI),!
|
|---|
| 306 | Q
|
|---|
| 307 | ;
|
|---|
| 308 | GETRXN(NDC) ; Extrinsic Function; PUBLIC; NDC to RxNorm
|
|---|
| 309 | ;; Get RxNorm Concept Number for a Given NDC
|
|---|
| 310 | ;
|
|---|
| 311 | S NDC=$TR(NDC,"-") ; Remove dashes
|
|---|
| 312 | N RXNORM,C0CZRXN,DIERR
|
|---|
| 313 | D FIND^DIC(176.002,,"@;.01","PX",NDC,"*","NDC",,,"C0CZRXN","DIERR")
|
|---|
| 314 | I $D(DIERR) D ^%ZTER BREAK
|
|---|
| 315 | S RXNORM(0)=+C0CZRXN("DILIST",0) ; RxNorm(0) will be # of entries
|
|---|
| 316 | N I S I=0
|
|---|
| 317 | F S I=$O(C0CZRXN("DILIST",I)) Q:I="" S RXNORM(I)=$P(C0CZRXN("DILIST",I,0),U,2)
|
|---|
| 318 | ; At this point, RxNorm(0) is # of entries; RxNorm(1...) are the entries
|
|---|
| 319 | ; If RxNorm(0) is 1, then we only have one entry, and that's it.
|
|---|
| 320 | I RXNORM(0)=1 QUIT RXNORM(1) ; RETURN RXNORM(1)
|
|---|
| 321 | ; Otherwise, we need to find out which one is the semantic
|
|---|
| 322 | ; clinical drug. I built an index on 176.001 (RxNorm Concepts)
|
|---|
| 323 | ; for that purpose.
|
|---|
| 324 | I RXNORM(0)>1 D
|
|---|
| 325 | . S I=0
|
|---|
| 326 | . F S I=$O(RXNORM(I)) Q:I="" D Q:$G(RXNORM)
|
|---|
| 327 | . . N RXNIEN S RXNIEN=$$FIND1^DIC(176.001,,,RXNORM(I),"SCD")
|
|---|
| 328 | . . I +$G(RXNIEN)=0 QUIT ; try the next entry...
|
|---|
| 329 | . . E S RXNORM=RXNORM(I) QUIT ; We found the right code
|
|---|
| 330 | QUIT +$G(RXNORM) ; RETURN RXNORM; if we couldn't find a clnical drug, return with 0
|
|---|
| 331 |
|
|---|
