source: ccr/trunk/p/GPLXPATH.m@ 50

Last change on this file since 50 was 50, checked in by George Lilly, 16 years ago

Added "GPLCCR" to TMP globals for SAC compliance
File size: 21.0 KB
Line 
1GPLXPATH ; CCDCCR/GPL - XPATH XML manipulation utilities; 6/1/08
2 ;;0.2;CCDCCR;nopatch;noreleasedate
3 W "This is an XML XPATH utility library",!
4 W !
5 Q
6 ;
7OUTPUT(OUTARY,OUTNAME,OUTDIR) ; WRITE AN ARRAY TO A FILE
8 ;
9 N Y
10 S Y=$$GTF^%ZISH(OUTARY,$QL(OUTARY),OUTDIR,OUTNAME)
11 I Y W "WROTE FILE: ",OUTNAME," TO ",OUTDIR,!
12 ; $NA(^TMP(14216,"FILE",0)),3,"/home/wvehr3","test.xml")
13 Q
14 ;
15PUSH(STK,VAL) ; pushs VAL onto STK and updates STK(0)
16 ; VAL IS A STRING AND STK IS PASSED BY NAME
17 ;
18 I '$D(@STK@(0)) S @STK@(0)=0 ; IF THE ARRAY IS EMPTY, INITIALIZE
19 S @STK@(0)=@STK@(0)+1 ; INCREMENT ARRAY DEPTH
20 S @STK@(@STK@(0))=VAL ; PUT VAL A THE END OF THE ARRAY
21 Q
22 ;
23POP(STK,VAL) ; POPS THE LAST VALUE OFF THE STK AND RETURNS IT IN VAL
24 ; VAL AND STK ARE PASSED BY REFERENCE
25 ;
26 I @STK@(0)<1 D ; IF ARRAY IS EMPTY
27 . S VAL=""
28 . S @STK@(0)=0
29 I @STK@(0)>0 D ;
30 . S VAL=@STK@(@STK@(0))
31 . K @STK@(@STK@(0))
32 . S @STK@(0)=@STK@(0)-1 ; NEW DEPTH OF THE ARRAY
33 Q
34 ;
35MKMDX(STK,RTN) ; MAKES A MUMPS INDEX FROM THE ARRAY STK
36 ; RTN IS SET TO //FIRST/SECOND/THIRD" FOR THREE ARRAY ELEMENTS
37 S RTN=""
38 N I
39 ; W "STK= ",STK,!
40 I @STK@(0)>0 D ; IF THE ARRAY IS NOT EMPTY
41 . S RTN="//"_@STK@(1) ; FIRST ELEMENT NEEDS NO SEMICOLON
42 . I @STK@(0)>1 D ; SUBSEQUENT ELEMENTS NEED A SEMICOLON
43 . . F I=2:1:@STK@(0) S RTN=RTN_"/"_@STK@(I)
44 Q
45 ;
46XNAME(ISTR) ; FUNCTION TO EXTRACT A NAME FROM AN XML FRAG
47 ; </NAME> AND <NAME ID=XNAME> WILL RETURN NAME
48 ; ISTR IS PASSED BY VALUE
49 N CUR,TMP
50 I ISTR?.E1"<".E D ; STRIP OFF LEFT BRACKET
51 . S TMP=$P(ISTR,"<",2)
52 I TMP?1"/".E D ; ALSO STRIP OFF SLASH IF PRESENT IE </NAME>
53 . S TMP=$P(TMP,"/",2)
54 S CUR=$P(TMP,">",1) ; EXTRACT THE NAME
55 ; W "CUR= ",CUR,!
56 I CUR?.1"_"1.A1" ".E D ; CONTAINS A BLANK IE NAME ID=TEST>
57 . S CUR=$P(CUR," ",1) ; STRIP OUT BLANK AND AFTER
58 ; W "CUR2= ",CUR,!
59 Q CUR
60 ;
61INDEX(ZXML) ; parse the XML in ZXML and produce an XPATH index
62 ; ex. ZXML(FIRST,SECOND,THIRD,FOURTH)=FIRSTLINE^LASTLINE
63 ; WHERE FIRSTLINE AND LASTLINE ARE THE BEGINNING AND ENDING OF THE
64 ; XML SECTION
65 ; ZXML IS PASSED BY NAME
66 N I,LINE,FIRST,LAST,CUR,TMP,MDX,FOUND
67 N GPLSTK ; LEAVE OUT FOR DEBUGGING
68 I '$D(@ZXML@(0)) D ; NO XML PASSED
69 . W "ERROR IN XML FILE",!
70 S GPLSTK(0)=0 ; INITIALIZE STACK
71 F I=1:1:@ZXML@(0) D ; PROCESS THE ENTIRE ARRAY
72 . S LINE=@ZXML@(I)
73 . ;W LINE,!
74 . S FOUND=0 ; INTIALIZED FOUND FLAG
75 . I LINE?.E1"<!".E S FOUND=1 ; SKIP OVER COMMENTS
76 . I FOUND'=1 D
77 . . I (LINE?.E1"<"1.E1"</".E)!(LINE?.E1"<"1.E1"/>".E) D
78 . . . ; THIS IS THE CASE THERE SECTION BEGINS AND ENDS
79 . . . ; ON THE SAME LINE
80 . . . ; W "FOUND ",LINE,!
81 . . . S FOUND=1 ; SET FOUND FLAG
82 . . . S CUR=$$XNAME(LINE) ; EXTRACT THE NAME
83 . . . D PUSH("GPLSTK",CUR) ; ADD TO THE STACK
84 . . . D MKMDX("GPLSTK",.MDX) ; GENERATE THE M INDEX
85 . . . ; W "MDX=",MDX,!
86 . . . I $D(@ZXML@(MDX)) D ; IN THE INDEX, IS A MULTIPLE
87 . . . . S $P(@ZXML@(MDX),"^",2)=I ; UPDATE LAST LINE NUMBER
88 . . . I '$D(@ZXML@(MDX)) D ; NOT IN THE INDEX, NOT A MULTIPLE
89 . . . . S @ZXML@(MDX)=I_"^"_I ; ADD INDEX ENTRY-FIRST AND LAST
90 . . . D POP("GPLSTK",.TMP) ; REMOVE FROM STACK
91 . I FOUND'=1 D ; THE LINE DOESN'T CONTAIN THE START AND END
92 . . I LINE?.E1"</"1.E D ; LINE CONTAINS END OF A SECTION
93 . . . ; W "FOUND ",LINE,!
94 . . . S FOUND=1 ; SET FOUND FLAG
95 . . . S CUR=$$XNAME(LINE) ; EXTRACT THE NAME
96 . . . D MKMDX("GPLSTK",.MDX) ; GENERATE THE M INDEX
97 . . . S $P(@ZXML@(MDX),"^",2)=I ; UPDATE LAST LINE NUMBER
98 . . . D POP("GPLSTK",.TMP) ; REMOVE FROM STACK
99 . . . I TMP'=CUR D ; MALFORMED XML, END MUST MATCH START
100 . . . . W "MALFORMED XML ",CUR,"LINE "_I_LINE,!
101 . . . . Q
102 . I FOUND'=1 D ; THE LINE MIGHT CONTAIN A SECTION BEGINNING
103 . . I (LINE?.E1"<"1.E)&(LINE'["?>") D ; BEGINNING OF A SECTION
104 . . . ; W "FOUND ",LINE,!
105 . . . S FOUND=1 ; SET FOUND FLAG
106 . . . S CUR=$$XNAME(LINE) ; EXTRACT THE NAME
107 . . . D PUSH("GPLSTK",CUR) ; ADD TO THE STACK
108 . . . D MKMDX("GPLSTK",.MDX) ; GENERATE THE M INDEX
109 . . . ; W "MDX=",MDX,!
110 . . . I $D(@ZXML@(MDX)) D ; IN THE INDEX, IS A MULTIPLE
111 . . . . S $P(@ZXML@(MDX),"^",2)=I ; UPDATE LAST LINE NUMBER
112 . . . I '$D(@ZXML@(MDX)) D ; NOT IN THE INDEX, NOT A MULTIPLE
113 . . . . S @ZXML@(MDX)=I_"^" ; INSERT INTO THE INDEX
114 S @ZXML@("INDEXED")=""
115 S @ZXML@("//")="1^"_@ZXML@(0) ; ROOT XPATH
116 Q
117 ;
118QUERY(IARY,XPATH,OARY) ; RETURNS THE XML ARRAY MATCHING THE XPATH EXPRESSION
119 ; XPATH IS OF THE FORM "//FIRST/SECOND/THIRD"
120 ; IARY AND OARY ARE PASSED BY NAME
121 I '$D(@IARY@("INDEXED")) D ; INDEX IS NOT PRESENT IN IARY
122 . D INDEX(IARY) ; GENERATE AN INDEX FOR THE XML
123 N FIRST,LAST ; FIRST AND LAST LINES OF ARRAY TO RETURN
124 N TMP,I,J,QXPATH
125 S FIRST=1
126 S LAST=@IARY@(0) ; FIRST AND LAST DEFAULT TO ROOT
127 I XPATH'="//" D ; NOT A ROOT QUERY
128 . S TMP=@IARY@(XPATH) ; LOOK UP LINE VALUES
129 . S FIRST=$P(TMP,"^",1)
130 . S LAST=$P(TMP,"^",2)
131 K @OARY
132 S @OARY@(0)=+LAST-FIRST+1
133 S J=1
134 FOR I=FIRST:1:LAST D
135 . S @OARY@(J)=@IARY@(I) ; COPY THE LINE TO OARY
136 . S J=J+1
137 ; ZWR OARY
138 Q
139 ;
140XF(IDX,XPATH) ; EXTRINSIC TO RETURN THE STARTING LINE FROM AN XPATH
141 ; INDEX WITH TWO PIECES START^FINISH
142 ; IDX IS PASSED BY NAME
143 Q $P(@IDX@(XPATH),"^",1)
144 ;
145XL(IDX,XPATH) ; EXTRINSIC TO RETURN THE LAST LINE FROM AN XPATH
146 ; INDEX WITH TWO PIECES START^FINISH
147 ; IDX IS PASSED BY NAME
148 Q $P(@IDX@(XPATH),"^",2)
149 ;
150START(ISTR) ; EXTRINSIC TO RETURN THE STARTING LINE FROM AN INDEX
151 ; TYPE STRING WITH THREE PIECES ARRAY;START;FINISH
152 ; COMPANION TO FINISH ; IDX IS PASSED BY NAME
153 Q $P(ISTR,";",2)
154 ;
155FINISH(ISTR) ; EXTRINSIC TO RETURN THE LAST LINE FROM AN INDEX
156 ; TYPE STRING WITH THREE PIECES ARRAY;START;FINISH
157 Q $P(ISTR,";",3)
158 ;
159ARRAY(ISTR) ; EXTRINSIC TO RETURN THE ARRAY REFERENCE FROM AN INDEX
160 ; TYPE STRING WITH THREE PIECES ARRAY;START;FINISH
161 Q $P(ISTR,";",1)
162 ;
163BUILD(BLIST,BDEST) ; A COPY MACHINE THAT TAKE INSTRUCTIONS IN ARRAY BLIST
164 ; WHICH HAVE ARRAY;START;FINISH AND COPIES THEM TO DEST
165 ; DEST IS CLEARED TO START
166 ; USES PUSH TO DO THE COPY
167 N I
168 K @BDEST
169 F I=1:1:@BLIST@(0) D ; FOR EACH INSTRUCTION IN BLIST
170 . N J,ATMP
171 . S ATMP=$$ARRAY(@BLIST@(I))
172 . I DEBUG W "ATMP=",ATMP,!
173 . I DEBUG W @BLIST@(I),!
174 . F J=$$START(@BLIST@(I)):1:$$FINISH(@BLIST@(I)) D ;
175 . . ; FOR EACH LINE IN THIS INSTR
176 . . I DEBUG W "BDEST= ",BDEST,!
177 . . I DEBUG W "ATMP= ",@ATMP@(J),!
178 . . D PUSH(BDEST,@ATMP@(J))
179 Q
180 ;
181QUEUE(BLST,ARRAY,FIRST,LAST) ; ADD AN ENTRY TO A BLIST
182 ;
183 I DEBUG W "QUEUEING ",BLST,!
184 D PUSH(BLST,ARRAY_";"_FIRST_";"_LAST)
185 Q
186 ;
187CP(CPSRC,CPDEST) ; COPIES CPSRC TO CPDEST BOTH PASSED BY NAME
188 ; KILLS CPDEST FIRST
189 N CPINSTR
190 I DEBUG W "MADE IT TO COPY",CPSRC,CPDEST,!
191 I @CPSRC@(0)<1 D ; BAD LENGTH
192 . W "ERROR IN COPY BAD SOURCE LENGTH: ",CPSRC,!
193 . Q
194 ; I '$D(@CPDEST@(0)) S @CPDEST@(0)=0 ; IF THE DEST IS EMPTY, INIT
195 D QUEUE("CPINSTR",CPSRC,1,@CPSRC@(0)) ; BLIST FOR ENTIRE ARRAY
196 D BUILD("CPINSTR",CPDEST)
197 Q
198 ;
199QOPEN(QOBLIST,QOXML,QOXPATH) ; ADD ALL BUT THE LAST LINE OF QOXML TO QOBLIST
200 ; WARNING NEED TO DO QCLOSE FOR SAME XML BEFORE CALLING BUILD
201 ; QOXPATH IS OPTIONAL - WILL OPEN INSIDE THE XPATH POINT
202 ; USED TO INSERT CHILDREN NODES
203 I @QOXML@(0)<1 D ; MALFORMED XML
204 . W "MALFORMED XML PASSED TO QOPEN: ",QOXML,!
205 . Q
206 I DEBUG W "DOING QOPEN",!
207 N S1,E1,QOT,QOTMP
208 S S1=1 ; OPEN FROM THE BEGINNING OF THE XML
209 I $D(QOXPATH) D ; XPATH PROVIDED
210 . D QUERY(QOXML,QOXPATH,"QOT") ; INSURE INDEX
211 . S E1=$P(@QOXML@(QOXPATH),"^",2)-1
212 I '$D(QOXPATH) D ; NO XPATH PROVIDED, OPEN AT ROOT
213 . S E1=@QOXML@(0)-1
214 D QUEUE(QOBLIST,QOXML,S1,E1)
215 ; S QOTMP=QOXML_"^"_S1_"^"_E1
216 ; D PUSH(QOBLIST,QOTMP)
217 Q
218 ;
219QCLOSE(QCBLIST,QCXML,QCXPATH) ; CLOSE XML AFTER A QOPEN
220 ; ADDS THE LIST LINE OF QCXML TO QCBLIST
221 ; USED TO FINISH INSERTING CHILDERN NODES
222 ; QCXPATH IS OPTIONAL - IF PROVIDED, WILL CLOSE UNTIL THE END
223 ; IF QOPEN WAS CALLED WITH XPATH, QCLOSE SHOULD BE TOO
224 I @QCXML@(0)<1 D ; MALFORMED XML
225 . W "MALFORMED XML PASSED TO QCLOSE: ",QCXML,!
226 I DEBUG W "GOING TO CLOSE",!
227 N S1,E1,QCT,QCTMP
228 S E1=@QCXML@(0) ; CLOSE UNTIL THE END OF THE XML
229 I $D(QCXPATH) D ; XPATH PROVIDED
230 . D QUERY(QCXML,QCXPATH,"QCT") ; INSURE INDEX
231 . S S1=$P(@QCXML@(QCXPATH),"^",2) ; REMAINING XML
232 I '$D(QCXPATH) D ; NO XPATH PROVIDED, CLOSE AT ROOT
233 . S S1=@QCXML@(0)
234 D QUEUE(QCBLIST,QCXML,S1,E1)
235 ; D PUSH(QCBLIST,QCXML_";"_S1_";"_E1)
236 Q
237 ;
238INSERT(INSXML,INSNEW,INSXPATH) ; INSERT INSNEW INTO INSXML AT THE
239 ; INSXPATH XPATH POINT INSXPATH IS OPTIONAL - IF IT IS
240 ; OMITTED, INSERTION WILL BE AT THE ROOT
241 ; NOTE INSERT IS NON DESTRUCTIVE AND WILL ADD THE NEW
242 ; XML AT THE END OF THE XPATH POINT
243 ; INSXML AND INSNEW ARE PASSED BY NAME INSXPATH IS A VALUE
244 N INSBLD,INSTMP
245 I DEBUG W "DOING INSERT ",INSXML,INSNEW,INSXPATH,!
246 I DEBUG F G1=1:1:@INSXML@(0) W @INSXML@(G1),!
247 I '$D(@INSXML@(0)) D ; INSERT INTO AN EMPTY ARRAY
248 . D CP^GPLXPATH(INSNEW,INSXML) ; JUST COPY INTO THE OUTPUT
249 I $D(@INSXML@(0)) D ; IF ORIGINAL ARRAY IS NOT EMPTY
250 . I $D(INSXPATH) D ; XPATH PROVIDED
251 . . D QOPEN("INSBLD",INSXML,INSXPATH) ; COPY THE BEFORE
252 . . I DEBUG D PARY^GPLXPATH("INSBLD")
253 . I '$D(INSXPATH) D ; NO XPATH PROVIDED, OPEN AT ROOT
254 . . D QOPEN("INSBLD",INSXML,"//") ; OPEN WITH ROOT XPATH
255 . D QUEUE("INSBLD",INSNEW,1,@INSNEW@(0)) ; COPY IN NEW XML
256 . I $D(INSXPATH) D ; XPATH PROVIDED
257 . . D QCLOSE("INSBLD",INSXML,INSXPATH) ; CLOSE WITH XPATH
258 . I '$D(INSXPATH) D ; NO XPATH PROVIDED, CLOSE AT ROOT
259 . . D QCLOSE("INSBLD",INSXML,"//") ; CLOSE WITH ROOT XPATH
260 . D BUILD("INSBLD","INSTMP") ; PUT RESULTS IN INDEST
261 . D CP^GPLXPATH("INSTMP",INSXML) ; COPY BUFFER TO SOURCE
262 Q
263 ;
264INSINNER(INNXML,INNNEW,INNXPATH) ; INSERT THE INNER XML OF INNNEW
265 ; INTO INNXML AT THE INNXPATH XPATH POINT
266 ;
267 N INNBLD,UXPATH
268 N INNTBUF
269 S INNTBUF=$NA(^TMP($J,"INNTBUF"))
270 I '$D(INNXPATH) D ; XPATH NOT PASSED
271 . S UXPATH="//" ; USE ROOT XPATH
272 I $D(INNXPATH) S UXPATH=INNXPATH ; USE THE XPATH THAT'S PASSED
273 I '$D(@INNXML@(0)) D ; INNXML IS EMPTY
274 . D QUEUE^GPLXPATH("INNBLD",INNNEW,2,@INNNEW@(0)-1) ; JUST INNER
275 . D BUILD("INNBLD",INNXML)
276 I @INNXML@(0)>0 D ; NOT EMPTY
277 . D QOPEN("INNBLD",INNXML,UXPATH) ;
278 . D QUEUE("INNBLD",INNNEW,2,@INNNEW@(0)-1) ; JUST INNER XML
279 . D QCLOSE("INNBLD",INNXML,UXPATH)
280 . D BUILD("INNBLD",INNTBUF) ; BUILD TO BUFFER
281 . D CP(INNTBUF,INNXML) ; COPY BUFFER TO DEST
282 Q
283 ;
284REPLACE(REXML,RENEW,REXPATH) ; REPLACE THE XML AT THE XPATH POINT
285 ; WITH RENEW - NOTE THIS WILL DELETE WHAT WAS THERE BEFORE
286 ; REXML AND RENEW ARE PASSED BY NAME XPATH IS A VALUE
287 ; THE DELETED XML IS PUT IN ^TMP($J,"REPLACE_OLD")
288 N REBLD,XFIRST,XLAST,OLD,XNODE,RETMP
289 S OLD=$NA(^TMP($J,"REPLACE_OLD"))
290 D QUERY(REXML,REXPATH,OLD) ; CREATE INDEX, TEST XPATH, MAKE OLD
291 S XNODE=@REXML@(REXPATH) ; PULL OUT FIRST AND LAST LINE PTRS
292 S XFIRST=$P(XNODE,"^",1)
293 S XLAST=$P(XNODE,"^",2)
294 D QUEUE("REBLD",REXML,1,XFIRST) ; THE BEFORE
295 I RENEW'="" D ; NEW XML IS NOT NULL
296 . D QUEUE("REBLD",RENEW,1,@RENEW@(0)) ; THE NEW
297 D QUEUE("REBLD",REXML,XLAST,@REXML@(0)) ; THE REST
298 I DEBUG W "REPALCE PREBUILD",!
299 I DEBUG D PARY("REBLD")
300 D BUILD("REBLD","RTMP")
301 K @REXML ; KILL WHAT WAS THERE
302 D CP("RTMP",REXML) ; COPY IN THE RESULT
303 Q
304 ;
305MISSING(IXML,OARY) ; SEARTH THROUGH INXLM AND PUT ANY @@X@@ VARS IN OARY
306 ; W "Reporting on the missing",!
307 ; W OARY
308 I '$D(@IXML@(0)) W "MALFORMED XML PASSED TO MISSING",! Q
309 N I
310 S @OARY@(0)=0 ; INITIALIZED MISSING COUNT
311 F I=1:1:@IXML@(0) D ; LOOP THROUGH WHOLE ARRAY
312 . I @IXML@(I)?.E1"@@".E D ; MISSING VARIABLE HERE
313 . . D PUSH^GPLXPATH(OARY,$P(@IXML@(I),"@@",2)) ; ADD TO OUTARY
314 . . Q
315 Q
316 ;
317MAP(IXML,INARY,OXML) ; SUBSTITUTE @@X@@ VARS IN IXML WITH VALUES IN INARY
318 ; AND PUT THE RESULTS IN OXML
319 I '$D(@IXML@(0)) W "MALFORMED XML PASSED TO MAP",! Q
320 I $O(@INARY@(""))="" W "EMPTY ARRAY PASSED TO MAP",! Q
321 N I,TNAM,TVAL
322 S @OXML@(0)=@IXML@(0) ; TOTAL LINES IN OUTPUT
323 F I=1:1:@OXML@(0) D ; LOOP THROUGH WHOLE ARRAY
324 . S @OXML@(I)=@IXML@(I) ; COPY THE LINE TO OUTPUT
325 . I @OXML@(I)?.E1"@@".E D ; IS THERE A VARIABLE HERE?
326 . . S TNAM=$P(@OXML@(I),"@@",2) ; EXTRACT THE VARIABLE NAME
327 . . I $D(@INARY@(TNAM)) D ; IS THE VARIABLE IN THE MAP?
328 . . . S TVAL=@INARY@(TNAM) ; PULL OUT MAPPED VALUE
329 . . . S @OXML@(I)=$P(@OXML@(I),"@@",1)_TVAL_$P(@OXML@(I),"@@",3)
330 W "MAPPED",!
331 Q
332 ;
333TRIM(THEXML) ; TAKES OUT ALL NULL ELEMENTS
334 ; THEXML IS PASSED BY NAME
335 N I,J,TMPXML,DEL
336 F I=1:1:@THEXML@(0) D ; LOOP THROUGH ENTIRE ARRAY
337 . I @THEXML@(I)'["><" D PUSH("TMPXML",@THEXML@(I))
338 D INDEX("TMPXML") ; MAKE AN XPATH INDEX
339 S I="" S I=$O(TMPXML(I))
340 F K=0:0 D Q:I="" ; NOW LOOK FOR EMPTY SECTIONS
341 . I I["//" D ;
342 . . W I,TMPXML(I),!
343 . . S J=$P(TMPXML(I),"^",1)
344 . . I J+1=$P(TMPXML(I),"^",2) D ;
345 . . . W I,!
346 . . . S DEL(J)=""
347 . . . S DEL(J+1)=""
348 . S I=$O(TMPXML(I))
349 F I=1:1:TMPXML(0) D ;
350 . I '$D(DEL(I))
351 . D PUSH("TMPXML2",TMPXML(I))
352 D CP("TMPXML2",THEXML)
353 Q
354 ;
355PARY(GLO) ;PRINT AN ARRAY
356 N I
357 F I=1:1:@GLO@(0) W @GLO@(I),!
358 Q
359 ;
360TEST ; Run all the test cases
361 D TESTALL^GPLUNIT("GPLXPATH")
362 Q
363 ;
364OLDTEST ; RUN ALL THE TEST CASES
365 N ZTMP
366 D ZLOAD^GPLUNIT("ZTMP","GPLXPATH")
367 D ZTEST^GPLUNIT(.ZTMP,"ALL")
368 W "PASSED: ",TPASSED,!
369 W "FAILED: ",TFAILED,!
370 W !
371 ; W "THE TESTS!",!
372 ; ZWR ZTMP
373 Q
374 ;
375ZTEST(WHICH) ; RUN ONE SET OF TESTS
376 N ZTMP
377 S DEBUG=1
378 D ZLOAD^GPLUNIT("ZTMP","GPLXPATH")
379 D ZTEST^GPLUNIT(.ZTMP,WHICH)
380 Q
381 ;
382TLIST ; LIST THE TESTS
383 N ZTMP
384 D ZLOAD^GPLUNIT("ZTMP","GPLXPATH")
385 D TLIST^GPLUNIT(.ZTMP)
386 Q
387 ;
388 ;;><TEST>
389 ;;><INIT>
390 ;;>>>K GPL S GPL=""
391 ;;>>>D PUSH^GPLXPATH("GPL","FIRST")
392 ;;>>>D PUSH^GPLXPATH("GPL","SECOND")
393 ;;>>>D PUSH^GPLXPATH("GPL","THIRD")
394 ;;>>>D PUSH^GPLXPATH("GPL","FOURTH")
395 ;;>>?GPL(0)=4
396 ;;><INITXML>
397 ;;>>>K GXML S GXML=""
398 ;;>>>D PUSH^GPLXPATH("GXML","<FIRST>")
399 ;;>>>D PUSH^GPLXPATH("GXML","<SECOND>")
400 ;;>>>D PUSH^GPLXPATH("GXML","<THIRD>")
401 ;;>>>D PUSH^GPLXPATH("GXML","<FOURTH>@@DATA1@@</FOURTH>")
402 ;;>>>D PUSH^GPLXPATH("GXML","<FIFTH>")
403 ;;>>>D PUSH^GPLXPATH("GXML","@@DATA2@@")
404 ;;>>>D PUSH^GPLXPATH("GXML","</FIFTH>")
405 ;;>>>D PUSH^GPLXPATH("GXML","<SIXTH ID=""SELF"" />")
406 ;;>>>D PUSH^GPLXPATH("GXML","</THIRD>")
407 ;;>>>D PUSH^GPLXPATH("GXML","<SECOND>")
408 ;;>>>D PUSH^GPLXPATH("GXML","</SECOND>")
409 ;;>>>D PUSH^GPLXPATH("GXML","</SECOND>")
410 ;;>>>D PUSH^GPLXPATH("GXML","</FIRST>")
411 ;;><INITXML2>
412 ;;>>>K GXML S GXML=""
413 ;;>>>D PUSH^GPLXPATH("GXML","<FIRST>")
414 ;;>>>D PUSH^GPLXPATH("GXML","<SECOND>")
415 ;;>>>D PUSH^GPLXPATH("GXML","<THIRD>")
416 ;;>>>D PUSH^GPLXPATH("GXML","<FOURTH>DATA1</FOURTH>")
417 ;;>>>D PUSH^GPLXPATH("GXML","<FOURTH>")
418 ;;>>>D PUSH^GPLXPATH("GXML","DATA2")
419 ;;>>>D PUSH^GPLXPATH("GXML","</FOURTH>")
420 ;;>>>D PUSH^GPLXPATH("GXML","</THIRD>")
421 ;;>>>D PUSH^GPLXPATH("GXML","<_SECOND>")
422 ;;>>>D PUSH^GPLXPATH("GXML","<FOURTH>DATA3</FOURTH>")
423 ;;>>>D PUSH^GPLXPATH("GXML","</_SECOND>")
424 ;;>>>D PUSH^GPLXPATH("GXML","</SECOND>")
425 ;;>>>D PUSH^GPLXPATH("GXML","</FIRST>")
426 ;;><PUSHPOP>
427 ;;>>>D ZLOAD^GPLUNIT("ZTMP","GPLXPATH")
428 ;;>>>D ZTEST^GPLUNIT(.ZTMP,"INIT")
429 ;;>>?GPL(GPL(0))="FOURTH"
430 ;;>>>D POP^GPLXPATH("GPL",.GX)
431 ;;>>?GX="FOURTH"
432 ;;>>?GPL(GPL(0))="THIRD"
433 ;;>>>D POP^GPLXPATH("GPL",.GX)
434 ;;>>?GX="THIRD"
435 ;;>>?GPL(GPL(0))="SECOND"
436 ;;><MKMDX>
437 ;;>>>D ZLOAD^GPLUNIT("ZTMP","GPLXPATH")
438 ;;>>>D ZTEST^GPLUNIT(.ZTMP,"INIT")
439 ;;>>>S GX=""
440 ;;>>>D MKMDX^GPLXPATH("GPL",.GX)
441 ;;>>?GX="//FIRST/SECOND/THIRD/FOURTH"
442 ;;><XNAME>
443 ;;>>?$$XNAME^GPLXPATH("<FOURTH>DATA1</FOURTH>")="FOURTH"
444 ;;>>?$$XNAME^GPLXPATH("<SIXTH ID=""SELF"" />")="SIXTH"
445 ;;>>?$$XNAME^GPLXPATH("</THIRD>")="THIRD"
446 ;;><INDEX>
447 ;;>>>D ZLOAD^GPLUNIT("ZTMP","GPLXPATH")
448 ;;>>>D ZTEST^GPLUNIT(.ZTMP,"INITXML")
449 ;;>>>D INDEX^GPLXPATH("GXML")
450 ;;>>?GXML("//FIRST/SECOND")="2^12"
451 ;;>>?GXML("//FIRST/SECOND/THIRD")="3^9"
452 ;;>>?GXML("//FIRST/SECOND/THIRD/FIFTH")="5^7"
453 ;;>>?GXML("//FIRST/SECOND/THIRD/FOURTH")="4^4"
454 ;;>>?GXML("//FIRST/SECOND/THIRD/SIXTH")="8^8"
455 ;;>>?GXML("//FIRST/SECOND")="2^12"
456 ;;>>?GXML("//FIRST")="1^13"
457 ;;><INDEX2>
458 ;;>>>D ZTEST^GPLXPATH("INITXML2")
459 ;;>>>D INDEX^GPLXPATH("GXML")
460 ;;>>?GXML("//FIRST/SECOND")="2^12"
461 ;;>>?GXML("//FIRST/SECOND/_SECOND")="9^11"
462 ;;>>?GXML("//FIRST/SECOND/_SECOND/FOURTH")="10^10"
463 ;;>>?GXML("//FIRST/SECOND/THIRD")="3^8"
464 ;;>>?GXML("//FIRST/SECOND/THIRD/FOURTH")="4^7"
465 ;;>>?GXML("//FIRST")="1^13"
466 ;;><MISSING>
467 ;;>>>D ZTEST^GPLXPATH("INITXML")
468 ;;>>>S OUTARY="^TMP($J,""MISSINGTEST"")"
469 ;;>>>D MISSING^GPLXPATH("GXML",OUTARY)
470 ;;>>?@OUTARY@(1)="DATA1"
471 ;;>>?@OUTARY@(2)="DATA2"
472 ;;><MAP>
473 ;;>>>D ZTEST^GPLXPATH("INITXML")
474 ;;>>>S MAPARY="^TMP($J,""MAPVALUES"")"
475 ;;>>>S OUTARY="^TMP($J,""MAPTEST"")"
476 ;;>>>S @MAPARY@("DATA2")="VALUE2"
477 ;;>>>D MAP^GPLXPATH("GXML",MAPARY,OUTARY)
478 ;;>>?@OUTARY@(6)="VALUE2"
479 ;;><QUEUE>
480 ;;>>>D QUEUE^GPLXPATH("BTLIST","GXML",2,3)
481 ;;>>>D QUEUE^GPLXPATH("BTLIST","GXML",4,5)
482 ;;>>?$P(BTLIST(2),";",2)=4
483 ;;><BUILD>
484 ;;>>>D ZTEST^GPLXPATH("INITXML")
485 ;;>>>D QUERY^GPLXPATH("GXML","//FIRST/SECOND/THIRD/FOURTH","G2")
486 ;;>>>D ZTEST^GPLXPATH("QUEUE")
487 ;;>>>D BUILD^GPLXPATH("BTLIST","G3")
488 ;;><CP>
489 ;;>>>D ZTEST^GPLXPATH("INITXML")
490 ;;>>>D CP^GPLXPATH("GXML","G2")
491 ;;>>?G2(0)=13
492 ;;><QOPEN>
493 ;;>>>K G2,GBL
494 ;;>>>D ZTEST^GPLXPATH("INITXML")
495 ;;>>>D QOPEN^GPLXPATH("GBL","GXML")
496 ;;>>?$P(GBL(1),";",3)=12
497 ;;>>>D BUILD^GPLXPATH("GBL","G2")
498 ;;>>?G2(G2(0))="</SECOND>"
499 ;;><QOPEN2>
500 ;;>>>K G2,GBL
501 ;;>>>D ZTEST^GPLXPATH("INITXML")
502 ;;>>>D QOPEN^GPLXPATH("GBL","GXML","//FIRST/SECOND")
503 ;;>>?$P(GBL(1),";",3)=11
504 ;;>>>D BUILD^GPLXPATH("GBL","G2")
505 ;;>>?G2(G2(0))="</SECOND>"
506 ;;><QCLOSE>
507 ;;>>>K G2,GBL
508 ;;>>>D ZTEST^GPLXPATH("INITXML")
509 ;;>>>D QCLOSE^GPLXPATH("GBL","GXML")
510 ;;>>?$P(GBL(1),";",3)=13
511 ;;>>>D BUILD^GPLXPATH("GBL","G2")
512 ;;>>?G2(G2(0))="</FIRST>"
513 ;;><QCLOSE2>
514 ;;>>>K G2,GBL
515 ;;>>>D ZTEST^GPLXPATH("INITXML")
516 ;;>>>D QCLOSE^GPLXPATH("GBL","GXML","//FIRST/SECOND/THIRD")
517 ;;>>?$P(GBL(1),";",3)=13
518 ;;>>>D BUILD^GPLXPATH("GBL","G2")
519 ;;>>?G2(G2(0))="</FIRST>"
520 ;;>>?G2(1)="</THIRD>"
521 ;;><INSERT>
522 ;;>>>K G2,GBL,G3,G4
523 ;;>>>D ZTEST^GPLXPATH("INITXML")
524 ;;>>>D QUERY^GPLXPATH("GXML","//FIRST/SECOND/THIRD/FIFTH","G2")
525 ;;>>>D INSERT^GPLXPATH("GXML","G2","//FIRST/SECOND/THIRD")
526 ;;>>>D INSERT^GPLXPATH("G3","G2","//")
527 ;;>>?G2(1)=GXML(9)
528 ;;><REPLACE>
529 ;;>>>K G2,GBL,G3
530 ;;>>>D ZTEST^GPLXPATH("INITXML")
531 ;;>>>D QUERY^GPLXPATH("GXML","//FIRST/SECOND/THIRD/FIFTH","G2")
532 ;;>>>D REPLACE^GPLXPATH("GXML","G2","//FIRST/SECOND")
533 ;;>>?GXML(3)="<FIFTH>"
534 ;;><INSINNER>
535 ;;>>>K GXML,G2,GBL,G3
536 ;;>>>D ZTEST^GPLXPATH("INITXML")
537 ;;>>>D QUERY^GPLXPATH("GXML","//FIRST/SECOND/THIRD","G2")
538 ;;>>>D INSINNER^GPLXPATH("GXML","G2","//FIRST/SECOND/THIRD")
539 ;;>>?GXML(10)="<FIFTH>"
540 ;;><INSINNER2>
541 ;;>>>K GXML,G2,GBL,G3
542 ;;>>>D ZTEST^GPLXPATH("INITXML")
543 ;;>>>D QUERY^GPLXPATH("GXML","//FIRST/SECOND/THIRD","G2")
544 ;;>>>D INSINNER^GPLXPATH("G2","G2")
545 ;;>>?G2(8)="<FIFTH>"
546 ;;></TEST>
Note: See TracBrowser for help on using the repository browser.