| 1 | CCRMEDS2 ; WV/CCDCCR/SMH - CCR/CCD PROCESSING FOR MEDICATIONS - Pending Meds;08/24/08
|
|---|
| 2 | ;;0.1;CCDCCR;;JUL 16,2008;
|
|---|
| 3 | ; Copyright 2008 WorldVistA. Licensed under the terms of the GNU
|
|---|
| 4 | ; General Public License See attached copy of the License.
|
|---|
| 5 | ;
|
|---|
| 6 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 7 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 8 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 9 | ; (at your option) any later version.
|
|---|
| 10 | ;
|
|---|
| 11 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 12 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 13 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 14 | ; GNU General Public License for more details.
|
|---|
| 15 | ;
|
|---|
| 16 | ; You should have received a copy of the GNU General Public License along
|
|---|
| 17 | ; with this program; if not, write to the Free Software Foundation, Inc.,
|
|---|
| 18 | ; 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
|
|---|
| 19 | ;
|
|---|
| 20 | W "NO ENTRY FROM TOP",!
|
|---|
| 21 | Q
|
|---|
| 22 | ;
|
|---|
| 23 | EXTRACT(MINXML,DFN,OUTXML) ; EXTRACT MEDICATIONS INTO PROVIDED XML TEMPLATE
|
|---|
| 24 | ;
|
|---|
| 25 | ; MINXML is the Input XML Template, passed by name
|
|---|
| 26 | ; DFN is Patient IEN
|
|---|
| 27 | ; OUTXML is the resultant XML.
|
|---|
| 28 | ;
|
|---|
| 29 | ; MEDS is return array from RPC.
|
|---|
| 30 | ; MAP is a mapping variable map (store result) for each med
|
|---|
| 31 | ; MED is holds each array element from MEDS, one medicine
|
|---|
| 32 | ;
|
|---|
| 33 | ; PEN^PSO5241 is a Pharmacy Re-Enginnering (PRE) API to get Pending
|
|---|
| 34 | ; meds data available.
|
|---|
| 35 | ; http://www.va.gov/vdl/documents/Clinical/Pharm-Outpatient_Pharmacy/phar_1_api_r0807.pdf
|
|---|
| 36 | ; Output of API is ^TMP($J,"SUBSCRIPT",DFN,RXIENS).
|
|---|
| 37 | ; File for pending meds is 52.41
|
|---|
| 38 | ; Unfortuantely, API does not supply us with any useful info beyond
|
|---|
| 39 | ; the IEN in 52.41, and the Med Name, and route.
|
|---|
| 40 | ; So, most of the info is going to get pulled from 52.41.
|
|---|
| 41 | N MEDS,MAP
|
|---|
| 42 | K ^TMP($J)
|
|---|
| 43 | D PEN^PSO5241(DFN,"CCDCCR")
|
|---|
| 44 | M MEDS=^TMP($J,"CCDCCR",DFN)
|
|---|
| 45 | ; @(0) contains the number of meds or -1^NO DATA FOUND
|
|---|
| 46 | ; If it is -1, we quit.
|
|---|
| 47 | I $P(MEDS(0),U)=-1 S @OUTXML@(0)=0 QUIT
|
|---|
| 48 | I DEBUG ZWR MEDS
|
|---|
| 49 | N RXIEN S RXIEN=0
|
|---|
| 50 | N MEDCOUNT S MEDCOUNT=0
|
|---|
| 51 | S MEDMAP=$NA(^TMP("GPLCCR",$J,"MEDMAP")) ; THIS IS THE VARIABLE MAP
|
|---|
| 52 | S MEDCOUNT=@MEDMAP@(0) ; ACCOUNT FOR MEDS ALREADY IN ARRAY
|
|---|
| 53 | F S RXIEN=$O(MEDS(RXIEN)) Q:RXIEN="B" D ; FOR EACH MEDICATION IN THE LIST
|
|---|
| 54 | . I $$GET1^DIQ(52.41,RXIEN,2,"I")="RF" QUIT ; Dont' want refill request as a "pending" order
|
|---|
| 55 | . S MEDCOUNT=MEDCOUNT+1
|
|---|
| 56 | . I DEBUG W "RXIEN IS ",RXIEN,!
|
|---|
| 57 | . S MAP=$NA(^TMP("GPLCCR",$J,"MEDMAP",MEDCOUNT))
|
|---|
| 58 | . ; K @MAP DON'T KILL MAP HERE, IT IS DONE IN CCRMEDS
|
|---|
| 59 | . S @MEDMAP@(0)=@MEDMAP@(0)+1 ; INCREMENT TOTAL MEDS IN VAR ARRAY
|
|---|
| 60 | . I DEBUG W "MAP= ",MAP,!
|
|---|
| 61 | . N MED M MED=MEDS(RXIEN) ; PULL OUT MEDICATION FROM
|
|---|
| 62 | . S @MAP@("MEDOBJECTID")="MED_PENDING"_MEDCOUNT ; MEDCOUNT FOR ID
|
|---|
| 63 | . ; S @MAP@("MEDOBJECTID")="MED_PENDING"_MED(.01) ;Pending IEN
|
|---|
| 64 | . S @MAP@("MEDISSUEDATETXT")="Issue Date"
|
|---|
| 65 | . ; Field 6 is "Effective date", and we pull it in timson format w/ I
|
|---|
| 66 | . S @MAP@("MEDISSUEDATE")=$$FMDTOUTC^CCRUTIL($$GET1^DIQ(52.41,RXIEN,6,"I"))
|
|---|
| 67 | . ; Med never filled; next 4 fields are not applicable.
|
|---|
| 68 | . S @MAP@("MEDLASTFILLDATETXT")=""
|
|---|
| 69 | . S @MAP@("MEDLASTFILLDATE")=""
|
|---|
| 70 | . S @MAP@("MEDRXNOTXT")=""
|
|---|
| 71 | . S @MAP@("MEDRXNO")=""
|
|---|
| 72 | . S @MAP@("MEDTYPETEXT")="Medication"
|
|---|
| 73 | . S @MAP@("MEDDETAILUNADORNED")="" ; Leave blank, field has its uses
|
|---|
| 74 | . S @MAP@("MEDSTATUSTEXT")="On Hold" ; nearest status for pending meds
|
|---|
| 75 | . S @MAP@("MEDSOURCEACTORID")="ACTORPROVIDER_"_$$GET1^DIQ(52.41,RXIEN,5,"I")
|
|---|
| 76 | . S @MAP@("MEDPRODUCTNAMETEXT")=$P(MED(11),U,2)
|
|---|
| 77 | . ; NDC not supplied in API, but is rather trivial to obtain
|
|---|
| 78 | . ; MED(11) piece 1 has the IEN of the drug (file 50)
|
|---|
| 79 | . ; IEN is field 31 in the drug file.
|
|---|
| 80 | . N MEDIEN S MEDIEN=$P(MED(11),U)
|
|---|
| 81 | . S @MAP@("MEDPRODUCTNAMECODEVALUE")=$$GET1^DIQ(50,MEDIEN,31,"E")
|
|---|
| 82 | . S @MAP@("MEDPRODUCTNAMECODINGINGSYSTEM")="NDC"
|
|---|
| 83 | . S @MAP@("MEDPRODUCTNAMECODEVERSION")="none"
|
|---|
| 84 | . S @MAP@("MEDBRANDNAMETEXT")=""
|
|---|
| 85 | . D DOSE^PSS50(MEDIEN,,,,,"DOSE")
|
|---|
| 86 | . N DOSEDATA M DOSEDATA=^TMP($J,"DOSE",MEDIEN)
|
|---|
| 87 | . S @MAP@("MEDSTRENGTHVALUE")=DOSEDATA(901)
|
|---|
| 88 | . S @MAP@("MEDSTRENGTHUNIT")=$P(DOSEDATA(902),U,2)
|
|---|
| 89 | . ; Units, concentration, etc, come from another call
|
|---|
| 90 | . ; $$CPRS^PSNAPIS which returns dosage-form^va class^strengh^unit
|
|---|
| 91 | . ; This call takes nodes 1 and 3 of ^PSDRUG(D0,"ND") as parameters
|
|---|
| 92 | . ; NDF Entry IEN, and VA Product Name
|
|---|
| 93 | . ; These can be obtained using NDF^PSS50 (IEN,,,,,"SUBSCRIPT")
|
|---|
| 94 | . ; Documented in the same manual.
|
|---|
| 95 | . D NDF^PSS50(MEDIEN,,,,,"CONC")
|
|---|
| 96 | . N NDFDATA M NDFDATA=^TMP($J,"CONC",MEDIEN)
|
|---|
| 97 | . N NDFIEN S NDFIEN=$P(NDFDATA(20),U)
|
|---|
| 98 | . N VAPROD S VAPROD=$P(NDFDATA(22),U)
|
|---|
| 99 | . N CONCDATA
|
|---|
| 100 | . ; If a drug was not matched to NDF, then the NDFIEN is gonna be ""
|
|---|
| 101 | . ; and this will crash the call. So...
|
|---|
| 102 | . I NDFIEN="" S CONCDATA=""
|
|---|
| 103 | . E S CONCDATA=$$CPRS^PSNAPIS(NDFIEN,VAPROD)
|
|---|
| 104 | . S @MAP@("MEDFORMTEXT")=$P(CONCDATA,U,1)
|
|---|
| 105 | . S @MAP@("MEDCONCVALUE")=$P(CONCDATA,U,3)
|
|---|
| 106 | . S @MAP@("MEDCONCUNIT")=$P(CONCDATA,U,4)
|
|---|
| 107 | . S @MAP@("MEDSIZETEXT")=$P(NDFDATA(23),U,2)_" "_$P(NDFDATA(24),U,2)
|
|---|
| 108 | . S @MAP@("MEDQUANTITYVALUE")=$$GET1^DIQ(52.41,RXIEN,12)
|
|---|
| 109 | . ; Oddly, there is no easy place to find the dispense unit.
|
|---|
| 110 | . ; It's not included in the original call, so we have to go to the drug file.
|
|---|
| 111 | . ; That would be DATA^PSS50(IEN,,,,,"SUBSCRIPT")
|
|---|
| 112 | . ; Node 14.5 is the Dispense Unit
|
|---|
| 113 | . D DATA^PSS50(MEDIEN,,,,,"QTY")
|
|---|
| 114 | . N QTYDATA M QTYDATA=^TMP($J,"QTY",MEDIEN)
|
|---|
| 115 | . S @MAP@("MEDQUANTITYUNIT")=QTYDATA(14.5)
|
|---|
| 116 | . ;
|
|---|
| 117 | . ; --- START OF DIRECTIONS ---
|
|---|
| 118 | . ; Sig data is not in any API. We obtain it using the IEN from
|
|---|
| 119 | . ; the PEN API to file 52.41. It's in field 3, which is a multiple.
|
|---|
| 120 | . ; I will be using FM call GETS^DIQ(FILE,IENS,FIELD,FLAGS,TARGET_ROOT)
|
|---|
| 121 | . K FMSIG ; it's passed via the symbol table, so remove any leftovers from last call
|
|---|
| 122 | . D GETS^DIQ(52.41,RXIEN,"3*",,"FMSIG")
|
|---|
| 123 | . N FMSIGNUM S FMSIGNUM=0 ; Sigline number in fileman.
|
|---|
| 124 | . ; FMSIGNUM gets outputted as "IEN,RXIEN,".
|
|---|
| 125 | . ; DIRNUM will be first piece for IEN.
|
|---|
| 126 | . ; DIRNUM is the proper Sigline numer.
|
|---|
| 127 | . ; SIGDATA is the simplfied array. Subscripts are really field numbers
|
|---|
| 128 | . ; in subfile 52.413.
|
|---|
| 129 | . N DIRCNT S DIRCNT=0 ; COUNT OF DIRECTIONS
|
|---|
| 130 | . F S FMSIGNUM=$O(FMSIG(52.413,FMSIGNUM)) Q:FMSIGNUM="" D
|
|---|
| 131 | . . N DIRNUM S DIRNUM=$P(FMSIGNUM,",")
|
|---|
| 132 | . . S DIRCNT=DIRCNT+1 ; INCREMENT DIRECTIONS COUNT
|
|---|
| 133 | . . N SIGDATA M SIGDATA=FMSIG(52.413,FMSIGNUM)
|
|---|
| 134 | . . ; If this is an order for a refill; it's not really a new order; move on to next
|
|---|
| 135 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRECTIONDESCRIPTIONTEXT")="" ; This is reserved for systems not able to generate the sig in components.
|
|---|
| 136 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEINDICATOR")="1" ; means that we are specifying it. See E2369-05.
|
|---|
| 137 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDELIVERYMETHOD")=SIGDATA(13)
|
|---|
| 138 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEVALUE")=SIGDATA(8)
|
|---|
| 139 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDOSEUNIT")=@MAP@("MEDCONCUNIT")
|
|---|
| 140 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDRATEVALUE")="" ; For inpatient
|
|---|
| 141 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDRATEUNIT")="" ; For inpatient
|
|---|
| 142 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDVEHICLETEXT")="" ; For inpatient
|
|---|
| 143 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRECTIONROUTETEXT")=SIGDATA(10)
|
|---|
| 144 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDFREQUENCYVALUE")=SIGDATA(1)
|
|---|
| 145 | . . ; Invervals... again another call.
|
|---|
| 146 | . . ; The schedule is a free text field
|
|---|
| 147 | . . ; However, it gets translated by a call to the administration
|
|---|
| 148 | . . ; schedule file to see if that schedule exists.
|
|---|
| 149 | . . ; That's the same thing I am going to do.
|
|---|
| 150 | . . ; The call is AP^PSS51P1(PSSPP,PSSFT,PSSWDIEN,PSSSTPY,LIST,PSSFREQ).
|
|---|
| 151 | . . ; PSSPP is "PSJ" (for some reason, schedules are stored as PSJ, not PSO--
|
|---|
| 152 | . . ; I looked), PSSFT is the name,
|
|---|
| 153 | . . ; and list is the ^TMP name to store the data in.
|
|---|
| 154 | . . ; Also, freqency may have "PRN" in it, so strip that out
|
|---|
| 155 | . . N FREQ S FREQ=SIGDATA(1)
|
|---|
| 156 | . . I FREQ["PRN" S FREQ=$E(FREQ,1,$F(FREQ,"PRN")-5) ; 5 for $L("PRN") + 1 + sp
|
|---|
| 157 | . . D AP^PSS51P1("PSJ",FREQ,,,"SCHEDULE")
|
|---|
| 158 | . . N SCHEDATA M SCHEDATA=^TMP($J,"SCHEDULE")
|
|---|
| 159 | . . N INTERVAL
|
|---|
| 160 | . . I $P(SCHEDATA(0),U)=-1 S INTERVAL=""
|
|---|
| 161 | . . E D
|
|---|
| 162 | . . . N SUB S SUB=$O(SCHEDATA(0))
|
|---|
| 163 | . . . S INTERVAL=SCHEDATA(SUB,2)
|
|---|
| 164 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDINTERVALVALUE")=INTERVAL
|
|---|
| 165 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDINTERVALUNIT")="Minute"
|
|---|
| 166 | . . ; Duration comes as M2,H2,D2,W2,L2 for 2 minutes,hours,days,weeks,months
|
|---|
| 167 | . . N DUR S DUR=SIGDATA(2)
|
|---|
| 168 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONVALUE")=$E(DUR,2,$L(DUR))
|
|---|
| 169 | . . N DURUNIT S DURUNIT=$E(DUR)
|
|---|
| 170 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDURATIONUNIT")=$S(DURUNIT="M":"Minutes",DURUNIT="H":"Hours",DURUNIT="D":"Days",DURUNIT="W":"Weeks",DURUNIT="L":"Months",1:"")
|
|---|
| 171 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPRNFLAG")=SIGDATA(1)["PRN"
|
|---|
| 172 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMOBJECTID")=""
|
|---|
| 173 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMTYPETXT")=""
|
|---|
| 174 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMDESCRIPTION")=""
|
|---|
| 175 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODEVALUE")=""
|
|---|
| 176 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODINGSYSTEM")=""
|
|---|
| 177 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMCODINGVERSION")=""
|
|---|
| 178 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDPROBLEMSOURCEACTORID")=""
|
|---|
| 179 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDSTOPINDICATOR")="" ; Vista doesn't have that field
|
|---|
| 180 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDDIRSEQ")=DIRNUM
|
|---|
| 181 | . . S @MAP@("M","DIRECTIONS",DIRCNT,"MEDMULDIRMOD")=SIGDATA(6)
|
|---|
| 182 | . ;
|
|---|
| 183 | . ; --- END OF DIRECTIONS ---
|
|---|
| 184 | . ;
|
|---|
| 185 | . ; S @MAP@("MEDPTINSTRUCTIONS","F")="52.41^105"
|
|---|
| 186 | . S @MAP@("MEDPTINSTRUCTIONS")=$G(^PSRX(RXIEN,"PI",1,0)) ;GPL
|
|---|
| 187 | . ; W @MAP@("MEDPTINSTRUCTIONS"),!
|
|---|
| 188 | . ; S @MAP@("MEDFULLFILLMENTINSTRUCTIONS","F")="52.41^9"
|
|---|
| 189 | . S @MAP@("MEDFULLFILLMENTINSTRUCTIONS")=$G(^PSRX(RXIEN,"SIG1",1,0)) ;GPL
|
|---|
| 190 | . ; W @MAP@("MEDFULLFILLMENTINSTRUCTIONS"),!
|
|---|
| 191 | . S @MAP@("MEDRFNO")=$$GET1^DIQ(52.41,RXIEN,13)
|
|---|
| 192 | . N RESULT S RESULT=$NA(^TMP("GPLCCR",$J,"MAPPED"))
|
|---|
| 193 | . K @RESULT
|
|---|
| 194 | . D MAP^GPLXPATH(MINXML,MAP,RESULT)
|
|---|
| 195 | . ; D PARY^GPLXPATH(RESULT)
|
|---|
| 196 | . ; MAPPING DIRECTIONS
|
|---|
| 197 | . N MEDDIR1,DIRXML1 S DIRXML1="MEDDIR1" ; VARIABLE AND NAME VARIABLE TEMPLATE
|
|---|
| 198 | . N MEDDIR2,DIRXML2 S DIRXML2="MEDDIR2" ; VARIABLE AND NAME VARIABLE RESULT
|
|---|
| 199 | . D QUERY^GPLXPATH(MINXML,"//Medications/Medication/Directions",DIRXML1)
|
|---|
| 200 | . D REPLACE^GPLXPATH(RESULT,"","//Medications/Medication/Directions")
|
|---|
| 201 | . ; N MDZ1,MDZNA
|
|---|
| 202 | . I DIRCNT>0 D ; IF THERE ARE DIRCTIONS
|
|---|
| 203 | . . F MDZ1=1:1:DIRCNT D ; FOR EACH DIRECTION
|
|---|
| 204 | . . . S MDZNA=$NA(@MAP@("M","DIRECTIONS",MDZ1))
|
|---|
| 205 | . . . D MAP^GPLXPATH(DIRXML1,MDZNA,DIRXML2)
|
|---|
| 206 | . . . D INSERT^GPLXPATH(RESULT,DIRXML2,"//Medications/Medication")
|
|---|
| 207 | . D:MEDCOUNT=1 CP^GPLXPATH(RESULT,OUTXML) ; First one is a copy
|
|---|
| 208 | . D:MEDCOUNT>1 INSINNER^GPLXPATH(OUTXML,RESULT) ; AFTER THE FIRST, INSERT INNER XML
|
|---|
| 209 | N MEDTMP,MEDI
|
|---|
| 210 | D MISSING^GPLXPATH(OUTXML,"MEDTMP") ; SEARCH XML FOR MISSING VARS
|
|---|
| 211 | I MEDTMP(0)>0 D ; IF THERE ARE MISSING VARS - MARKED AS @@X@@
|
|---|
| 212 | . W "MEDICATION MISSING ",!
|
|---|
| 213 | . F MEDI=1:1:MEDTMP(0) W MEDTMP(MEDI),!
|
|---|
| 214 | Q
|
|---|
| 215 | ; |
|---|
