source: fmts/trunk/p/C0XPT2.m@ 1613

Last change on this file since 1613 was 1606, checked in by Sam Habiel, 12 years ago

Finished allergies (added reactions); allergies and problems in their own routines now
File size: 5.5 KB
Line 
1C0XPT2 ; VEN/SMH - Get and Store Allergies/ADRs ;2013-02-19 12:03 PM
2 ;;1.1;FILEMAN TRIPLE STORE;;
3 ;
4ADR(G,DFN) ; Private Proc; Extract Allergies and ADRs from Graph and add to Patient's Record
5 ; Input: G, Patient Graph, DFN, you should know that that is; Both by value.
6 ;
7 ; Try No known allergies first.
8 N NKA S NKA=$$ONETYPE1^C0XGET3(G,"sp:AllergyExclusion") ; Get NKA node
9 ;
10 ; Add NKA to record.
11 ; We don't really care about the return value. If patient already has
12 ; allergies, we just keep them.
13 I $L(NKA) N % S %=$$NKA(DFN) QUIT ; If it exists, let's try to file it into VISTA
14 ;
15 ; If we are here, it means that the patient has allergies. Fun!
16 ; Process incoming allergies
17 N RETURN ; Local return variable. I don't expect a patient to have more than 50 allergies.
18 D ONETYPE^C0XGET3($NA(RETURN),G,"sp:Allergy") ; Get all allergies for patient
19 ;
20 N S F S=0:0 S S=$O(RETURN(S)) Q:'S D ; For each allergy
21 . ; Get the SNOMED code for the category
22 . N ALLERGYTYPE
23 . N SNOCAT S SNOCAT=$$GSPO1^C0XGET3(G,RETURN(S),"sp:category.sp:code"),SNOCAT=$P(SNOCAT,"/",$L(SNOCAT,"/"))
24 . I SNOCAT=414285001 S ALLERGYTYPE="F" ; Food
25 . E I SNOCAT=416098002 S ALLERGYTYPE="D" ; Drug
26 . I '$D(ALLERGYTYPE) S $EC=",U1," ; Crash if neither of these is true.
27 . ;
28 . N ALLERGEN,ALLERGENI ; Allergen, Internal Allergen
29 . I ALLERGYTYPE="F" D ; Food
30 . . S ALLERGEN=$$UP^XLFSTR($$GSPO1^C0XGET3(G,RETURN(S),"sp:otherAllergen.dcterms:title")) ; uppercase the allergen
31 . . I ALLERGEN="PEANUT" S ALLERGEN="PEANUTS" ; TODO: temporary fix
32 . . S ALLERGENI=$$GMRA(ALLERGEN) ; Get internal representation for GMRA call
33 . ;
34 . ; Otherwise, it's a drug. But we need to find out if it's a class,
35 . ; ingredient, canonical drug, etc. Unfortunately, Smart examples don't
36 . ; show such variety. The only one specified is a drug class.
37 . ; Therefore
38 . ; TODO: Handle other drug items besides drug class
39 . ;
40 . E D ; Drug Class
41 . . N DC S DC=$$GSPO1^C0XGET3(G,RETURN(S),"sp:drugClassAllergen.sp:code") ; drug class
42 . . I '$L(DC) QUIT ; edit this line out when handling other items
43 . . S ALLERGEN=$P(DC,"/",$L(DC,"/")) ; Get last piece
44 . . ; TODO: Resolve drug class properly. Need all of RxNorm for that.
45 . . N STR S STR=$$UP^XLFSTR($$GSPO1^C0XGET3(G,RETURN(S),"sp:drugClassAllergen.dcterms:title"))
46 . . I ALLERGEN="N0000175503" S ALLERGENI=STR_U_"23;PS(50.605," ; hard codeded for sulfonamides
47 . . ;
48 . ; DEBUG.ASSERT THAT allergen Internal isn't empty
49 . I '$L(ALLERGENI) S $EC=",U1,"
50 . ;
51 . ; Get Severity (Mild or Severe) - We get free text rather than SNOMED
52 . N SEVERITY S SEVERITY=$$UP^XLFSTR($$GSPO1^C0XGET3(G,RETURN(S),"sp:severity.dcterms:title"))
53 . I '$L(SEVERITY) S $EC=",U1,"
54 . ;
55 . ; Get Reaction - We get free text rather than SNOMED
56 . N REACTION S REACTION=$$UP^XLFSTR($$GSPO1^C0XGET3(G,RETURN(S),"sp:allergicReaction.dcterms:title"))
57 . I '$L(REACTION) S $EC=",U1,"
58 . ;
59 . ; Now that we have determined the allergy, add it
60 . D FILEADR(DFN,ALLERGENI,REACTION,SEVERITY,ALLERGYTYPE) ; Internal API
61 QUIT
62 ;
63NKA(DFN) ; Public $$; Add no known allergies to patient record
64 N ORDFN S ORDFN=DFN ; CPRS API requires this one
65 N ORY ; Return value: 0 - Everything is okay; -1^msg: Patient already has allergies
66 D NKA^GMRAGUI1 ; API
67 QUIT $G(ORY) ; Not always returned
68 ;
69GMRA(NAME) ; $$ Private - Retrieve GMRAGNT for food allergy from 120.82
70 ; Input: Brand Name, By Value
71 ; Output: Entry Name^IEN;File Root for IEN
72 N C0PIEN S C0PIEN=$$FIND1^DIC(120.82,"","O",NAME,"B")
73 Q:C0PIEN $$GET1^DIQ(120.82,C0PIEN,.01)_"^"_C0PIEN_";GMRD(120.82,"
74 QUIT "" ; no match otherwise
75 ;
76TYPE(GMRAGNT) ; $$ Private - Get allergy Type (Drug, food, or other)
77 ; Input: Allergen, formatted as Allergen^IEN;File Root
78 ; Output: Type (internal)^Type (external) e.g. D^Drug
79 N C0PIEN S C0PIEN=+$P(GMRAGNT,U,2)
80 I GMRAGNT["GMRD(120.82," Q $$GET1^DIQ(120.82,C0PIEN,"ALLERGY TYPE","I")_U_$$GET1^DIQ(120.82,C0PIEN,"ALLERGY TYPE","E")
81 Q "D^Drug" ; otherwise, it's a drug
82 ;
83FILEADR(DFN,AGENT,REACTION,SEVERITY,TYPE,DATE) ; Private Proc - File Drug Reaction
84 ; This is very messy right now. The more use this gets, the better idea
85 ; I will have of how much data resolution this API should expect and how
86 ; much it should do itself.
87 ;
88 K ^TMP($J,"ADR")
89 S ^TMP($J,"ADR","GMRAGNT")=AGENT ; Agent Free Text^Agent in variable pointer format
90 S ^TMP($J,"ADR","GMRATYPE")=TYPE ; F(ood), D(rug), or O(ther) or combination.
91 S ^TMP($J,"ADR","GMRANATR")="U^Unknown" ; Mechanism: Allergic, Pharmacologic, or Unknown
92 S ^TMP($J,"ADR","GMRAORIG")=$$NP^C0XPT0 ; New Person generated for SMART
93 S ^TMP($J,"ADR","GMRAORDT")=$G(DATE,$$NOW^XLFDT) ; Origination Date; Ideally, would have a date for the allergy.
94 S ^TMP($J,"ADR","GMRACHT",0)=1 ; Mark Chart as allergy document; don't know why; CPRS does that.
95 S ^TMP($J,"ADR","GMRACHT",1)=$$NOW^XLFDT ; Chart documentation date; don't know why; CPRS does that.
96 S ^TMP($J,"ADR","GMRAOBHX")="h^HISTORICAL" ; or o^Observered
97 S ^TMP($J,"ADR","GMRACMTS",0)=1 ; Comments
98 S ^TMP($J,"ADR","GMRACMTS",1)=SEVERITY ; Store severity in the comments (Severity in VISTA only applies to observed allergies)
99 S ^TMP($J,"ADR","GMRASYMP",0)=1 ; One Symptom
100 ;
101 ; Find IEN of Reaction from S/S file. We say "Q - Don't transform; X - exact match only; Screen on VUID status"
102 N RXN S RXN=$$FIND1^DIC(120.83,,"QX",REACTION,"B^D","I '$$SCREEN^XTID(120.83,.01,Y_"","")") ; Get Reaction IEN
103 I RXN S ^TMP($J,"ADR","GMRASYMP",1)=RXN_U_REACTION ; Coded reaction
104 E S ^TMP($J,"ADR","GMRASYMP",1)="FT"_U_REACTION ; Free Text Reaction
105 ;
106 N ORY ; Return value 0: success; -1: failure; discarded.
107 D UPDATE^GMRAGUI1("",DFN,$NA(^TMP($J,"ADR")))
108 K ^TMP($J,"ADR")
109 QUIT
Note: See TracBrowser for help on using the repository browser.