Index: /Scheduling/trunk/m/BSDX26.m
===================================================================
--- /Scheduling/trunk/m/BSDX26.m	(revision 1035)
+++ /Scheduling/trunk/m/BSDX26.m	(revision 1036)
@@ -1,3 +1,3 @@
-BSDX26  ; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 11/18/10 5:36pm
+BSDX26  ; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 12/6/10 3:08am
     ;;1.42;BSDX;;Sep 29, 2010
     ; Change History:
@@ -34,4 +34,5 @@
     D EDITAPT(.ZZZ,188,NOTE)
     I +^BSDXTMP($J,1)'=-100 W "ERROR IN -100",! B
+    k bsdxdie
     ; Test 5: Trestart
     N bsdxrestart S bsdxrestart=1
@@ -40,9 +41,10 @@
     D EDITAPT(.ZZZ,188,NOTE)
     I ^BSDXAPPT(188,1,1,0)'=NOTE W "ERROR in TRESTART",! B
-    ; Test for Hosp Location Update
+    ; Test 6: for Hosp Location Update
     N DATE S DATE=$$NOW^XLFDT()
+    S DATE=$E(DATE,1,12) ; Just get minutes b/c of HL file input transform
     D APPADD^BSDX07(.ZZZ,DATE,DATE+.001,3,"Dr Office",30,"Old Note",1)
     N APPID S APPID=+$P(^BSDXTMP($J,1),U)
-    D EDITAPT(.ZZZ,APTID,"New Note")
+    D EDITAPT(.ZZZ,APPID,"New Note")
     I ^BSDXAPPT(APTID,1,1,0)'="New Note" W "Error in HL Section",! B
     I $P(^SC(2,"S",DATE,1,1,0),U,4)'="New Note" W "Error in HL Section",! B
Index: /Scheduling/trunk/m/BSDX29.m
===================================================================
--- /Scheduling/trunk/m/BSDX29.m	(revision 1035)
+++ /Scheduling/trunk/m/BSDX29.m	(revision 1036)
@@ -1,13 +1,17 @@
-BSDX29	; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 7/18/10 2:03pm
-	;;1.41;BSDX;;Sep 29, 2010
-	   ; 
-	   ; Change Log:
-	   ; v1.3 by WV/SMH on 3100713
+BSDX29	; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 12/6/10 6:05am
+	;;1.42;BSDX;;Sep 29, 2010
+	; 
+	; Change Log:
+	; v1.3 by WV/SMH on 3100713
 	; - Beginning and Ending dates passed as FM Dates
+    ; v1.42 by WV/SMH on 3101023
+    ; - Transaction moved; now restartable too.
+    ; --> Thanks to Zach Gonzalez and Rick Marshall.
+    ; - Refactoring of major portions of routine
 	;
 BSDXCPD(BSDXY,BSDXRES,BSDX44,BSDXBEG,BSDXEND)	;EP
 	;Entry point for debugging
 	;
-	;D DEBUG^%Serenji("BSDXCP^BSDX29(.BSDXY,BSDXRES,BSDX44,BSDXBEG,BSDXEND)")
+	D DEBUG^%Serenji("BSDXCP^BSDX29(.BSDXY,BSDXRES,BSDX44,BSDXBEG,BSDXEND)")
 	Q
 	;
@@ -15,39 +19,40 @@
 	;Copy appointments from HOSPITAL LOCATION entry BSDX44 to BSDX RESOURCE entry BSDXRES
 	;Beginning with appointments on day BSDXBEG and ending on BSDXEND, inclusive
-	;
-	;Returns ADO Recordset formatted fields containing count of records copied and error message:
-	   ;
-	   ; July 13 2010: D dates (BEG and END) from US format to FM Dates for i18n
-	;
-	;
-	S BSDXY="^BSDXTMP("_$J_")"
-	N BSDXI,BSDXST,ZTSK
-	S BSDXI=0
-	S X="ETRAP^BSDX29",@^%ZOSF("TRAP")
+    ;Called by RPC: BSDX COPY APPOINTMENTS
+	;
+    ; Parameters:
+    ; - BSDXY: Global Return
+    ; - BSDXRES: BSDX RESOURCE to copy appointments to
+    ; - BSDX44: Hospital Location IEN to copy appointments from
+    ; - BSDXBEG: Beginning Date in FM Format
+    ; - BSDXEND: End Date in FM Format
+    ;
+	;Returns ADO Recordset containing TASK_NUMBER and ERRORID
+	;
+    ; Return Array
+	S BSDXY=$NA(^BSDXTMP($J))
+    K ^BSDXTMP($J)
+    ; $ET
+    N $ET S $ET="G ETRAP^BSDX29"
+	; Counter
+    N BSDXI S BSDXI=0
+    ; Header Node
 	S ^BSDXTMP($J,0)="T00010TASK_NUMBER^T00020ERRORID"_$C(30)
 	;
-	;Convert beginning and ending dates
-	   ;
-	   ;TODO:Validate FM Dates coming through
-	;
-	S BSDXBEG=BSDXBEG-1
+    ; Make dates inclusive; add 1 to FM dates
+    S BSDXBEG=BSDXBEG-1
 	S BSDXEND=BSDXEND+1
 	;
+    ; Taskman variables
+    N ZTSK,ZTRTN,ZTDTH,ZTDESC,ZTSAVE 
+	; Task Load
 	S ZTRTN="ZTM^BSDX29",ZTDTH=$H,ZTDESC="COPY PATIENT APPTS"
 	S ZTSAVE("BSDXBEG")="",ZTSAVE("BSDXEND")="",ZTSAVE("BSDX44")="",ZTSAVE("BSDXRES")=""
 	D ^%ZTLOAD
-	;
-	S BSDXI=BSDXI+1
-	S BSDXST=$S($G(ZTSK)>0:"OK",1:"Unable to create task.")
+	; Set up return ADO.net dataset
+	N BSDXST S BSDXST=$S($G(ZTSK)>0:"OK",1:"Unable to create task.")
+	S BSDXI=BSDXI+1
 	S ^BSDXTMP($J,BSDXI)=$G(ZTSK)_"^"_BSDXST_$C(30)_$C(31)
-	Q
-	;
-ZTMTST	;
-	;
-	S %DT="AE" D ^%DT S BSDXBEG=Y
-	S %DT="AE" D ^%DT S BSDXEND=Y
-	S BSDX44=3,BSDXSRES=1,ZTSK=3380
-	D ZTM
-	Q
+	QUIT
 	;
 ZTMD	;EP - Debug entry point
@@ -55,24 +60,32 @@
 	Q
 	;
-ZTM	;EP
-	;Taskman entry point
-	S X="ZTMERR^BSDX29",@^%ZOSF("TRAP")
+ZTM	;EP - Taskman entry point
+    ; Variables set up in ZTSAVE above
+    ;
+	Q:'$D(ZTSK)
+    ; $ET
+    N $ET S $ET="G ZTMERR^BSDX29"
+	; Txn
+    TSTART (BSDXBEG,BSDXEND,BSDX44,BSDXRES):T="BSDX COPY APPOINTMENT^BSDX29"
 	;$O through ^SC(BSDX44,"S",
-	Q:'$D(ZTSK)
-	N BSDXCNT,BSDXIEN,BSDXNOD,BSDXNOTE,BSDXCAN,BSDXPAT,BSDXLEN,BSDXMADE,BSDXCLRK,BSDXPAT,BSDXQUIT
-	S BSDXCNT=0,BSDXQUIT=0
-	S ^BSDXTMP("BSDXCOPY",ZTSK)=BSDXCNT
-	TSTART
-	F  S BSDXBEG=$O(^SC(BSDX44,"S",BSDXBEG)) Q:'+BSDXBEG  Q:BSDXBEG>BSDXEND  Q:BSDXQUIT  D
-	. S BSDXIEN=0 F  S BSDXIEN=$O(^SC(BSDX44,"S",BSDXBEG,1,BSDXIEN)) Q:'+BSDXIEN  Q:BSDXQUIT  D
-	. . S BSDXNOD=$G(^SC(BSDX44,"S",BSDXBEG,1,BSDXIEN,0))
-	. . Q:'+BSDXNOD
-	. . S BSDXCAN=$P(BSDXNOD,U,9)
-	. . Q:BSDXCAN="C"
-	. . S BSDXPAT=$P(BSDXNOD,U)
-	. . S BSDXLEN=$P(BSDXNOD,U,2) ;duration in minutes
-	. . S BSDXCLRK=$P(BSDXNOD,U,6) ;appt made by (clerk)
-	. . S BSDXMADE=$P(BSDXNOD,U,7) ;date appt made
-	. . S BSDXNOTE=$P(BSDXNOD,U,4) ;'OTHER' field contains note
+	N BSDXCNT S BSDXCNT=0  ; Count of Copied Appointments
+    N BSDXQUIT S BSDXQUIT=0  ; Quit Flag to be retrieved from an external proc
+	; Set Count
+    S ^BSDXTMP("BSDXCOPY",ZTSK)=BSDXCNT
+	; Loop through dates here.
+    F  S BSDXBEG=$O(^SC(BSDX44,"S",BSDXBEG)) Q:'+BSDXBEG  Q:BSDXBEG>BSDXEND  Q:BSDXQUIT  D
+    . ; Loop through Entries in each date in the subsubfile.
+    . ; Quit if we are at the end or if a remote process requests a quit.
+    . N BSDXIEN S BSDXIEN=0
+	. F  S BSDXIEN=$O(^SC(BSDX44,"S",BSDXBEG,1,BSDXIEN)) Q:'+BSDXIEN  Q:BSDXQUIT  D
+	. . N BSDXNOD S BSDXNOD=$G(^SC(BSDX44,"S",BSDXBEG,1,BSDXIEN,0)) ; Node
+	. . Q:'+BSDXNOD  ; Quit if no node
+	. . N BSDXCAN S BSDXCAN=$P(BSDXNOD,U,9) ; Cancel flag
+	. . Q:BSDXCAN="C"  ; Quit if appt cancelled
+    . . N BSDXPAT S BSDXPAT=$P(BSDXNOD,U) ; Patient
+    . . N BSDXLEN S BSDXLEN=$P(BSDXNOD,U,2) ;duration in minutes
+	. . N BSDXCLRK S BSDXCLRK=$P(BSDXNOD,U,6) ;appt made by (clerk)
+	. . N BSDXMADE S BSDXMADE=$P(BSDXNOD,U,7) ;date appt made
+	. . N BSDXNOTE S BSDXNOTE=$P(BSDXNOD,U,4) ;'OTHER' field contains note
 	. . S BSDXCNT=BSDXCNT+$$XFER(BSDXRES,BSDXBEG,BSDXPAT,BSDXLEN,BSDXCLRK,BSDXMADE,BSDXNOTE)
 	. . I +BSDXCNT,BSDXCNT#10=0 S ^BSDXTMP("BSDXCOPY",ZTSK)=BSDXCNT_" records copied." ;every 10th record
@@ -85,8 +98,11 @@
 	Q
 	;
-ZTMERR	;
-	TROLLBACK
+ZTMERR	; For now, error from TM is only in trap; not returned to client.
+	N $ET S $ET="D ^%ZTER HALT" ; Emergency Error Trap
+    ; Rollback before logging the error
+    I $TL>0 TROLLBACK
 	D ^%ZTER
-	Q
+    S $EC="" ; Clear Error
+	QUIT
 	;
 XFER(BSDXRES,BSDXBEG,BSDXPAT,BSDXLEN,BSDXCLRK,BSDXMADE,BSDXNOTE)	;EP
@@ -132,4 +148,5 @@
 ERR(BSDXI,BSDXCNT,BSDXERR)	;Error processing
 	S BSDXI=BSDXI+1
+    S BSDXERR=$TR(BSDXERR,"^","~")
 	S ^BSDXTMP($J,BSDXI)=BSDXCNT_"^"_BSDXERR_$C(30)
 	S BSDXI=BSDXI+1
@@ -138,11 +155,13 @@
 	;
 ETRAP	;EP Error trap entry
-	D ^%ZTER
-	I '$D(BSDXI) N BSDXI S BSDXI=999
-	S BSDXI=BSDXI+1
-	D ERR(BSDXI,$G(BSDXCNT),"Routine: BSDX29, Error: "_$G(%ZTERROR))
-	Q
-	;
-CPSTAT(BSDXY,BSDXTSK)	;EP
+	; No Txn here. So don't rollback anything
+    N $ET S $ET="D ^%ZTER HALT" ; Emergency Error Trap
+    D ^%ZTER
+    S $EC="" ; Clear error
+	I '$D(BSDXI) N BSDXI S BSDXI=0
+	D ERR(BSDXI,$G(BSDXCNT),"~100~BSDX29, Error: "_$G(%ZTERZE))
+	Q
+	;
+CPSTAT(BSDXY,BSDXTSK)	;EP - Note: As of Dec 6 2010: Inactive Code
 	;Return status (copied record count) of tasked job having ZTSK=BSDXTSK
 	;
@@ -160,5 +179,5 @@
 	Q
 	;
-CPCANC(BSDXY,BSDXTSK)	;EP
+CPCANC(BSDXY,BSDXTSK)	;EP Note: As of Dec 6 2010: Inactive code.
 	;Signal tasked job having ZTSK=BSDXTSK to cancel
 	;Returns current record count of copy process
Index: /Scheduling/trunk/m/BSDX31.m
===================================================================
--- /Scheduling/trunk/m/BSDX31.m	(revision 1035)
+++ /Scheduling/trunk/m/BSDX31.m	(revision 1036)
@@ -1,151 +1,194 @@
-BSDX31	; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ;
-	;;1.41;BSDX;;Sep 29, 2010
-	;
-	;
-NOSHOWD(BSDXY,BSDXAPTID,BSDXNS)	;EP
-	;Entry point for debugging
-	;
-	;D DEBUG^%Serenji("NOSHOW^BSDX31(.BSDXY,BSDXAPTID,BSDXNS)")
-	Q
-	;
-NOSHOW(BSDXY,BSDXAPTID,BSDXNS)	       ;EP
-	;Called by BSDX NOSHOW
-	;Sets appointment noshow flag in BSDX APPOINTMENT file
-	;BSDXAPTID is entry number in BSDX APPOINTMENT file
-	;BSDXNS = 1: NOSHOW, 0: CANCEL NOSHO
-	;Calls CANCEL^BSDAPI to set noshow data in ^DPT
-	;Returns error code in recordset field ERRORID
-	;
-	N BSDXNOD,BSDXPATID,BSDXSTART,BSDXID,BSDXI,BSDXZ,BSDXERR,BSDXMSG,BSDXFDA,BSDXIENS
-	N BSDXNOEV
-	S BSDXNOEV=1 ;Don't execute protocol
-	;
-	D ^XBKVAR S X="ETRAP^BSDX31",@^%ZOSF("TRAP")
-	S BSDXI=0
-	K ^BSDXTMP($J)
-	S BSDXY="^BSDXTMP("_$J_")"
-	S ^BSDXTMP($J,BSDXI)="I00020ERRORID^T00030ERRORTEXT"_$C(30)
-	S BSDXI=BSDXI+1
-	TSTART
-	I '+BSDXAPTID D ERR(0,"BSDX31: Invalid Appointment ID") Q
-	I '$D(^BSDXAPPT(BSDXAPTID,0)) D ERR(0,"BSDX31: Invalid Appointment ID") Q
-	S BSDXNS=+BSDXNS
-	I BSDXNS'=1&(BSDXNS'=0) D ERR(0,"BSDX31: Invalid No Show value") Q
-	;
-	;Edit BSDX APPOINTMENT entry NOSHOW field
-	S BSDXNOD=^BSDXAPPT(BSDXAPTID,0)
-	I BSDXNOD="" D ERR(0,"BSDX31: Invalid Appointment ID") Q
-	S BSDXPATID=$P(BSDXNOD,U,5)
-	S BSDXSTART=$P(BSDXNOD,U)
-	;
-	D BSDXNOS(BSDXAPTID,BSDXNS)
-	I $D(BSDXMSG("DIERR")) S BSDXMSG=$G(BSDXMSG("DIERR",1,"TEXT",1)) D ERR(0,"BSDX31: "_BSDXMSG) Q
-	;
-	S BSDXSC1=$P(BSDXNOD,U,7) ;RESOURCEID
-	I BSDXSC1]"",$D(^BSDXRES(BSDXSC1,0)) D  I $G(BSDXZ)]"" S BSDXERR="BSDX31: APNOSHO Returned: "_BSDXZ D ERR(0,BSDXERR) Q
-	. S BSDXNOD=^BSDXRES(BSDXSC1,0)
-	. S BSDXSC1=$P(BSDXNOD,U,4) ;HOSPITAL LOCATION
-	. I BSDXSC1]"",$D(^SC(BSDXSC1,0)) D APNOSHO(.BSDXZ,BSDXSC1,BSDXPATID,BSDXSTART,BSDXNS)
-	;
-	TCOMMIT
-	S BSDXI=BSDXI+1
-	S ^BSDXTMP($J,BSDXI)="1^"_$C(30)
-	S BSDXI=BSDXI+1
-	S ^BSDXTMP($J,BSDXI)=$C(31)
-	Q
-	;
-APNOSHO(BSDXZ,BSDXSC1,BSDXDFN,BSDXSD,BSDXNS)	        ;
-	; update file 2 info
-	;Set noshow for patient BSDXDFN in clinic BSDXSC1
-	;at time BSDXSD
-	N BSDXC,%H,BSDXCDT,BSDXIEN
-	N BSDXIENS,BSDXFDA,BSDXMSG
-	S %H=$H D YMD^%DTC
-	S BSDXCDT=X+%
-	;
-	S BSDXIENS=BSDXSD_","_BSDXDFN_","
-	I +BSDXNS D
-	. S BSDXFDA(2.98,BSDXIENS,3)="N"
-	. S BSDXFDA(2.98,BSDXIENS,14)=DUZ
-	. S BSDXFDA(2.98,BSDXIENS,15)=BSDXCDT
-	E  D
-	. S BSDXFDA(2.98,BSDXIENS,3)=""
-	. S BSDXFDA(2.98,BSDXIENS,14)=""
-	. S BSDXFDA(2.98,BSDXIENS,15)=""
-	K BSDXIEN
-	D UPDATE^DIE("","BSDXFDA","BSDXIEN","BSDXMSG")
-	S BSDXZ=$G(BSDXMSG("DIERR",1,"TEXT",1))
-	Q
-	;
-BSDXNOS(BSDXAPTID,BSDXNS)	;
-	;
-	N BSDXFDA,BSDXIENS
-	S BSDXIENS=BSDXAPTID_","
-	S BSDXFDA(9002018.4,BSDXIENS,.1)=BSDXNS ;NOSHOW
-	D FILE^DIE("","BSDXFDA","BSDXMSG")
-	;
-	Q
-	;
-NOSEVT(BSDXPAT,BSDXSTART,BSDXSC)	;EP Called by BSDX NOSHOW APPOINTMENT event
-	;when appointments NOSHOW via PIMS interface.
-	;Propagates NOSHOW to BSDXAPPT and raises refresh event to running GUI clients
-	;
-	Q:+$G(BSDXNOEV)
-	Q:'+$G(BSDXSC)
-	Q:$G(SDATA("AFTER","STATUS"))["AUTO RE-BOOK"
-	N BSDXSTAT,BSDXFOUND,BSDXRES
-	S BSDXSTAT=1
-	S:$G(SDATA("BEFORE","STATUS"))["NO-SHOW" BSDXSTAT=0
-	S BSDXFOUND=0
-	I $D(^BSDXRES("ALOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ALOC",BSDXSC,0)) S BSDXFOUND=$$NOSEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT)
-	I BSDXFOUND D NOSEVT3(BSDXRES) Q
-	I $D(^BXDXRES("ASSOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ASSOC",BSDXSC,0)) S BSDXFOUND=$$NOSEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT)
-	I BSDXFOUND D NOSEVT3(BSDXRES)
-	Q
-	;
-NOSEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT)	;
-	;Get appointment id in BSDXAPT
-	;If found, call BSDXNOS(BSDXAPPT) and return 1
-	;else return 0
-	N BSDXFOUND,BSDXAPPT
-	S BSDXFOUND=0
-	Q:'+$G(BSDXRES) BSDXFOUND
-	Q:'$D(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART)) BSDXFOUND
-	S BSDXAPPT=0 F  S BSDXAPPT=$O(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART,BSDXAPPT)) Q:'+BSDXAPPT  D  Q:BSDXFOUND
-	. S BSDXNOD=$G(^BSDXAPPT(BSDXAPPT,0)) Q:BSDXNOD=""
-	. I $P(BSDXNOD,U,5)=BSDXPAT,$P(BSDXNOD,U,12)="" S BSDXFOUND=1 Q
-	I BSDXFOUND,+$G(BSDXAPPT) D BSDXNOS(BSDXAPPT,BSDXSTAT)
-	Q BSDXFOUND
-	;
-NOSEVT3(BSDXRES)	;
-	;Call RaiseEvent to notify GUI clients
-	;
-	N BSDXRESN
-	S BSDXRESN=$G(^BSDXRES(BSDXRES,0))
-	Q:BSDXRESN=""
-	S BSDXRESN=$P(BSDXRESN,"^")
-	D EVENT^BMXMEVN("BSDX SCHEDULE",BSDXRESN)
-	Q
-	;
-	;
-ERR(BSDXERID,ERRTXT)	;Error processing
-	S:'+$G(BSDXI) BSDXI=999999
-	S BSDXI=BSDXI+1
-	TROLLBACK
-	S ^BSDXTMP($J,BSDXI)=BSDXERID_"^"_ERRTXT_$C(30)
-	S BSDXI=BSDXI+1
-	S ^BSDXTMP($J,BSDXI)=$C(31)
-	Q
-	;
-ETRAP	;EP Error trap entry
-	D ^%ZTER
-	I '$D(BSDXI) N BSDXI S BSDXI=999999
-	S BSDXI=BSDXI+1
-	D ERR(0,"BSDX31 Error: "_$G(%ZTERROR))
-	Q
-	;
-IMHERE(BSDXRES)	;EP
-	;Entry point for BSDX IM HERE remote procedure
-	S BSDXRES=1
-	Q
-	;
+BSDX31  ; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 12/6/10 8:25am
+    ;;1.42;BSDX;;Sep 29, 2010
+    ; Change Log:
+    ; v1.42 Oct 23 2010 WV/SMH
+    ; - Change transaction to restartable. Thanks to Zach Gonzalez
+    ; --> and Rick Marshall for their help.
+    ; v1.42 Dec 6 2010: Extensive refactoring
+    ; 
+    ; Error Reference:
+    ; -1: zero or null Appt ID
+    ; -2: Invalid APPT ID (doesn't exist in ^BSDXAPPT)
+    ; -3: No-show flag is invalid
+    ; -100: M Error
+    ;
+    ;
+NOSHOWD(BSDXY,BSDXAPTID,BSDXNS) ;EP
+    ;Entry point for debugging
+    ;
+    D DEBUG^%Serenji("NOSHOW^BSDX31(.BSDXY,BSDXAPTID,BSDXNS)")
+    Q
+    ;
+UT ; Unit Tests
+    ; Test 1: Sanity Check
+    N ZZZ ; Garbage return variable
+    N DATE S DATE=$$NOW^XLFDT()
+    S DATE=$E(DATE,1,12) ; Just get minutes b/c of HL file input transform
+    D APPADD^BSDX07(.ZZZ,DATE,DATE+.0001,3,"Dr Office",30,"Old Note",1)
+    N APPID S APPID=+$P(^BSDXTMP($J,1),U)
+    D NOSHOW(.ZZZ,APPID,1)
+    I $P(^BSDXAPPT(APPID,0),U,10)'=1 W "ERROR T1",! B
+    I $P(^DPT(3,"S",DATE,0),U,2)'="N" W "ERROR T1",! B
+    ; Test 2: Undo noshow
+    D NOSHOW(.ZZZ,APPID,0)
+    I $P(^BSDXAPPT(APPID,0),U,10)'="0" W "ERROR T2",! B
+    I $P(^DPT(3,"S",DATE,0),U,2)'="" W "ERROR T2",! B
+    ; Test 3: -1
+    D NOSHOW(.ZZZ,"",0)
+    I $P(^BSDXTMP($J,1),U)'=-1 W "ERROR T3",! B
+    ; Test 4: -2
+    D NOSHOW(.ZZZ,2938748233,0)
+    I $P(^BSDXTMP($J,1),U)'=-2 W "ERROR T4",! B
+    QUIT
+NOSHOW(BSDXY,BSDXAPTID,BSDXNS)         ;EP - No show a patient
+    ; Called by RPC: BSDX NOSHOW
+    ; Sets appointment noshow flag in BSDX APPOINTMENT file and "S" node in File 2
+    ;
+    ; Parameters:
+    ; BSDXY: Global Return
+    ; BSDXAPTID is entry number in BSDX APPOINTMENT file
+    ; BSDXNS = 1: NOSHOW, 0: CANCEL NOSHO
+    ; 
+    ; Returns ADO.net record set with fields
+    ; - ERRORID; ERRORTEXT
+    ; ERRORID of 1 is okay
+    ; Anything else is an error.
+    ;
+    ; Return Array; set and clear
+    S BSDXY=$NA(^BSDXTMP($J))
+    K ^BSDXTMP($J)
+    ; $ET
+    N $ET S $ET="G ETRAP^BSDX31"
+    ; Basline vars
+    D ^XBKVAR  ; Set up baseline variables (DUZ, DUZ(2)) if they don't exist
+    ; Counter
+    N BSDXI S BSDXI=0
+    ; Header Node
+    S ^BSDXTMP($J,BSDXI)="I00020ERRORID^T00030ERRORTEXT"_$C(30)
+    ; Begin transaction
+    TSTART (BSDXI,BSDXY,BSDXAPTID,BSDXNS):T="BSDX NOSHOW CANCEL^BSDX29"
+    ; Turn off SDAM APPT PROTOCOL BSDX Entries
+    N BSDXNOEV S BSDXNOEV=1 ;Don't execute protocol
+    ; Appointment ID check
+    I '+BSDXAPTID D ERR(-1,"BSDX31: Invalid Appointment ID") Q
+    I '$D(^BSDXAPPT(BSDXAPTID,0)) D ERR(-2,"BSDX31: Invalid Appointment ID") Q
+    ; Noshow value check - Must be 1 or 0
+    S BSDXNS=+BSDXNS
+    I BSDXNS'=1&(BSDXNS'=0) D ERR(-3,"BSDX31: Invalid No Show value") Q
+    ; Get Some data
+    N BSDXNOD S BSDXNOD=^BSDXAPPT(BSDXAPTID,0) ; Node
+    N BSDXPATID S BSDXPATID=$P(BSDXNOD,U,5) ; DFN
+    N BSDXSTART S BSDXSTART=$P(BSDXNOD,U)  ; Start Date/Time
+    ; Edit BSDX APPOINTMENT entry
+    N BSDXMSG  ; 
+    D BSDXNOS(BSDXAPTID,BSDXNS,.BSDXMSG)  ;Edit BSDX APPOINTMENT entry NOSHOW field 
+    I $D(BSDXMSG("DIERR")) S BSDXMSG=$G(BSDXMSG("DIERR",1,"TEXT",1)) D ERR(-4,"BSDX31: "_BSDXMSG) Q
+    ; Edit File 2 "S" node entry
+    N BSDXZ,BSDXERR ; Error variables to control looping
+    S BSDXSC1=$P(BSDXNOD,U,7) ;RESOURCEID
+    ; If Resource ID exists, and HL exists (means that Resource is linked), No show in File 2
+    I BSDXSC1]"",$D(^BSDXRES(BSDXSC1,0)) D  I $G(BSDXZ)]"" S BSDXERR="BSDX31: APNOSHO Returned: "_BSDXZ D ERR(-5,BSDXERR) Q
+    . S BSDXNOD=^BSDXRES(BSDXSC1,0)
+    . S BSDXSC1=$P(BSDXNOD,U,4) ;HOSPITAL LOCATION
+    . I BSDXSC1]"",$D(^SC(BSDXSC1,0)) D APNOSHO(.BSDXZ,BSDXSC1,BSDXPATID,BSDXSTART,BSDXNS)
+    ;
+    TCOMMIT
+    S BSDXI=BSDXI+1
+    S ^BSDXTMP($J,BSDXI)="1^"_$C(30) ; 1 means everything okay
+    S BSDXI=BSDXI+1
+    S ^BSDXTMP($J,BSDXI)=$C(31)
+    QUIT
+    ;
+APNOSHO(BSDXZ,BSDXSC1,BSDXDFN,BSDXSD,BSDXNS)            ;
+    ; update file 2 info
+    ;Set noshow for patient BSDXDFN in clinic BSDXSC1
+    ;at time BSDXSD
+    N BSDXC,%H,BSDXCDT,BSDXIEN
+    N BSDXIENS,BSDXFDA,BSDXMSG
+    S %H=$H D YMD^%DTC
+    S BSDXCDT=X+%
+    ;
+    S BSDXIENS=BSDXSD_","_BSDXDFN_","
+    I +BSDXNS D
+    . S BSDXFDA(2.98,BSDXIENS,3)="N"
+    . S BSDXFDA(2.98,BSDXIENS,14)=DUZ
+    . S BSDXFDA(2.98,BSDXIENS,15)=BSDXCDT
+    E  D
+    . S BSDXFDA(2.98,BSDXIENS,3)=""
+    . S BSDXFDA(2.98,BSDXIENS,14)=""
+    . S BSDXFDA(2.98,BSDXIENS,15)=""
+    K BSDXIEN
+    D UPDATE^DIE("","BSDXFDA","BSDXIEN","BSDXMSG")
+    S BSDXZ=$G(BSDXMSG("DIERR",1,"TEXT",1))
+    Q
+    ;
+BSDXNOS(BSDXAPTID,BSDXNS,BSDXMSG)   ;
+    ;
+    N BSDXFDA,BSDXIENS
+    S BSDXIENS=BSDXAPTID_","
+    S BSDXFDA(9002018.4,BSDXIENS,.1)=BSDXNS ;NOSHOW
+    D FILE^DIE("","BSDXFDA","BSDXMSG")
+    QUIT
+    ;
+NOSEVT(BSDXPAT,BSDXSTART,BSDXSC)    ;EP Called by BSDX NOSHOW APPOINTMENT event
+    ;when appointments NOSHOW via PIMS interface.
+    ;Propagates NOSHOW to BSDXAPPT and raises refresh event to running GUI clients
+    ;
+    Q:+$G(BSDXNOEV)
+    Q:'+$G(BSDXSC)
+    Q:$G(SDATA("AFTER","STATUS"))["AUTO RE-BOOK"
+    N BSDXSTAT,BSDXFOUND,BSDXRES
+    S BSDXSTAT=1
+    S:$G(SDATA("BEFORE","STATUS"))["NO-SHOW" BSDXSTAT=0
+    S BSDXFOUND=0
+    I $D(^BSDXRES("ALOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ALOC",BSDXSC,0)) S BSDXFOUND=$$NOSEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT)
+    I BSDXFOUND D NOSEVT3(BSDXRES) Q
+    I $D(^BXDXRES("ASSOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ASSOC",BSDXSC,0)) S BSDXFOUND=$$NOSEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT)
+    I BSDXFOUND D NOSEVT3(BSDXRES)
+    Q
+    ;
+NOSEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT) ;
+    ;Get appointment id in BSDXAPT
+    ;If found, call BSDXNOS(BSDXAPPT) and return 1
+    ;else return 0
+    N BSDXFOUND,BSDXAPPT
+    S BSDXFOUND=0
+    Q:'+$G(BSDXRES) BSDXFOUND
+    Q:'$D(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART)) BSDXFOUND
+    S BSDXAPPT=0 F  S BSDXAPPT=$O(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART,BSDXAPPT)) Q:'+BSDXAPPT  D  Q:BSDXFOUND
+    . S BSDXNOD=$G(^BSDXAPPT(BSDXAPPT,0)) Q:BSDXNOD=""
+    . I $P(BSDXNOD,U,5)=BSDXPAT,$P(BSDXNOD,U,12)="" S BSDXFOUND=1 Q
+    I BSDXFOUND,+$G(BSDXAPPT) D BSDXNOS(BSDXAPPT,BSDXSTAT)
+    Q BSDXFOUND
+    ;
+NOSEVT3(BSDXRES)    ;
+    ;Call RaiseEvent to notify GUI clients
+    ;
+    N BSDXRESN
+    S BSDXRESN=$G(^BSDXRES(BSDXRES,0))
+    Q:BSDXRESN=""
+    S BSDXRESN=$P(BSDXRESN,"^")
+    D EVENT^BMXMEVN("BSDX SCHEDULE",BSDXRESN)
+    Q
+    ;
+    ;
+ERR(BSDXERID,ERRTXT)    ;Error processing
+    S BSDXI=BSDXI+1
+    TROLLBACK
+    S ^BSDXTMP($J,BSDXI)=BSDXERID_"^"_ERRTXT_$C(30)
+    S BSDXI=BSDXI+1
+    S ^BSDXTMP($J,BSDXI)=$C(31)
+    Q
+    ;
+ETRAP   ;EP Error trap entry
+    D ^%ZTER
+    I '$D(BSDXI) N BSDXI S BSDXI=999999
+    S BSDXI=BSDXI+1
+    D ERR(0,"BSDX31 Error: "_$G(%ZTERROR))
+    Q
+    ;
+IMHERE(BSDXRES) ;EP
+    ;Entry point for BSDX IM HERE remote procedure
+    S BSDXRES=1
+    Q
+    ;