| 1 | GPLRIMA ; CCDCCR/GPL - RIM REPORT ROUTINES; 6/6/08
|
|---|
| 2 | ;;0.1;CCDCCR;nopatch;noreleasedate
|
|---|
| 3 | ;Copyright 2008 WorldVistA. Licensed under the terms of the GNU
|
|---|
| 4 | ;General Public License See attached copy of the License.
|
|---|
| 5 | ;
|
|---|
| 6 | ;This program is free software; you can redistribute it and/or modify
|
|---|
| 7 | ;it under the terms of the GNU General Public License as published by
|
|---|
| 8 | ;the Free Software Foundation; either version 2 of the License, or
|
|---|
| 9 | ;(at your option) any later version.
|
|---|
| 10 | ;
|
|---|
| 11 | ;This program is distributed in the hope that it will be useful,
|
|---|
| 12 | ;but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 13 | ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 14 | ;GNU General Public License for more details.
|
|---|
| 15 | ;
|
|---|
| 16 | ;You should have received a copy of the GNU General Public License along
|
|---|
| 17 | ;with this program; if not, write to the Free Software Foundation, Inc.,
|
|---|
| 18 | ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
|
|---|
| 19 | ;
|
|---|
| 20 | ; THESE ROUTINES EXAMINE ONE OR MORE, UP TO ALL, OF THE PATIENTS ON THE
|
|---|
| 21 | ; SYSTEM TO DETERMINE HOW COMPLETE THE RESULTING CCR OR CCD WOULD BE FOR
|
|---|
| 22 | ; THESE PATIENTS. IT BEGINS TO MEASURE "HL7 RIM COHERENCE" WHICH IS HOW USEFUL
|
|---|
| 23 | ; THE VARIABLES WILL BE TO A RIM-MODELED APPLICATION AFTER THEY ARE
|
|---|
| 24 | ; CONVEYED VIA THE CCR OR CCD.
|
|---|
| 25 | ; FACTORS THAT AFFECT RIM COHERENCE INCLUDE:
|
|---|
| 26 | ; 1. THE PRESENSE OF CLINICAL DATA IN A SECTION
|
|---|
| 27 | ; 2. ARE THE DATA ELEMENTS TIME-BOUND
|
|---|
| 28 | ; 3. ARE THE DATA ELEMENTS CODED WITH SNOMED OR LOINC ETC
|
|---|
| 29 | ; 4. ARE SOURCE ACTORS ASSOCIATED WITH THE DATA ELEMENTS
|
|---|
| 30 | ; 5. ARE ACTORS IDENTIFIED REGARDING THEIR ROLE
|
|---|
| 31 | ; .. AND OTHER FACTORS YET TO BE DETERMINED
|
|---|
| 32 | ;
|
|---|
| 33 | ; SINCE THESE MEASUREMENTS ARE DONE AT THE VARIABLE LEVEL, THEY
|
|---|
| 34 | ; REFLECT ON RIM COHERENCE WHETHER THE CCR OR THE CCD IS USED FOR
|
|---|
| 35 | ; CONVEYANCE TO THE RIM APPLICATION.
|
|---|
| 36 | ;
|
|---|
| 37 | ;
|
|---|
| 38 | ANALYZE(BEGDFN,DFNCNT) ; RIM COHERANCE ANALYSIS ROUTINE
|
|---|
| 39 | ; BEGINS AT BEGDFN AND GOES FOR DFNCNT PATIENTS
|
|---|
| 40 | ; TO RESUME AT NEXT PATIENT, USE BEGDFN=""
|
|---|
| 41 | ; USE RESET^GPLRIMA TO RESET TO TOP OF PATIENT LIST
|
|---|
| 42 | ;
|
|---|
| 43 | N RIMARY,RIMTMP,RIMI,RIMDFN,RATTR
|
|---|
| 44 | N CCRGLO
|
|---|
| 45 | D ASETUP ; SET UP VARIABLES AND GLOBALS
|
|---|
| 46 | D AINIT ; INITIALIZE ATTRIBUTE VALUE TABLE
|
|---|
| 47 | I '$D(@RIMBASE@("RESUME")) S @RIMBASE@("RESUME")=$O(^DPT(0)) ; FIRST TIME
|
|---|
| 48 | S RESUME=@RIMBASE@("RESUME") ; WHERE WE LEFT OFF LAST RUN
|
|---|
| 49 | S RIMDFN=BEGDFN ; BEGIN WITH THE BEGDFN PATIENT
|
|---|
| 50 | I RIMDFN="" S RIMDFN=RESUME
|
|---|
| 51 | I +RIMDFN=0 D Q ; AT THE END OF THE PATIENTS
|
|---|
| 52 | . W "END OF PATIENT LIST, CALL RESET^GPLRIMA",!
|
|---|
| 53 | F RIMI=1:1:DFNCNT D Q:+RIMDFN=0 ; FOR DFNCNT NUMBER OF PATIENTS OR END
|
|---|
| 54 | . D CCRRPC^GPLCCR(.CCRGLO,RIMDFN,"CCR","","","") ;PROCESS THE CCR
|
|---|
| 55 | . W RIMDFN,!
|
|---|
| 56 | . K @RIMBASE@("VARS",RIMDFN) ; CLEAR OUT OLD VARS
|
|---|
| 57 | . ;
|
|---|
| 58 | . ; COPY ALL THE VARIABLES TO THE RIM MAP AREA INDEXED BY PATIENT
|
|---|
| 59 | . ;
|
|---|
| 60 | . I $D(^TMP("GPLCCR",$J,"PROBVALS",1)) D ; PROBLEM VARS EXISTS
|
|---|
| 61 | . . M @RIMBASE@("VARS",RIMDFN,"PROBLEMS")=^TMP("GPLCCR",$J,"PROBVALS")
|
|---|
| 62 | . . S @RIMBASE@("VARS",RIMDFN,"PROBLEMS",0)=^TMP("GPLCCR",$J,"PROBVALS",0)
|
|---|
| 63 | . I $D(^TMP("GPLCCR",$J,"VITALS",1)) D ; VITALS VARS EXISTS
|
|---|
| 64 | . . M @RIMBASE@("VARS",RIMDFN,"VITALS")=^TMP("GPLCCR",$J,"VITALS")
|
|---|
| 65 | . I $D(^TMP("GPLCCR",$J,"MEDMAP",1)) D ; MEDS VARS EXISTS
|
|---|
| 66 | . . M @RIMBASE@("VARS",RIMDFN,"MEDS")=^TMP("GPLCCR",$J,"MEDMAP")
|
|---|
| 67 | . I $D(^TMP("GPLCCR",$J,"ALERTS",1,"ALERTOBJECTID")) D ; ALERTS EXIST
|
|---|
| 68 | . . W "FOUND ALERT VARS",!
|
|---|
| 69 | . . M @RIMBASE@("VARS",RIMDFN,"ALERTS")=^TMP("GPLCCR",$J,"ALERTS")
|
|---|
| 70 | . I $D(^TMP("GPLCCR",$J,"RESULTS",0)) D ; RESULTS EXIST
|
|---|
| 71 | . . W "FOUND RESULTS VARS",!
|
|---|
| 72 | . . M @RIMBASE@("VARS",RIMDFN,"RESULTS")=^TMP("GPLCCR",$J,"RESULTS")
|
|---|
| 73 | . K ^TMP("GPLCCR",$J) ; KILL WORK AREA FOR CCR BUILDING
|
|---|
| 74 | . ;
|
|---|
| 75 | . ; EVALUATE THE VARIABLES AND CREATE AN ATTRIBUTE MAP
|
|---|
| 76 | . ;
|
|---|
| 77 | . S RATTR=$$SETATTR(RIMDFN) ; SET THE ATTRIBUTE STRING BASED ON THE VARS
|
|---|
| 78 | . S @RIMBASE@("ATTR",RIMDFN)=RATTR ; SAVE THE ATRIBUTES FOR THIS PAT
|
|---|
| 79 | . ;
|
|---|
| 80 | . ; INCREMENT THE COUNT OF PATIENTS WITH THESE ATTRIBUTES IN ATTRTBL
|
|---|
| 81 | . ;
|
|---|
| 82 | . ; I '$D(@RIMBASE@("ATTRTBL",RATTR)) D ; IF FIRST PAT WITH THESE ATTRS
|
|---|
| 83 | . ; . S @RIMBASE@("ATTRTBL",RATTR)=0 ; DEFAULT VALUE TO BE INCREMENTED
|
|---|
| 84 | . ; S @RIMBASE@("ATTRTBL",RATTR)=@RIMBASE@("ATTRTBL",RATTR)+1 ; INCREMENT
|
|---|
| 85 | . ;
|
|---|
| 86 | . N CATNAME,CATTBL
|
|---|
| 87 | . ; S CATBASE=$NA(@RIMBASE@("ANALYSIS"))
|
|---|
| 88 | . S CATNAME=""
|
|---|
| 89 | . D CPUSH(.CATNAME,RIMBASE,"RIMTBL",RIMDFN,RATTR) ; ADD TO CATEGORY
|
|---|
| 90 | . W "CATEGORY NAME: ",CATNAME,!
|
|---|
| 91 | . ;
|
|---|
| 92 | . F S RIMDFN=$O(^DPT(RIMDFN)) Q:'$$PTST^CCRSYS(RIMDFN) ; NEXT PATIENT
|
|---|
| 93 | . ; PTST TESTS TO SEE IF PATIENT WAS MERGED
|
|---|
| 94 | . ; IF CCRTEST=0, PTST WILL CHECK TO SEE IF THIS IS A TEST PATIENT
|
|---|
| 95 | . ; AND WE SKIP IT
|
|---|
| 96 | . S @RIMBASE@("RESUME")=RIMDFN ; WHERE WE ARE LEAVING OFF THIS RUN
|
|---|
| 97 | ; D PARY^GPLXPATH(@RIMBASE@("ATTRTBL"))
|
|---|
| 98 | Q
|
|---|
| 99 | ;
|
|---|
| 100 | SETATTR(SDFN) ; SET ATTRIBUTES BASED ON VARS
|
|---|
| 101 | N SBASE,SATTR
|
|---|
| 102 | S SBASE=$NA(@RIMBASE@("VARS",SDFN))
|
|---|
| 103 | D APOST("SATTR","RIMTBL","HEADER")
|
|---|
| 104 | I $D(@SBASE@("PROBLEMS",1)) D ;
|
|---|
| 105 | . D APOST("SATTR","RIMTBL","PROBLEMS")
|
|---|
| 106 | . ; W "POSTING PROBLEMS",!
|
|---|
| 107 | I $D(@SBASE@("VITALS",1)) D APOST("SATTR","RIMTBL","VITALS")
|
|---|
| 108 | I $D(@SBASE@("MEDS",1)) D ; IF THE PATIENT HAS MEDS VARIABLES
|
|---|
| 109 | . D APOST("SATTR","RIMTBL","MEDS")
|
|---|
| 110 | . N ZR,ZI
|
|---|
| 111 | . D GETPA(.ZR,SDFN,"MEDS","MEDPRODUCTNAMECODEVALUE") ;CHECK FOR MED CODES
|
|---|
| 112 | . I ZR(0)>0 D ; VAR LOOKUP WAS GOOD, CHECK FOR NON=NULL RETURN
|
|---|
| 113 | . . F ZI=1:1:ZR(0) D ; LOOP THROUGH RETURNED VAR^VALUE PAIRS
|
|---|
| 114 | . . . I $P(ZR(ZI),"^",2)'="" D APOST("SATTR","RIMTBL","MEDSCODE") ;CODES
|
|---|
| 115 | . ; D PATD^GPLRIMA(2,"MEDS","MEDPRODUCTNAMECODEVALUE") CHECK FOR MED CODES
|
|---|
| 116 | I $D(@SBASE@("ALERTS",1)) D ; IF THE PATIENT HAS ALERTS
|
|---|
| 117 | . D APOST("SATTR","RIMTBL","ALERTS")
|
|---|
| 118 | . N ZR,ZI
|
|---|
| 119 | . D GETPA(.ZR,SDFN,"ALERTS","ALERTAGENTPRODUCTCODEVALUE") ;REACTANT CODES
|
|---|
| 120 | . I ZR(0)>0 D ; VAR LOOKUP WAS GOOD, CHECK FOR NON=NULL RETURN
|
|---|
| 121 | . . F ZI=1:1:ZR(0) D ; LOOP THROUGH RETURNED VAR^VALUE PAIRS
|
|---|
| 122 | . . . I $P(ZR(ZI),"^",2)'="" D APOST("SATTR","RIMTBL","ALERTSCODE") ;CODES
|
|---|
| 123 | I $D(@SBASE@("RESULTS",1)) D ; IF THE PATIENT HAS LABS VARIABLES
|
|---|
| 124 | . D APOST("SATTR","RIMTBL","RESULTS")
|
|---|
| 125 | . N ZR,ZI
|
|---|
| 126 | . S ZR(0)=0 ; INITIALIZE TO NONE
|
|---|
| 127 | . D RPCGV(.ZR,SDFN,"RESULTS") ;CHECK FOR LABS CODES
|
|---|
| 128 | . ; D PARY^GPLXPATH("ZR") ;
|
|---|
| 129 | . I ZR(0)>0 D ; VAR LOOKUP WAS GOOD, CHECK FOR NON=NULL RETURN
|
|---|
| 130 | . . F ZI=1:1:ZR(0) D ; LOOP THROUGH RETURNED VAR^VALUE PAIRS
|
|---|
| 131 | . . . I $P(ZR(ZI),"^",2)="RESULTTESTCODINGSYSTEM" D ; LOINC CODE CHECK
|
|---|
| 132 | . . . . I $P(ZR(ZI),"^",3)="LOINC" D APOST("SATTR","RIMTBL","RESULTSLN") ;
|
|---|
| 133 | ; D APOST("SATTR","RIMTBL","NOTEXTRACTED") ; OUTPUT NOT YET PRODUCED
|
|---|
| 134 | W "ATTRIBUTES: ",SATTR,!
|
|---|
| 135 | Q SATTR
|
|---|
| 136 | ;
|
|---|
| 137 | RESET ; KILL RESUME INDICATOR TO START OVER. ALSO KILL RIM TMP VALUES
|
|---|
| 138 | K ^TMP("GPLRIM","RESUME")
|
|---|
| 139 | K ^TMP("GPLRIM")
|
|---|
| 140 | Q
|
|---|
| 141 | ;
|
|---|
| 142 | CLIST ; LIST THE CATEGORIES
|
|---|
| 143 | ;
|
|---|
| 144 | I '$D(RIMBASE) D ASETUP ; FOR COMMAND LINE CALLS
|
|---|
| 145 | N CLBASE,CLNUM,ZI,CLIDX
|
|---|
| 146 | S CLBASE=$NA(@RIMBASE@("RIMTBL","CATS"))
|
|---|
| 147 | S CLNUM=@CLBASE@(0)
|
|---|
| 148 | F ZI=1:1:CLNUM D ; LOOP THROUGH THE CATEGORIES
|
|---|
| 149 | . S CLIDX=@CLBASE@(ZI)
|
|---|
| 150 | . W "(",$P(@CLBASE@(CLIDX),"^",1)
|
|---|
| 151 | . W ":",$P(@CLBASE@(CLIDX),"^",2),") "
|
|---|
| 152 | . W CLIDX,!
|
|---|
| 153 | ; D PARY^GPLXPATH(CLBASE)
|
|---|
| 154 | Q
|
|---|
| 155 | ;
|
|---|
| 156 | CPUSH(CATRTN,CBASE,CTBL,CDFN,CATTR) ; ADD PATIENTS TO CATEGORIES
|
|---|
| 157 | ; AND PASS BACK THE NAME OF THE CATEGORY TO WHICH THE PATIENT
|
|---|
| 158 | ; WAS ADDED IN CATRTN, WHICH IS PASSED BY REFERENCE
|
|---|
| 159 | ; CBASE IS WHERE TO PUT THE CATEGORIES PASSED BY NAME
|
|---|
| 160 | ; CTBL IS THE NAME OF THE TABLE USED TO CREATE THE ATTRIBUTES,
|
|---|
| 161 | ; PASSED BY NAME AND USED TO CREATE CATEGORY NAMES IE "@CTBL_X"
|
|---|
| 162 | ; WHERE X IS THE CATEGORY NUMBER. CTBL(0) IS THE NUMBER OF CATEGORIES
|
|---|
| 163 | ; CATBL(X)=CATTR STORES THE ATTRIBUTE IN THE CATEGORY
|
|---|
| 164 | ; CDFN IS THE PATIENT DFN, CATTR IS THE ATTRIBUTE STRING
|
|---|
| 165 | ; THE LIST OF PATIENTS IN A CATEGORY IS STORED INDEXED BY CATEGORY
|
|---|
| 166 | ; NUMBER IE CTBL_X(CDFN)=""
|
|---|
| 167 | ;
|
|---|
| 168 | ; N CCTBL,CENTRY,CNUM,CCOUNT,CPATLIST
|
|---|
| 169 | S CCTBL=$NA(@CBASE@(CTBL,"CATS"))
|
|---|
| 170 | W "CBASE: ",CCTBL,!
|
|---|
| 171 | ;
|
|---|
| 172 | I '$D(@CCTBL@(CATTR)) D ; FIRST PATIENT IN THIS CATEGORY
|
|---|
| 173 | . D PUSH^GPLXPATH(CCTBL,CATTR) ; ADD THE CATEGORY TO THE ARRAY
|
|---|
| 174 | . S CNUM=@CCTBL@(0) ; ARRAY ENTRY NUMBER FOR THIS CATEGORY
|
|---|
| 175 | . S CENTRY=CTBL_"_"_CNUM_U_0 ; TABLE ENTRY DEFAULT
|
|---|
| 176 | . S @CCTBL@(CATTR)=CENTRY ; DEFAULT NON INCREMENTED TABLE ENTRY
|
|---|
| 177 | . ; NOTE THAT P1 IS THE CATEGORY NAME MADE UP OF THE TABLE NAME
|
|---|
| 178 | . ; AND CATGORY ARRAY NUMBER. P2 IS THE COUNT WHICH IS INITIALLY 0
|
|---|
| 179 | ;
|
|---|
| 180 | S CCOUNT=$P(@CCTBL@(CATTR),U,2) ; COUNT OF PATIENTS IN THIS CATEGORY
|
|---|
| 181 | S CCOUNT=CCOUNT+1 ; INCREMENT THE COUNT
|
|---|
| 182 | S $P(@CCTBL@(CATTR),U,2)=CCOUNT ; PUT IT BACK
|
|---|
| 183 | ;
|
|---|
| 184 | S CATRTN=$P(@CCTBL@(CATTR),U,1) ; THE CATEGORY NAME WHICH IS RETURNED
|
|---|
| 185 | ;
|
|---|
| 186 | S CPATLIST=$NA(@CBASE@(CTBL,"PATS",CATRTN)) ; BASE OF PAT LIST FOR THIS CAT
|
|---|
| 187 | W "PATS BASE: ",CPATLIST,!
|
|---|
| 188 | S @CPATLIST@(CDFN)="" ; ADD THIS PATIENT TO THE CAT PAT LIST
|
|---|
| 189 | ;
|
|---|
| 190 | Q
|
|---|
| 191 | ;
|
|---|
| 192 | CCOUNT ; RECOUNT THE CATEGORIES.. USE IN CASE OF RESTART OF ANALYZE
|
|---|
| 193 | ;
|
|---|
| 194 | I '$D(RIMBASE) D ASETUP ; FOR COMMAND LINE CALLS
|
|---|
| 195 | N ZI,ZJ,ZCNT,ZIDX,ZCAT,ZATR,ZTOT
|
|---|
| 196 | S ZCBASE=$NA(@RIMBASE@("RIMTBL","CATS")) ; BASE OF CATEGORIES
|
|---|
| 197 | S ZPBASE=$NA(@RIMBASE@("RIMTBL","PATS")) ; BASE OF PATIENTS
|
|---|
| 198 | S ZTOT=0 ; INITIALIZE OVERALL TOTAL
|
|---|
| 199 | F ZI=1:1:@ZCBASE@(0) D ; FOR ALL CATS
|
|---|
| 200 | . S ZCNT=0
|
|---|
| 201 | . S ZATR=@ZCBASE@(ZI) ; THE ATTRIBUTE OF THE CATEGORY
|
|---|
| 202 | . S ZCAT=$P(@ZCBASE@(ZATR),"^",1) ; USE IT TO LOOK UP THE CATEGORY NAME
|
|---|
| 203 | . ; S ZIDX=$O(@ZPBASE@(ZCAT,"")) ; FIRST PATIENT IN LIST
|
|---|
| 204 | . ; F ZJ=0:0 D Q:$O(@ZPBASE@(ZCAT,ZIDX))="" ; ALL PATIENTS IN THE LISTS
|
|---|
| 205 | . ; . S ZCNT=ZCNT+1 ; INCREMENT THE COUNT
|
|---|
| 206 | . ; . W ZCAT," DFN:",ZIDX," COUNT:",ZCNT,!
|
|---|
| 207 | . ; . S ZIDX=$O(@ZPBASE@(ZCAT,ZIDX))
|
|---|
| 208 | . S ZCNT=$$CNTLST($NA(@ZPBASE@(ZCAT)))
|
|---|
| 209 | . S $P(@ZCBASE@(ZATR),"^",2)=ZCNT ; UPDATE THE COUNT IN THE CAT RECORD
|
|---|
| 210 | . S ZTOT=ZTOT+ZCNT
|
|---|
| 211 | W "TOTAL: ",ZTOT,!
|
|---|
| 212 | Q
|
|---|
| 213 | ;
|
|---|
| 214 | CNTLST(INLST) ; RETURNS THE NUMBER OF ELEMENTS IN THE LIST
|
|---|
| 215 | ; INLST IS PASSED BY NAME
|
|---|
| 216 | N ZI,ZDX,ZCOUNT
|
|---|
| 217 | W INLST,!
|
|---|
| 218 | S ZCOUNT=0
|
|---|
| 219 | S ZDX=""
|
|---|
| 220 | F ZI=$O(@INLST@(ZDX)):0 D Q:$O(@INLST@(ZDX))="" ; LOOP UNTIL THE END
|
|---|
| 221 | . S ZCOUNT=ZCOUNT+1
|
|---|
| 222 | . S ZDX=$O(@INLST@(ZDX))
|
|---|
| 223 | . W "ZDX:",ZDX," ZCNT:",ZCOUNT,!
|
|---|
| 224 | Q ZCOUNT
|
|---|
| 225 | ;
|
|---|
| 226 | XCPAT(CPATCAT) ; EXPORT TO FILE ALL PATIENTS IN CATEGORY CPATCAT
|
|---|
| 227 | ;
|
|---|
| 228 | I '$D(RIMBASE) D ASETUP ; FOR COMMAND LINE CALLS
|
|---|
| 229 | N ZI,ZJ,ZC,ZPATBASE
|
|---|
| 230 | S ZPATBASE=$NA(@RIMBASE@("RIMTBL","PATS",CPATCAT))
|
|---|
| 231 | S ZI=""
|
|---|
| 232 | F ZJ=0:0 D Q:$O(@ZPATBASE@(ZI))="" ; TIL END
|
|---|
| 233 | . S ZI=$O(@ZPATBASE@(ZI))
|
|---|
| 234 | . D XPAT^GPLCCR(ZI,"","") ; EXPORT THE PATIENT TO A FILE
|
|---|
| 235 | Q
|
|---|
| 236 | ;
|
|---|
| 237 | CPAT(CPATCAT) ; SHOW PATIENT DFNS FOR A CATEGORY CPATCAT
|
|---|
| 238 | ;
|
|---|
| 239 | I '$D(RIMBASE) D ASETUP ; FOR COMMAND LINE CALLS
|
|---|
| 240 | N ZI,ZJ,ZC,ZPATBASE
|
|---|
| 241 | S ZC=0 ; COUNT FOR SPACING THE PRINTOUT
|
|---|
| 242 | S ZPATBASE=$NA(@RIMBASE@("RIMTBL","PATS",CPATCAT))
|
|---|
| 243 | S ZI=""
|
|---|
| 244 | F ZJ=0:0 D Q:$O(@ZPATBASE@(ZI))="" ; TIL END
|
|---|
| 245 | . S ZI=$O(@ZPATBASE@(ZI))
|
|---|
| 246 | . S ZC=ZC+1 ; INCREMENT OUTPUT PER LINE COUNT
|
|---|
| 247 | . W ZI," "
|
|---|
| 248 | . I ZC=10 D ; NEW LINE
|
|---|
| 249 | . . S ZC=0
|
|---|
| 250 | . . W !
|
|---|
| 251 | Q
|
|---|
| 252 | ;
|
|---|
| 253 | PATC(DFN) ; DISPLAY THE CATEGORY FOR THIS PATIENT
|
|---|
| 254 | ;
|
|---|
| 255 | N ATTR S ATTR=""
|
|---|
| 256 | I '$D(^TMP("GPLRIM","ATTR",DFN)) D ; RIM VARS NOT PRESENT
|
|---|
| 257 | . D ANALYZE(DFN,1) ; EXTRACT THE RIM VARIABLE FOR THIS PATIENT
|
|---|
| 258 | S ATTR=^TMP("GPLRIM","ATTR",DFN)
|
|---|
| 259 | I ATTR="" W "THIS PATIENT NOT ANALYZED.",! Q ;NO ATTRIBUTES FOUND
|
|---|
| 260 | I $D(^TMP("GPLRIM","RIMTBL","CATS",ATTR)) D ; FOUND A CAT
|
|---|
| 261 | . N CAT
|
|---|
| 262 | . S CAT=$P(^TMP("GPLRIM","RIMTBL","CATS",ATTR),U,1) ; LOOK UP THE CAT
|
|---|
| 263 | . W CAT,": ",ATTR,!
|
|---|
| 264 | Q
|
|---|
| 265 | ;
|
|---|
| 266 | APUSH(AMAP,AVAL) ; ADD AVAL TO ATTRIBUTE MAP AMAP (AMAP PASSED BY NAME)
|
|---|
| 267 | ; AMAP IS FORMED FOR ARRAY ACCESS: AMAP(0) IS THE COUNT
|
|---|
| 268 | ; AND AMAP(N)=AVAL IS THE NTH AVAL
|
|---|
| 269 | ; ALSO HASH ACCESS AMAP(AVAL)=N WHERE N IS THE ASSIGNED ORDER OF THE
|
|---|
| 270 | ; MAP VALUE. INSTANCES OF THE MAP WILL USE $P(X,U,N)=AVAL TO PLACE
|
|---|
| 271 | ; THE ATTRIBUTE IN ITS RIGHT PLACE. THE ATTRIBUTE VALUE IS STORED
|
|---|
| 272 | ; SO THAT DIFFERENT MAPS CAN BE AUTOMATICALLY CROSSWALKED
|
|---|
| 273 | ;
|
|---|
| 274 | I '$D(@AMAP) D ; IF THE MAP DOES NOT EXIST
|
|---|
| 275 | . S @AMAP@(0)=0 ; HAS ZERO ELEMENTS
|
|---|
| 276 | S @AMAP@(0)=@AMAP@(0)+1 ;INCREMENT ELEMENT COUNT
|
|---|
| 277 | S @AMAP@(@AMAP@(0))=AVAL ; ADD THE VALUE TO THE ARRAY
|
|---|
| 278 | S @AMAP@(AVAL)=@AMAP@(0) ; ADD THE VALUE TO THE HASH WITH ARRAY REF
|
|---|
| 279 | Q
|
|---|
| 280 | ;
|
|---|
| 281 | ASETUP ; SET UP GLOBALS AND VARS RIMBASE AND RIMTBL
|
|---|
| 282 | I '$D(RIMBASE) S RIMBASE=$NA(^TMP("GPLRIM"))
|
|---|
| 283 | I '$D(@RIMBASE) S @RIMBASE=""
|
|---|
| 284 | I '$D(RIMTBL) S RIMTBL=$NA(^TMP("GPLRIM","RIMTBL","TABLE")) ; ATTR TABLE
|
|---|
| 285 | S ^TMP("GPLRIM","TABLES","RIMTBL")=RIMTBL ; TABLE OF TABLES
|
|---|
| 286 | Q
|
|---|
| 287 | ;
|
|---|
| 288 | AINIT ; INITIALIZE ATTRIBUTE TABLE
|
|---|
| 289 | I '$D(RIMBASE) D ASETUP ; FOR COMMAND LINE CALLS
|
|---|
| 290 | K @RIMTBL
|
|---|
| 291 | D APUSH(RIMTBL,"EXTRACTED")
|
|---|
| 292 | D APUSH(RIMTBL,"NOTEXTRACTED")
|
|---|
| 293 | D APUSH(RIMTBL,"HEADER")
|
|---|
| 294 | D APUSH(RIMTBL,"NOPCP")
|
|---|
| 295 | D APUSH(RIMTBL,"PCP")
|
|---|
| 296 | D APUSH(RIMTBL,"PROBLEMS")
|
|---|
| 297 | D APUSH(RIMTBL,"PROBCODE")
|
|---|
| 298 | D APUSH(RIMTBL,"PROBNOCODE")
|
|---|
| 299 | D APUSH(RIMTBL,"PROBDATE")
|
|---|
| 300 | D APUSH(RIMTBL,"PROBNODATE")
|
|---|
| 301 | D APUSH(RIMTBL,"VITALS")
|
|---|
| 302 | D APUSH(RIMTBL,"VITALSCODE")
|
|---|
| 303 | D APUSH(RIMTBL,"VITALSNOCODE")
|
|---|
| 304 | D APUSH(RIMTBL,"VITALSDATE")
|
|---|
| 305 | D APUSH(RIMTBL,"VITALSNODATE")
|
|---|
| 306 | D APUSH(RIMTBL,"MEDS")
|
|---|
| 307 | D APUSH(RIMTBL,"MEDSCODE")
|
|---|
| 308 | D APUSH(RIMTBL,"MEDSNOCODE")
|
|---|
| 309 | D APUSH(RIMTBL,"MEDSDATE")
|
|---|
| 310 | D APUSH(RIMTBL,"MEDSNODATE")
|
|---|
| 311 | D APUSH(RIMTBL,"ALERTS")
|
|---|
| 312 | D APUSH(RIMTBL,"ALERTSCODE")
|
|---|
| 313 | D APUSH(RIMTBL,"RESULTS")
|
|---|
| 314 | D APUSH(RIMTBL,"RESULTSLN")
|
|---|
| 315 | Q
|
|---|
| 316 | ;
|
|---|
| 317 | APOST(PRSLT,PTBL,PVAL) ; POST AN ATTRIBUTE PVAL TO PRSLT USING PTBL
|
|---|
| 318 | ; PSRLT AND PTBL ARE PASSED BY NAME. PVAL IS A STRING
|
|---|
| 319 | ; PTBL IS THE NAME OF A TABLE IN @RIMBASE@("TABLES") - "RIMTBL"=ALL VALUES
|
|---|
| 320 | ; PVAL WILL BE PLACED IN THE STRING PRSLT AT $P(X,U,@PTBL@(PVAL))
|
|---|
| 321 | I '$D(RIMBASE) D ASETUP ; FOR COMMANDLINE PROCESSING
|
|---|
| 322 | N USETBL
|
|---|
| 323 | I '$D(@RIMBASE@("TABLES",PTBL)) D Q ; NO TABLE
|
|---|
| 324 | . W "ERROR NO SUCH TABLE",!
|
|---|
| 325 | S USETBL=@RIMBASE@("TABLES",PTBL)
|
|---|
| 326 | S $P(@PRSLT,U,@USETBL@(PVAL))=PVAL
|
|---|
| 327 | Q
|
|---|
| 328 | GETPA(RTN,DFN,ISEC,IVAR) ; RETURNS ARRAY OF RIM VARIABLES FOR PATIENT DFN
|
|---|
| 329 | ; EXAMPLE: D GETPA(.RT,2,"MEDS","MEDSSTATUSTEXT")
|
|---|
| 330 | ; RETURNS AN ARRAY RT OF VALUES OF MEDSTATUSTEXT FOR PATIENT 2 IN P2
|
|---|
| 331 | ; IN SECTION "MEDS"
|
|---|
| 332 | ; P1 IS THE IEN OF THE MED WITH THE VALUE IE 2^PENDING WOULD BE STATUS
|
|---|
| 333 | ; PENDING FOR MED 2 FOR PATIENT 2
|
|---|
| 334 | ; RT(0) IS THE COUNT OF HOW MANY IN THE ARRAY. NULL VALUES ARE
|
|---|
| 335 | ; RETURNED. RTN IS PASSED BY REFERENCE
|
|---|
| 336 | ;
|
|---|
| 337 | S RTN(0)=0 ; SET NULL DEFAULT RETURN VALUE
|
|---|
| 338 | I '$D(RIMBASE) D AINIT ; INITIALIZE GLOBAL NAMES AND TABLES
|
|---|
| 339 | S ZVBASE=$NA(@RIMBASE@("VARS")) ; BASE OF VARIABLES
|
|---|
| 340 | I '$D(@ZVBASE@(DFN,ISEC,0)) D Q ; NO VARIABLES IN SECTION
|
|---|
| 341 | . W "NO VARIABLES IN THIS SECTION FOR PATIENT ",DFN,!
|
|---|
| 342 | N ZZI,ZZS
|
|---|
| 343 | S ZZS=$NA(@ZVBASE@(DFN,ISEC)) ; SECTION VARIABLE ARRAY FOR THIS PATIENT
|
|---|
| 344 | ; ZWR @ZZS@(1)
|
|---|
| 345 | S RTN(0)=@ZZS@(0)
|
|---|
| 346 | F ZZI=1:1:RTN(0) D ; FOR ALL PARTS OF THIS SECTION ( IE FOR ALL MEDS)
|
|---|
| 347 | . S $P(RTN(ZZI),"^",1)=ZZI ; INDEX FOR VARIABLE
|
|---|
| 348 | . S $P(RTN(ZZI),"^",2)=@ZZS@(ZZI,IVAR) ; THE VALUE OF THE VARIABLE
|
|---|
| 349 | Q
|
|---|
| 350 | ;
|
|---|
| 351 | PATD(DFN,ISEC,IVAR) ; DISPLAY FOR PATIENT DFN THE VARIABLE IVAR
|
|---|
| 352 | ;
|
|---|
| 353 | N ZR
|
|---|
| 354 | D GETPA(.ZR,DFN,ISEC,IVAR)
|
|---|
| 355 | I $D(ZR(0)) D PARY^GPLXPATH("ZR")
|
|---|
| 356 | E W "NOTHING RETURNED",!
|
|---|
| 357 | Q
|
|---|
| 358 | ;
|
|---|
| 359 | CAGET(RTN,IATTR) ;
|
|---|
| 360 | ; GETPA LOOKS AT RIMTBL TO FIND PATIENTS WITH ATTRIBUTE IATTR
|
|---|
| 361 | ; IT DOES NOT SEARCH ALL PATIENTS, ONLY THE ONES WITH THE ATTRIBUTE
|
|---|
| 362 | ; IT RETURNS AN ARRAY OF THE VALUES OF VARIABLE IVAR IN SECTION ISEC
|
|---|
| 363 | Q
|
|---|
| 364 | ;
|
|---|
| 365 | PCLST(LSTRTN,IATTR) ; RETURNS ARRAY OF PATIENTS WITH ATTRIBUTE IATTR
|
|---|
| 366 | ;
|
|---|
| 367 | I '$D(RIMBASE) D AINIT ; INITIALIZE GLOBAL NAMES AND TABLES
|
|---|
| 368 | N ZLST
|
|---|
| 369 | S LSTRTN(0)=0 ; DEFAULT RETURN NONE
|
|---|
| 370 | S ZCBASE=$NA(@RIMBASE@("RIMTBL","CATS")) ; BASE OF CATEGORIES
|
|---|
| 371 | S ZPBASE=$NA(@RIMBASE@("RIMTBL","PATS")) ; BASE OF PATIENTS
|
|---|
| 372 | N ZNC ; ZNC IS NUMBER OF CATEGORIES
|
|---|
| 373 | S ZNC=@ZCBASE@(0)
|
|---|
| 374 | I ZNC=0 Q ; NO CATEGORIES TO SEARCH
|
|---|
| 375 | N ZAP ; ZAP IS THE PIECE INDEX OF THE ATTRIBUTE IN THE RIM ATTR TABLE
|
|---|
| 376 | S ZAP=@RIMBASE@("RIMTBL","TABLE",IATTR)
|
|---|
| 377 | N ZI,ZCATTBL,ZATBL,ZCNT,ZPAT
|
|---|
| 378 | F ZI=1:1:ZNC D ; FOR ALL CATEGORIES
|
|---|
| 379 | . S ZATBL=@ZCBASE@(ZI) ; PULL OUT ATTR TBL FOR CAT
|
|---|
| 380 | . I $P(ZATBL,"^",ZAP)'="" D ; CAT HAS ATTR
|
|---|
| 381 | . . S ZCATTBL=$P(@ZCBASE@(ZATBL),"^",1) ; NAME OF TBL
|
|---|
| 382 | . . M LSTRTN=@ZPBASE@(ZCATTBL) ; MERGE PATS FROM CAT
|
|---|
| 383 | S ZCNT=0 ; INITIALIZE COUNT OF PATIENTS
|
|---|
| 384 | S ZPAT=0 ; START AT FIRST PATIENT IN LIST
|
|---|
| 385 | F S ZPAT=$O(LSTRTN(ZPAT)) Q:ZPAT="" D ;
|
|---|
| 386 | . S ZCNT=ZCNT+1
|
|---|
| 387 | S LSTRTN(0)=ZCNT ; COUNT OF PATIENTS IN ARRAY
|
|---|
| 388 | Q
|
|---|
| 389 | ;
|
|---|
| 390 | DCPAT(CATTR) ; DISPLAY LIST OF PATIENTS WITH ATTRIBUTE CATTR
|
|---|
| 391 | ;
|
|---|
| 392 | N ZR
|
|---|
| 393 | D PCLST(.ZR,CATTR)
|
|---|
| 394 | I ZR(0)=0 D Q ;
|
|---|
| 395 | . W "NO PATIENTS RETURNED",!
|
|---|
| 396 | E D ;
|
|---|
| 397 | . D PARY^GPLXPATH("ZR") ; PRINT ARRAY
|
|---|
| 398 | . W "COUNT=",ZR(0),!
|
|---|
| 399 | Q
|
|---|
| 400 | ;
|
|---|
| 401 | RPCGV(RTN,DFN,WHICH) ; RPC GET VARS
|
|---|
| 402 | ; RETURNS IN RTN (PASSED BY REFERENCE) THE VARS AND VALUES
|
|---|
| 403 | ; FOUND AT INARY RTN(X)="VAR^VALUE" RTN(0) IS THE COUNT
|
|---|
| 404 | ; DFN IS THE PATIENT NUMBER.
|
|---|
| 405 | ; WHICH IS "ALL","MEDS","VITALS","PROBLEMS","ALERTS","RESULTS"
|
|---|
| 406 | ; OR OTHER SECTIONS AS THEY ARE ADDED
|
|---|
| 407 | ; THIS IS MEANT TO BE AVAILABLE AS AN RPC
|
|---|
| 408 | I '$D(RIMBASE) D ASETUP ; FOR COMMAND LINE CALLS
|
|---|
| 409 | S ZVBASE=$NA(@RIMBASE@("VARS")) ; BASE OF VARIABLES
|
|---|
| 410 | S RTN(0)=0 ; DEFAULT NOTHING IS RETURNED
|
|---|
| 411 | N ZZGI
|
|---|
| 412 | I WHICH="ALL" D ; VARIABLES FROM ALL SECTIONS
|
|---|
| 413 | . F ZZGI="PROBLEMS","VITALS","MEDS","ALERTS","RESULTS" D ; EACH SECTION
|
|---|
| 414 | . . D ZGVWRK(ZZGI) ; DO EACH SECTION
|
|---|
| 415 | E D ZGVWRK(WHICH) ; ONLY ONE SECTION ASKED FOR
|
|---|
| 416 | Q
|
|---|
| 417 | ;
|
|---|
| 418 | ZGVWRK(ZWHICH) ; DO ONE SECTION FOR RPCGV
|
|---|
| 419 | ;
|
|---|
| 420 | N ZZGN ; NAME FOR SECTION VARIABLES
|
|---|
| 421 | S ZZGN=$NA(@ZVBASE@(DFN,ZWHICH)) ; BASE OF VARS FOR SECTION
|
|---|
| 422 | I '$D(@ZZGN@(0)) Q ; NO VARS FOR THIS SECTION
|
|---|
| 423 | E D ; VARS EXIST
|
|---|
| 424 | . N ZGVI
|
|---|
| 425 | . F ZGVI=1:1:@ZZGN@(0) D ; FOR EACH MULTIPLE IN SECTION
|
|---|
| 426 | . . K ZZGA N ZZGA ; TEMP ARRAY FOR SECTION VARS
|
|---|
| 427 | . . K ZZGN2 N ZZGN2 ; NAME FOR MULTIPLE
|
|---|
| 428 | . . S ZZGN2=$NA(@ZZGN@(ZGVI))
|
|---|
| 429 | . . ; W ZZGN2,!,$O(@ZZGN2@("")),!
|
|---|
| 430 | . . D H2ARY^GPLXPATH("ZZGA",ZZGN2,ZGVI) ; CONVERT HASH TO ARRAY
|
|---|
| 431 | . . ; D PARY^GPLXPATH("ZZGA")
|
|---|
| 432 | . . D PUSHA^GPLXPATH("RTN","ZZGA") ; PUSH ARRAY INTO RETURN
|
|---|
| 433 | Q
|
|---|
| 434 | ;
|
|---|
| 435 | DPATV(DFN,IWHICH) ; DISPLAY VARS FOR PATIENT DFN THAT ARE MAINTAINED IN GPLRIM
|
|---|
| 436 | ; ALONG WITH SAMPLE VALUES.
|
|---|
| 437 | ; IWHICH IS "ALL","MEDS","VITALS","PROBLEMS","ALERTS","RESULTS"
|
|---|
| 438 | N GTMP
|
|---|
| 439 | I '$D(^TMP("GPLRIM","ATTR",DFN)) D ; RIM VARS NOT PRESENT
|
|---|
| 440 | . D ANALYZE(DFN,1) ; REFRESH THE RIM VARIABLES
|
|---|
| 441 | I '$D(IWHICH) S IWHICH="ALL"
|
|---|
| 442 | D RPCGV(.GTMP,DFN,IWHICH)
|
|---|
| 443 | D PARY^GPLXPATH("GTMP")
|
|---|
| 444 | Q
|
|---|
| 445 | ;
|
|---|
