source: ccr/trunk/p/GPLCCR.m@ 76

Last change on this file since 76 was 76, checked in by George Lilly, 16 years ago

Fixed CCD structure, added Narrative to Problems
File size: 8.1 KB
Line 
1GPLCCR ; CCDCCR/GPL - CCR MAIN PROCESSING; 6/6/08
2 ;;0.1;CCDCCR;nopatch;noreleasedate
3 ;Copyright 2008 WorldVistA. Licensed under the terms of the GNU
4 ;General Public License See attached copy of the License.
5 ;
6 ;This program is free software; you can redistribute it and/or modify
7 ;it under the terms of the GNU General Public License as published by
8 ;the Free Software Foundation; either version 2 of the License, or
9 ;(at your option) any later version.
10 ;
11 ;This program is distributed in the hope that it will be useful,
12 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 ;GNU General Public License for more details.
15 ;
16 ;You should have received a copy of the GNU General Public License along
17 ;with this program; if not, write to the Free Software Foundation, Inc.,
18 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
19 ;
20 ; EXPORT A CCR
21 ;
22EXPORT ; EXPORT ENTRY POINT FOR CCR
23 ; Select a patient.
24 S DIC=2,DIC(0)="AEMQ" D ^DIC
25 I Y<1 Q ; EXIT
26 S DFN=$P(Y,U,1) ; SET THE PATIENT
27 N CCRGLO
28 D CCRRPC(.CCRGLO,DFN,"CCR","","","")
29 S OARY=$NA(^TMP("GPLCCR",$J,DFN,"CCR",1))
30 S ONAM="PAT_"_DFN_"_CCR_V1.xml"
31 S ODIRGLB=$NA(^TMP("GPLCCR","ODIR"))
32 I '$D(@ODIRGLB) D ; IF NOT ODIR HAS BEEN SET
33 . S @ODIRGLB="/home/glilly/CCROUT"
34 . ;S @ODIRGLB="/home/cedwards/"
35 . ;S @ODIRGLB="/opt/wv/p/"
36 S ODIR=@ODIRGLB
37 D OUTPUT^GPLXPATH(OARY,ONAM,ODIR)
38 Q
39 ;
40CCRRPC(CCRGRTN,DFN,CCRPART,TIME1,TIME2,HDRARY) ;RPC ENTRY POINT FOR CCR OUTPUT
41 ; CCRGRTN IS RETURN ARRAY PASSED BY NAME
42 ; DFN IS PATIENT IEN
43 ; CCRPART IS "CCR" FOR ENTIRE CCR, OR SECTION NAME FOR A PART
44 ; OF THE CCR BODY.. PARTS INCLUDE "PROBLEMS" "VITALS" ETC
45 ; TIME1 IS STARTING TIME TO INCLUDE - NULL MEANS ALL
46 ; TIME2 IS ENDING TIME TO INCLUDE TIME IS FILEMAN TIME
47 ; - NULL MEANS NOW
48 ; HDRARY IS THE HEADER ARRAY DEFINING THE "FROM" AND
49 ; "TO" VARIABLES
50 ; IF NULL WILL DEFAULT TO "FROM" DUZ AND "TO" DFN
51 S DEBUG=0
52 S CCD=0 ; NEED THIS FLAG TO DISTINGUISH FROM CCD
53 S TGLOBAL=$NA(^TMP("GPLCCR",$J,"TEMPLATE")) ; GLOBAL FOR STORING TEMPLATE
54 S CCRGLO=$NA(^TMP("GPLCCR",$J,DFN,"CCR")) ; GLOBAL FOR BUILDING THE CCR
55 S ACTGLO=$NA(^TMP("GPLCCR",$J,DFN,"ACTORS")) ; GLOBAL FOR ALL ACTORS
56 ; TO GET PART OF THE CCR RETURNED, PASS CCRPART="PROBLEMS" ETC
57 S CCRGRTN=$NA(^TMP("GPLCCR",$J,DFN,CCRPART)) ; RTN GLO NM OF PART OR ALL
58 D LOAD^GPLCCR0(TGLOBAL) ; LOAD THE CCR TEMPLATE
59 D CP^GPLXPATH(TGLOBAL,CCRGLO) ; COPY THE TEMPLATE TO CCR GLOBAL
60 ;
61 ; DELETE THE BODY, ACTORS AND SIGNATURES SECTIONS FROM GLOBAL
62 ; THESE WILL BE POPULATED AFTER CALLS TO THE XPATH ROUTINES
63 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Body")
64 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Actors")
65 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Signatures")
66 I DEBUG F I=1:1:@CCRGLO@(0) W @CCRGLO@(I),!
67 ;
68 D HDRMAP(CCRGLO,DFN,HDRARY) ; MAP HEADER VARIABLES
69 ;
70 K ^TMP("GPLCCR",$J,"CCRSTEP") ; KILL GLOBAL PRIOR TO ADDING TO IT
71 S CCRXTAB=$NA(^TMP("GPLCCR",$J,"CCRSTEP")) ; GLOBAL TO STORE CCR STEPS
72 D INITSTPS(CCRXTAB) ; INITIALIZED CCR PROCESSING STEPS
73 N I,XI,TAG,RTN,CALL,XPATH,IXML,OXML,INXML,CCRBLD
74 F I=1:1:@CCRXTAB@(0) D ; PROCESS THE CCR BODY SECTIONS
75 . S XI=@CCRXTAB@(I) ; CALL COPONENTS TO PARSE
76 . S RTN=$P(XI,";",2) ; NAME OF ROUTINE TO CALL
77 . S TAG=$P(XI,";",1) ; LABEL INSIDE ROUTINE TO CALL
78 . S XPATH=$P(XI,";",3) ; XPATH TO XML TO PASS TO ROUTINE
79 . D QUERY^GPLXPATH(TGLOBAL,XPATH,"INXML") ; EXTRACT XML TO PASS
80 . S IXML="INXML"
81 . S OXML=$P(XI,";",4) ; ARRAY FOR SECTION VALUES
82 . ; W OXML,!
83 . S CALL="D "_TAG_"^"_RTN_"(IXML,DFN,OXML)" ; SETUP THE CALL
84 . W "RUNNING ",CALL,!
85 . X CALL
86 . ; NOW INSERT THE RESULTS IN THE CCR BUFFER
87 . D INSERT^GPLXPATH(CCRGLO,OXML,"//ContinuityOfCareRecord/Body")
88 . I DEBUG F GPLI=1:1:@OXML@(0) W @OXML@(GPLI),!
89 D ACTLST^GPLCCR(CCRGLO,ACTGLO) ; GEN THE ACTOR LIST
90 D QUERY^GPLXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","ACTT")
91 D EXTRACT^GPLACTORS("ACTT",ACTGLO,"ACTT2")
92 D INSINNER^GPLXPATH(CCRGLO,"ACTT2","//ContinuityOfCareRecord/Actors")
93 N I,J,DONE S DONE=0
94 F I=0:0 D Q:DONE ; DELETE UNTIL ALL EMPTY ELEMENTS ARE GONE
95 . S J=$$TRIM^GPLXPATH(CCRGLO) ; DELETE EMPTY ELEMENTS
96 . W "TRIMMED",J,!
97 . I J=0 S DONE=1 ; DONE WHEN TRIM RETURNS FALSE
98 Q
99 ;
100INITSTPS(TAB) ; INITIALIZE CCR PROCESSING STEPS
101 ; TAB IS PASSED BY NAME
102 W "TAB= ",TAB,!
103 ; ORDER FOR CCR IS PROBLEMS,FAMILYHISTORY,SOCIALHISTORY,MEDICATIONS,VITALSIGNS,RESULTS,HEALTHCAREPROVIDERS
104 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLPROBS;//ContinuityOfCareRecord/Body/Problems;^TMP(""GPLCCR"",$J,DFN,""PROBLEMS"")")
105 ;D PUSH^GPLXPATH(TAB,"EXTRACT;GPLMEDS;//ContinuityOfCareRecord/Body/Medications;^TMP(""GPLCCR"",$J,DFN,""MEDICATIONS"")")
106 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLVITALS;//ContinuityOfCareRecord/Body/VitalSigns;^TMP(""GPLCCR"",$J,DFN,""VITALS"")")
107 Q
108 ;
109HDRMAP(CXML,DFN,IHDR) ; MAP HEADER VARIABLES: FROM, TO ECT
110 N VMAP S VMAP=$NA(^TMP("GPLCCR",$J,DFN,"HEADER"))
111 ; K @VMAP
112 S @VMAP@("DATETIME")=$$FMDTOUTC^CCRUTIL($$NOW^XLFDT,"DT")
113 I IHDR="" D ; HEADER ARRAY IS NOT PROVIDED, USE DEFAULTS
114 . S @VMAP@("ACTORPATIENT")="ACTORPATIENT_"_DFN
115 . S @VMAP@("ACTORFROM")="ACTORORGANIZATION_"_DUZ ; FROM DUZ - ???
116 . S @VMAP@("ACTORFROM2")="ACTORSYSTEM_1" ; SECOND FROM IS THE SYSTEM
117 . S @VMAP@("ACTORTO")="ACTORPATIENT_"_DFN ; FOR TEST PURPOSES
118 . S @VMAP@("PURPOSEDESCRIPTION")="CEND PHR" ; FOR TEST PURPOSES
119 . S @VMAP@("ACTORTOTEXT")="Patient" ; FOR TEST PURPOSES
120 . ; THIS IS THE USE CASE FOR THE PHR WHERE "TO" IS THE PATIENT
121 I IHDR'="" D ; HEADER VALUES ARE PROVIDED
122 . D CP^GPLXPATH(IHDR,VMAP) ; COPY HEADER VARIABLES TO MAP ARRAY
123 N CTMP
124 D MAP^GPLXPATH(CXML,VMAP,"CTMP")
125 D CP^GPLXPATH("CTMP",CXML)
126 Q
127 ;
128ACTLST(AXML,ACTRTN) ; RETURN THE ACTOR LIST FOR THE XML IN AXML
129 ; AXML AND ACTRTN ARE PASSED BY NAME
130 ; EACH ACTOR RECORD HAS 3 PARTS - IE IF OBJECTID=ACTORPATIENT_2
131 ; P1= OBJECTID - ACTORPATIENT_2
132 ; P2= OBJECT TYPE - PATIENT OR PROVIDER OR SOFTWARE
133 ;OR INSTITUTION
134 ; OR PERSON(IN PATIENT FILE IE NOK)
135 ; P3= IEN RECORD NUMBER FOR ACTOR - 2
136 N I,J,K,L
137 K @ACTRTN ; CLEAR RETURN ARRAY
138 F I=1:1:@AXML@(0) D ; SCAN ALL LINES
139 . I @AXML@(I)?.E1"<ActorID>".E D ; THERE IS AN ACTOR THIS LINE
140 . . S J=$P($P(@AXML@(I),"<ActorID>",2),"</ActorID>",1)
141 . . W "<ActorID>=>",J,!
142 . . I J'="" S K(J)="" ; HASHING ACTOR
143 . . ; TO GET RID OF DUPLICATES
144 S I="" ; GOING TO $O THROUGH THE HASH
145 F J=0:0 D Q:$O(K(I))=""
146 . S I=$O(K(I)) ; WALK THROUGH THE HASH OF ACTORS
147 . S $P(L,U,1)=I ; FIRST PIECE IS THE OBJECT ID
148 . S $P(L,U,2)=$P($P(I,"ACTOR",2),"_",1) ; ACTOR TYPE
149 . S $P(L,U,3)=$P(I,"_",2) ; IEN RECORD NUMBER FOR ACTOR
150 . D PUSH^GPLXPATH(ACTRTN,L) ; ADD THE ACTOR TO THE RETURN ARRAY
151 Q
152 ;
153TEST ; RUN ALL THE TEST CASES
154 D TESTALL^GPLUNIT("GPLCCR")
155 Q
156 ;
157ZTEST(WHICH) ; RUN ONE SET OF TESTS
158 N ZTMP
159 D ZLOAD^GPLUNIT("ZTMP","GPLCCR")
160 D ZTEST^GPLUNIT(.ZTMP,WHICH)
161 Q
162 ;
163TLIST ; LIST THE TESTS
164 N ZTMP
165 D ZLOAD^GPLUNIT("ZTMP","GPLCCR")
166 D TLIST^GPLUNIT(.ZTMP)
167 Q
168 ;
169 ;;><TEST>
170 ;;><PROBLEMS>
171 ;;>>>K GPL S GPL=""
172 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","PROBLEMS","","","")
173 ;;>>?@GPL@(@GPL@(0))["</Problems>"
174 ;;><VITALS>
175 ;;>>>K GPL S GPL=""
176 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","VITALS","","","")
177 ;;>>?@GPL@(@GPL@(0))["</VitalSigns>"
178 ;;><CCR>
179 ;;>>>K GPL S GPL=""
180 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCR","","","")
181 ;;>>?@GPL@(@GPL@(0))["</ContinuityOfCareRecord>"
182 ;;><ACTLST>
183 ;;>>>K GPL S GPL=""
184 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCR","","","")
185 ;;>>>D ACTLST^GPLCCR(GPL,"ACTTEST")
186 ;;><ACTORS>
187 ;;>>>D ZTEST^GPLCCR("ACTLST")
188 ;;>>>D QUERY^GPLXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","G2")
189 ;;>>>D EXTRACT^GPLACTORS("G2","ACTTEST","G3")
190 ;;>>?G3(G3(0))["</Actors>"
191 ;;><TRIM>
192 ;;>>>D ZTEST^GPLCCR("CCR")
193 ;;>>>W $$TRIM^GPLXPATH(CCRGLO)
194 ;;><CCD>
195 ;;>>>K GPL S GPL=""
196 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCD","","","")
197 ;;>>?@GPL@(@GPL@(0))["</ContinuityOfCareRecord>"
198 ;;></TEST>
Note: See TracBrowser for help on using the repository browser.