source: ccr/trunk/p/GPLRIMA.m@ 97

Last change on this file since 97 was 97, checked in by George Lilly, 16 years ago

killed value arrays at beginning of processing for Vitals and Problems
File size: 6.6 KB
Line 
1GPLRIMA ; CCDCCR/GPL - RIM REPORT ROUTINES; 6/6/08
2 ;;0.1;CCDCCR;nopatch;noreleasedate
3 ;Copyright 2008 WorldVistA. Licensed under the terms of the GNU
4 ;General Public License See attached copy of the License.
5 ;
6 ;This program is free software; you can redistribute it and/or modify
7 ;it under the terms of the GNU General Public License as published by
8 ;the Free Software Foundation; either version 2 of the License, or
9 ;(at your option) any later version.
10 ;
11 ;This program is distributed in the hope that it will be useful,
12 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 ;GNU General Public License for more details.
15 ;
16 ;You should have received a copy of the GNU General Public License along
17 ;with this program; if not, write to the Free Software Foundation, Inc.,
18 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
19 ;
20 ; THESE ROUTINES EXAMINE ONE OR MORE, UP TO ALL, OF THE PATIENTS ON THE
21 ; SYSTEM TO DETERMINE HOW COMPLETE THE RESULTING CCR OR CCD WOULD BE FOR
22 ; THESE PATIENTS. IT BEGINS TO MEASURE "HL7 RIM COHERENCE" WHICH IS HOW USEFUL
23 ; THE VARIABLES WILL BE TO A RIM-MODELED APPLICATION AFTER THEY ARE
24 ; CONVEYED VIA THE CCR OR CCD.
25 ; FACTORS THAT AFFECT RIM COHERENCE INCLUDE:
26 ; 1. THE PRESENSE OF CLINICAL DATA IN A SECTION
27 ; 2. ARE THE DATA ELEMENTS TIME-BOUND
28 ; 3. ARE THE DATA ELEMENTS CODED WITH SNOMED OR LOINC ETC
29 ; 4. ARE SOURCE ACTORS ASSOCIATED WITH THE DATA ELEMENTS
30 ; 5. ARE ACTORS IDENTIFIED REGARDING THEIR ROLE
31 ; .. AND OTHER FACTORS YET TO BE DETERMINED
32 ;
33 ; SINCE THESE MEASUREMENTS ARE DONE AT THE VARIABLE LEVEL, THEY
34 ; REFLECT ON RIM COHERENCE WHETHER THE CCR OR THE CCD IS USED FOR
35 ; CONVEYANCE TO THE RIM APPLICATION.
36 ;
37 ;
38ANALYZE(BEGDFN,DFNCNT) ; RIM COHERANCE ANALYSIS ROUTINE
39 ; BEGINS AT BEGDFN AND GOES FOR DFNCNT PATIENTS
40 ; TO RESUME AT NEXT PATIENT, USE BEGDFN=""
41 ; USE RESET^GPLRIMA TO RESET TO TOP OF PATIENT LIST
42 ;
43 N RIMARY,RIMTMP,RIMI,RIMDFN,RATTR
44 N CCRGLO
45 D ASETUP ; SET UP VARIABLES AND GLOBALS
46 D AINIT ; INITIALIZE ATTRIBUTE VALUE TABLE
47 I '$D(@RIMBASE@("RESUME")) S @RIMBASE@("RESUME")=$O(^DPT(0)) ; FIRST TIME
48 S RESUME=@RIMBASE@("RESUME") ; WHERE WE LEFT OFF LAST RUN
49 S RIMDFN=BEGDFN ; BEGIN WITH THE BEGDFN PATIENT
50 I RIMDFN="" S RIMDFN=RESUME
51 I +RIMDFN=0 D Q ; AT THE END OF THE PATIENTS
52 . W "END OF PATIENT LIST, CALL RESET^GPLRIMA",!
53 F RIMI=1:1:DFNCNT D Q:+RIMDFN=0 ; FOR DFNCNT NUMBER OF PATIENTS OR END
54 . D CCRRPC^GPLCCR(.CCRGLO,RIMDFN,"CCR","","","") ;PROCESS THE CCR
55 . W RIMDFN,!
56 . K @RIMBASE@("VARS",RIMDFN) ; CLEAR OUT OLD VARS
57 . ;
58 . ; COPY ALL THE VARIABLES TO THE RIM MAP AREA INDEXED BY PATIENT
59 . ;
60 . I $D(^TMP("GPLCCR",$J,"PROBVALS",1)) D ; PROBLEM VARS EXISTS
61 . . M @RIMBASE@("VARS",RIMDFN,"PROBLEMS")=^TMP("GPLCCR",$J,"PROBVALS")
62 . I $D(^TMP("GPLCCR",$J,"VITALS",1)) D ; VITALS VARS EXISTS
63 . . M @RIMBASE@("VARS",RIMDFN,"VITALS")=^TMP("GPLCCR",$J,"VITALS")
64 . I $D(^TMP("GPLCCR",$J,"MEDICATIONS",1)) D ; MEDS VARS EXISTS
65 . . M @RIMBASE@("VARS",RIMDFN,"MEDS")=^TMP("GPLCCR",$J,"MEDICATIONS")
66 . ;
67 . ; EVALUATE THE VARIABLES AND CREATE AN ATTRIBUTE MAP
68 . ;
69 . S RATTR=$$SETATTR(RIMDFN) ; SET THE ATTRIBUTE STRING BASED ON THE VARS
70 . S @RIMBASE@("ATTR",RIMDFN)=RATTR ; SAVE THE ATRIBUTES FOR THIS PAT
71 . ;
72 . ; INCREMENT THE COUNT OF PATIENTS WITH THESE ATTRIBUTES IN ATTRTBL
73 . ;
74 . I '$D(@RIMBASE@("ATTRTBL",RATTR)) D ; IF FIRST PAT WITH THESE ATTRS
75 . . S @RIMBASE@("ATTRTBL",RATTR)=0 ; DEFAULT VALUE TO BE INCREMENTED
76 . S @RIMBASE@("ATTRTBL",RATTR)=@RIMBASE@("ATTRTBL",RATTR)+1 ; INCREMENT
77 . ;
78 . S RIMDFN=$O(^DPT(RIMDFN)) ; NEXT PATIENT
79 S @RIMBASE@("RESUME")=RIMDFN ; WHERE WE ARE LEAVING OFF THIS RUN
80 ; D PARY^GPLXPATH(@RIMBASE@("ATTRTBL"))
81 Q
82 ;
83SETATTR(SDFN) ; SET ATTRIBUTES BASED ON VARS
84 N SBASE,SATTR
85 S SBASE=$NA(@RIMBASE@("VARS",SDFN))
86 D APOST("SATTR","RIMTBL","HEADER")
87 I $D(@SBASE@("PROBLEMS",1)) D ;
88 . D APOST("SATTR","RIMTBL","PROBLEMS")
89 . W "POSTING PROBLEMS",!
90 I $D(@SBASE@("VITALS",1)) D APOST("SATTR","RIMTBL","VITALS")
91 I $D(@SBASE@("MEDS",1)) D APOST("SATTR","RIMTBL","MEDS")
92 W "ATTRIBUTES: ",SATTR,!
93 Q SATTR
94 ;
95RESET ; KILL RESUME INDICATOR TO START OVER. ALSO KILL RIM TMP VALUES
96 K ^TMP("GPLRIM","RESUME")
97 K ^TMP("GPLRIM")
98 Q
99 ;
100APUSH(AMAP,AVAL) ; ADD AVAL TO ATTRIBUTE MAP AMAP (AMAP PASSED BY NAME)
101 ; AMAP IS FORMED FOR ARRAY ACCESS: AMAP(0) IS THE COUNT
102 ; AND AMAP(N)=AVAL IS THE NTH AVAL
103 ; ALSO HASH ACCESS AMAP(AVAL)=N WHERE N IS THE ASSIGNED ORDER OF THE
104 ; MAP VALUE. INSTANCES OF THE MAP WILL USE $P(X,U,N)=AVAL TO PLACE
105 ; THE ATTRIBUTE IN ITS RIGHT PLACE. THE ATTRIBUTE VALUE IS STORED
106 ; SO THAT DIFFERENT MAPS CAN BE AUTOMATICALLY CROSSWALKED
107 ;
108 I '$D(@AMAP) D ; IF THE MAP DOES NOT EXIST
109 . S @AMAP@(0)=0 ; HAS ZERO ELEMENTS
110 S @AMAP@(0)=@AMAP@(0)+1 ;INCREMENT ELEMENT COUNT
111 S @AMAP@(@AMAP@(0))=AVAL ; ADD THE VALUE TO THE ARRAY
112 S @AMAP@(AVAL)=@AMAP@(0) ; ADD THE VALUE TO THE HASH WITH ARRAY REF
113 Q
114 ;
115ASETUP ; SET UP GLOBALS AND VARS RIMBASE AND RIMTBL
116 I '$D(RIMBASE) S RIMBASE=$NA(^TMP("GPLRIM"))
117 I '$D(@RIMBASE) S @RIMBASE=""
118 I '$D(RIMTBL) S RIMTBL=$NA(^TMP("GPLRIM","RIMTBL")) ;BASE FOR ATTR TABLE
119 S ^TMP("GPLRIM","TABLES","RIMTBL")=RIMTBL ; FOR COMMAND LINE PROCESSING
120 Q
121 ;
122AINIT ; INITIALIZE ATTRIBUTE TABLE
123 I '$D(RIMBASE) D ASETUP ; FOR COMMAND LINE CALLS
124 K @RIMTBL
125 D APUSH(RIMTBL,"HEADER")
126 D APUSH(RIMTBL,"NOPCP")
127 D APUSH(RIMTBL,"PCP")
128 D APUSH(RIMTBL,"PROBLEMS")
129 D APUSH(RIMTBL,"PROBCODE")
130 D APUSH(RIMTBL,"PROBNOCODE")
131 D APUSH(RIMTBL,"PROBDATE")
132 D APUSH(RIMTBL,"PROBNODATE")
133 D APUSH(RIMTBL,"VITALS")
134 D APUSH(RIMTBL,"VITALSCODE")
135 D APUSH(RIMTBL,"VITALSNOCODE")
136 D APUSH(RIMTBL,"VITALSDATE")
137 D APUSH(RIMTBL,"VITALSNODATE")
138 D APUSH(RIMTBL,"MEDS")
139 D APUSH(RIMTBL,"MEDSCODE")
140 D APUSH(RIMTBL,"MEDSNOCODE")
141 D APUSH(RIMTBL,"MEDSDATE")
142 D APUSH(RIMTBL,"MEDSNODATE")
143 Q
144 ;
145APOST(PRSLT,PTBL,PVAL) ; POST AN ATTRIBUTE PVAL TO PRSLT USING PTBL
146 ; PSRLT AND PTBL ARE PASSED BY NAME. PVAL IS A STRING
147 ; PTBL IS THE NAME OF A TABLE IN @RIMBASE@("TABLES") - "RIMTBL"=ALL VALUES
148 ; PVAL WILL BE PLACED IN THE STRING PRSLT AT $P(X,U,@PTBL@(PVAL))
149 I '$D(RIMBASE) D ASETUP ; FOR COMMANDLINE PROCESSING
150 N USETBL
151 I '$D(@RIMBASE@("TABLES",PTBL)) D Q ; NO TABLE
152 . W "ERROR NO SUCH TABLE",!
153 S USETBL=@RIMBASE@("TABLES",PTBL)
154 S $P(@PRSLT,U,@USETBL@(PVAL))=PVAL
155 Q
Note: See TracBrowser for help on using the repository browser.