source: ccr/trunk/p/GPLCCD.m@ 74

Last change on this file since 74 was 74, checked in by George Lilly, 16 years ago

First commit for CCD
File size: 10.2 KB
Line 
1GPLCCD ; CCDCCR/GPL - CCD MAIN PROCESSING; 6/6/08
2 ;;0.1;CCDCCR;nopatch;noreleasedate
3 ;Copyright 2008 WorldVistA. Licensed under the terms of the GNU
4 ;General Public License See attached copy of the License.
5 ;
6 ;This program is free software; you can redistribute it and/or modify
7 ;it under the terms of the GNU General Public License as published by
8 ;the Free Software Foundation; either version 2 of the License, or
9 ;(at your option) any later version.
10 ;
11 ;This program is distributed in the hope that it will be useful,
12 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 ;GNU General Public License for more details.
15 ;
16 ;You should have received a copy of the GNU General Public License along
17 ;with this program; if not, write to the Free Software Foundation, Inc.,
18 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
19 ;
20 ; EXPORT A CCR
21 ;
22EXPORT ; EXPORT ENTRY POINT FOR CCR
23 ; Select a patient.
24 S DIC=2,DIC(0)="AEMQ" D ^DIC
25 I Y<1 Q ; EXIT
26 S DFN=$P(Y,U,1) ; SET THE PATIENT
27 ; N CCRGLO
28 D CCRRPC(.CCRGLO,DFN,"CCD","","","")
29 S OARY=$NA(^TMP("GPLCCR",$J,DFN,"CCD",1))
30 S ONAM="PAT_"_DFN_"_CCD_V1.xml"
31 S ODIRGLB=$NA(^TMP("GPLCCR","ODIR"))
32 I '$D(@ODIRGLB) D ; IF NOT ODIR HAS BEEN SET
33 . S @ODIRGLB="/home/glilly/CCROUT"
34 . ;S @ODIRGLB="/home/cedwards/"
35 . ;S @ODIRGLB="/opt/wv/p/"
36 S ODIR=@ODIRGLB
37 D OUTPUT^GPLXPATH(OARY,ONAM,ODIR)
38 Q
39 ;
40CCRRPC(CCRGRTN,DFN,CCRPART,TIME1,TIME2,HDRARY) ;RPC ENTRY POINT FOR CCR OUTPUT
41 ; CCRGRTN IS RETURN ARRAY PASSED BY NAME
42 ; DFN IS PATIENT IEN
43 ; CCRPART IS "CCR" FOR ENTIRE CCR, OR SECTION NAME FOR A PART
44 ; OF THE CCR BODY.. PARTS INCLUDE "PROBLEMS" "VITALS" ETC
45 ; TIME1 IS STARTING TIME TO INCLUDE - NULL MEANS ALL
46 ; TIME2 IS ENDING TIME TO INCLUDE TIME IS FILEMAN TIME
47 ; - NULL MEANS NOW
48 ; HDRARY IS THE HEADER ARRAY DEFINING THE "FROM" AND
49 ; "TO" VARIABLES
50 ; IF NULL WILL DEFAULT TO "FROM" DUZ AND "TO" DFN
51 S DEBUG=0
52 N CCD S CCD=0 ; FLAG FOR PROCESSING A CCD
53 I CCRPART="CCD" S CCD=1 ; WE ARE PROCESSING A CCD
54 S TGLOBAL=$NA(^TMP("GPLCCR",$J,"TEMPLATE")) ; GLOBAL FOR STORING TEMPLATE
55 I CCD S CCRGLO=$NA(^TMP("GPLCCR",$J,DFN,"CCD")) ; GLOBAL FOR THE CCD
56 E S CCRGLO=$NA(^TMP("GPLCCR",$J,DFN,"CCR")) ; GLOBAL FOR BUILDING THE CCR
57 S ACTGLO=$NA(^TMP("GPLCCR",$J,DFN,"ACTORS")) ; GLOBAL FOR ALL ACTORS
58 ; TO GET PART OF THE CCR RETURNED, PASS CCRPART="PROBLEMS" ETC
59 S CCRGRTN=$NA(^TMP("GPLCCR",$J,DFN,CCRPART)) ; RTN GLO NM OF PART OR ALL
60 I CCD D LOAD^GPLCCD1(TGLOBAL) ; LOAD THE CCR TEMPLATE
61 E D LOAD^GPLCCR0(TGLOBAL) ; LOAD THE CCR TEMPLATE
62 D CP^GPLXPATH(TGLOBAL,CCRGLO) ; COPY THE TEMPLATE TO CCR GLOBAL
63 S CAPSAVE=@TGLOBAL@(3) ; SAVE THE CCD ROOT
64 S CAPSAVE2=@TGLOBAL@(@TGLOBAL@(0)) ; SAVE LAST LINE OF CCD
65 S @CCRGLO@(3)="<ContinuityOfCareRecord>" ; CAP WITH CCR ROOT
66 S @TGLOBAL@(3)=@CCRGLO@(3) ; CAP THE TEMPLATE TOO
67 S @CCRGLO@(@CCRGLO@(0))="</ContinuityOfCareRecord>" ; FINISH CAP
68 S @TGLOBAL@(@TGLOBAL@(0))="</ContinuityOfCareRecord>" ; FINISH CAP TEMP
69 ;
70 ; DELETE THE BODY, ACTORS AND SIGNATURES SECTIONS FROM GLOBAL
71 ; THESE WILL BE POPULATED AFTER CALLS TO THE XPATH ROUTINES
72 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Body")
73 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Actors")
74 I 'CCD D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Signatures")
75 I DEBUG F I=1:1:@CCRGLO@(0) W @CCRGLO@(I),!
76 ;
77 D HDRMAP(CCRGLO,DFN,HDRARY) ; MAP HEADER VARIABLES
78 ;
79 K ^TMP("GPLCCR",$J,"CCRSTEP") ; KILL GLOBAL PRIOR TO ADDING TO IT
80 S CCRXTAB=$NA(^TMP("GPLCCR",$J,"CCRSTEP")) ; GLOBAL TO STORE CCR STEPS
81 D INITSTPS(CCRXTAB) ; INITIALIZED CCR PROCESSING STEPS
82 N I,XI,TAG,RTN,CALL,XPATH,IXML,OXML,INXML,CCRBLD
83 F I=1:1:@CCRXTAB@(0) D ; PROCESS THE CCR BODY SECTIONS
84 . S XI=@CCRXTAB@(I) ; CALL COPONENTS TO PARSE
85 . S RTN=$P(XI,";",2) ; NAME OF ROUTINE TO CALL
86 . S TAG=$P(XI,";",1) ; LABEL INSIDE ROUTINE TO CALL
87 . S XPATH=$P(XI,";",3) ; XPATH TO XML TO PASS TO ROUTINE
88 . D QUERY^GPLXPATH(TGLOBAL,XPATH,"INXML") ; EXTRACT XML TO PASS
89 . S IXML="INXML"
90 . I CCD D SHAVE(IXML) ; REMOVE ALL BUT REPEATING PARTS OF TEMPLATE SECTION
91 . S OXML=$P(XI,";",4) ; ARRAY FOR SECTION VALUES
92 . ; W OXML,!
93 . S CALL="D "_TAG_"^"_RTN_"(IXML,DFN,OXML)" ; SETUP THE CALL
94 . W "RUNNING ",CALL,!
95 . X CALL
96 . I CCD D QUERY^GPLXPATH(TGLOBAL,XPATH,"ITMP") ; XML TO UNSHAVE WITH
97 . I CCD D UNSHAVE("ITMP",OXML)
98 . ; NOW INSERT THE RESULTS IN THE CCR BUFFER
99 . D INSERT^GPLXPATH(CCRGLO,OXML,"//ContinuityOfCareRecord/Body")
100 . I DEBUG F GPLI=1:1:@OXML@(0) W @OXML@(GPLI),!
101 D ACTLST^GPLCCR(CCRGLO,ACTGLO) ; GEN THE ACTOR LIST
102 D QUERY^GPLXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","ACTT")
103 D EXTRACT^GPLACTORS("ACTT",ACTGLO,"ACTT2")
104 D INSINNER^GPLXPATH(CCRGLO,"ACTT2","//ContinuityOfCareRecord/Actors")
105 N I,J,DONE S DONE=0
106 F I=0:0 D Q:DONE ; DELETE UNTIL ALL EMPTY ELEMENTS ARE GONE
107 . S J=$$TRIM^GPLXPATH(CCRGLO) ; DELETE EMPTY ELEMENTS
108 . W "TRIMMED",J,!
109 . I J=0 S DONE=1 ; DONE WHEN TRIM RETURNS FALSE
110 S @CCRGLO@(3)=CAPSAVE ; UNCAP - TURN IT BACK INTO A CCD
111 S @CCRGLO@(@CCRGLO@(0))=CAPSAVE2 ; UNCAP LAST LINE
112 Q
113 ;
114INITSTPS(TAB) ; INITIALIZE CCR PROCESSING STEPS
115 ; TAB IS PASSED BY NAME
116 W "TAB= ",TAB,!
117 ; ORDER FOR CCR IS PROBLEMS,FAMILYHISTORY,SOCIALHISTORY,MEDICATIONS,VITALSIGNS,RESULTS,HEALTHCAREPROVIDERS
118 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLPROBS;//ContinuityOfCareRecord/Body/Problems;^TMP(""GPLCCR"",$J,DFN,""PROBLEMS"")")
119 ;D PUSH^GPLXPATH(TAB,"EXTRACT;GPLMEDS;//ContinuityOfCareRecord/Body/Medications;^TMP(""GPLCCR"",$J,DFN,""MEDICATIONS"")")
120 I 'CCD D PUSH^GPLXPATH(TAB,"EXTRACT;GPLVITALS;//ContinuityOfCareRecord/Body/VitalSigns;^TMP(""GPLCCR"",$J,DFN,""VITALS"")")
121 Q
122 ;
123SHAVE(SHXML) ; REMOVES THE 2-6 AND N-1 AND N-2 LINES FROM A COMPONENT
124 ; NEEDED TO EXPOSE THE REPEATING PARTS FOR GENERATION
125 N SHTMP,SHBLD ; TEMP ARRAY AND BUILD LIST
126 W SHXML,!
127 W @SHXML@(1),!
128 D QUEUE^GPLXPATH("SHBLD",SHXML,1,1) ; THE FIRST LINE IS NEEDED
129 D QUEUE^GPLXPATH("SHBLD",SHXML,7,@SHXML@(0)-3) ; REPEATING PART
130 D QUEUE^GPLXPATH("SHBLD",SHXML,@SHXML@(0),@SHXML@(0)) ; LAST LINE
131 D PARY^GPLXPATH("SHBLD") ; PRINT BUILD LIST
132 D BUILD^GPLXPATH("SHBLD","SHTMP") ; BUILD EDITED SECTION
133 D CP^GPLXPATH("SHTMP",SHXML) ; COPY RESULT TO PASSED ARRAY
134 Q
135 ;
136UNSHAVE(ORIGXML,SHXML) ; REPLACES THE 2-6 AND N-1 AND N-2 LINES FROM TEMPLATE
137 ; NEEDED TO RESTORM FIXED TOP AND BOTTOM OF THE COMPONENT XML
138 N SHTMP,SHBLD ; TEMP ARRAY AND BUILD LIST
139 W SHXML,!
140 W @SHXML@(1),!
141 D QUEUE^GPLXPATH("SHBLD",ORIGXML,1,6) ; FIRST 6 LINES OF TEMPLATE
142 D QUEUE^GPLXPATH("SHBLD",SHXML,2,@SHXML@(0)-1) ; INS ALL BUT FIRST/LAST
143 D QUEUE^GPLXPATH("SHBLD",ORIGXML,@ORIGXML@(0)-2,@ORIGXML@(0)) ; FROM TEMP
144 D PARY^GPLXPATH("SHBLD") ; PRINT BUILD LIST
145 D BUILD^GPLXPATH("SHBLD","SHTMP") ; BUILD EDITED SECTION
146 D CP^GPLXPATH("SHTMP",SHXML) ; COPY RESULT TO PASSED ARRAY
147 Q
148 ;
149HDRMAP(CXML,DFN,IHDR) ; MAP HEADER VARIABLES: FROM, TO ECT
150 N VMAP S VMAP=$NA(^TMP("GPLCCR",$J,DFN,"HEADER"))
151 ; K @VMAP
152 S @VMAP@("DATETIME")=$$FMDTOUTC^CCRUTIL($$NOW^XLFDT,"DT")
153 I IHDR="" D ; HEADER ARRAY IS NOT PROVIDED, USE DEFAULTS
154 . S @VMAP@("ACTORPATIENT")="ACTORPATIENT_"_DFN
155 . S @VMAP@("ACTORFROM")="ACTORORGANIZATION_"_DUZ ; FROM DUZ - ???
156 . S @VMAP@("ACTORFROM2")="ACTORSYSTEM_1" ; SECOND FROM IS THE SYSTEM
157 . S @VMAP@("ACTORTO")="ACTORPATIENT_"_DFN ; FOR TEST PURPOSES
158 . S @VMAP@("PURPOSEDESCRIPTION")="CEND PHR" ; FOR TEST PURPOSES
159 . S @VMAP@("ACTORTOTEXT")="Patient" ; FOR TEST PURPOSES
160 . ; THIS IS THE USE CASE FOR THE PHR WHERE "TO" IS THE PATIENT
161 I IHDR'="" D ; HEADER VALUES ARE PROVIDED
162 . D CP^GPLXPATH(IHDR,VMAP) ; COPY HEADER VARIABLES TO MAP ARRAY
163 N CTMP
164 D MAP^GPLXPATH(CXML,VMAP,"CTMP")
165 D CP^GPLXPATH("CTMP",CXML)
166 Q
167 ;
168ACTLST(AXML,ACTRTN) ; RETURN THE ACTOR LIST FOR THE XML IN AXML
169 ; AXML AND ACTRTN ARE PASSED BY NAME
170 ; EACH ACTOR RECORD HAS 3 PARTS - IE IF OBJECTID=ACTORPATIENT_2
171 ; P1= OBJECTID - ACTORPATIENT_2
172 ; P2= OBJECT TYPE - PATIENT OR PROVIDER OR SOFTWARE
173 ;OR INSTITUTION
174 ; OR PERSON(IN PATIENT FILE IE NOK)
175 ; P3= IEN RECORD NUMBER FOR ACTOR - 2
176 N I,J,K,L
177 K @ACTRTN ; CLEAR RETURN ARRAY
178 F I=1:1:@AXML@(0) D ; SCAN ALL LINES
179 . I @AXML@(I)?.E1"<ActorID>".E D ; THERE IS AN ACTOR THIS LINE
180 . . S J=$P($P(@AXML@(I),"<ActorID>",2),"</ActorID>",1)
181 . . W "<ActorID>=>",J,!
182 . . I J'="" S K(J)="" ; HASHING ACTOR
183 . . ; TO GET RID OF DUPLICATES
184 S I="" ; GOING TO $O THROUGH THE HASH
185 F J=0:0 D Q:$O(K(I))=""
186 . S I=$O(K(I)) ; WALK THROUGH THE HASH OF ACTORS
187 . S $P(L,U,1)=I ; FIRST PIECE IS THE OBJECT ID
188 . S $P(L,U,2)=$P($P(I,"ACTOR",2),"_",1) ; ACTOR TYPE
189 . S $P(L,U,3)=$P(I,"_",2) ; IEN RECORD NUMBER FOR ACTOR
190 . D PUSH^GPLXPATH(ACTRTN,L) ; ADD THE ACTOR TO THE RETURN ARRAY
191 Q
192 ;
193TEST ; RUN ALL THE TEST CASES
194 D TESTALL^GPLUNIT("GPLCCR")
195 Q
196 ;
197ZTEST(WHICH) ; RUN ONE SET OF TESTS
198 N ZTMP
199 D ZLOAD^GPLUNIT("ZTMP","GPLCCR")
200 D ZTEST^GPLUNIT(.ZTMP,WHICH)
201 Q
202 ;
203TLIST ; LIST THE TESTS
204 N ZTMP
205 D ZLOAD^GPLUNIT("ZTMP","GPLCCR")
206 D TLIST^GPLUNIT(.ZTMP)
207 Q
208 ;
209 ;;><TEST>
210 ;;><PROBLEMS>
211 ;;>>>K GPL S GPL=""
212 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","PROBLEMS","","","")
213 ;;>>?@GPL@(@GPL@(0))["</Problems>"
214 ;;><VITALS>
215 ;;>>>K GPL S GPL=""
216 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","VITALS","","","")
217 ;;>>?@GPL@(@GPL@(0))["</VitalSigns>"
218 ;;><CCR>
219 ;;>>>K GPL S GPL=""
220 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCR","","","")
221 ;;>>?@GPL@(@GPL@(0))["</ContinuityOfCareRecord>"
222 ;;><ACTLST>
223 ;;>>>K GPL S GPL=""
224 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCR","","","")
225 ;;>>>D ACTLST^GPLCCR(GPL,"ACTTEST")
226 ;;><ACTORS>
227 ;;>>>D ZTEST^GPLCCR("ACTLST")
228 ;;>>>D QUERY^GPLXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","G2")
229 ;;>>>D EXTRACT^GPLACTORS("G2","ACTTEST","G3")
230 ;;>>?G3(G3(0))["</Actors>"
231 ;;><TRIM>
232 ;;>>>D ZTEST^GPLCCR("CCR")
233 ;;>>>W $$TRIM^GPLXPATH(CCRGLO)
234 ;;><CCD>
235 ;;>>>K GPL S GPL=""
236 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCD","","","")
237 ;;>>?@GPL@(@GPL@(0))["</ContinuityOfCareRecord>"
238 ;;></TEST>
Note: See TracBrowser for help on using the repository browser.