PSS0088 ;BIR/JLC - CHECK MED ROUTE ABBREVIATIONS ;04/12/2007
 ;;1.0;PHARMACY DATA MANAGEMENT;**88**;9/30/97;Build 12
 ;
 ;
 Q
EN K ZTSAVE,ZTSK,ZTDESC,ZTIO,ZTRTN S ZTRTN="ENQN^PSS0088",ZTDESC="PDM - Check Med Route Abbreviations",ZTIO="" D ^%ZTLOAD
 W !!,"The check for Med Route Abbreviations is",$S($D(ZTSK):"",1:" NOT")," queued",!
 I $D(ZTSK) D
 . W " (to start NOW).",!!,"YOU WILL RECEIVE A MAILMAN MESSAGE WHEN TASK #"_ZTSK_" HAS COMPLETED."
 Q
ENQN N IEN,MRAB,A K PSS,PSS1
 S PSS=6,PSS(6,0)="",PSS1=1,PSS1(1,0)="",IEN=0 F  S IEN=$O(^PS(51.2,IEN)) Q:'IEN  D
 . S A=$G(^PS(51.2,IEN,0)),MRAB=$P(A,"^",3) I $L(PSS(PSS,0))>55 S PSS=PSS+1,PSS(PSS,0)=""
 . I MRAB["IV"!(MRAB["IM")!(MRAB["ID")!(MRAB["SC")!(MRAB["SQ") S PSS(PSS,0)=PSS(PSS,0)_MRAB_", "
 . I $L(PSS1(PSS1,0))>55 S PSS1=PSS1+1,PSS1(PSS1,0)=""
 . I $P(A,"^")="IV PUSH"!(MRAB="IVP") S PSS1(PSS1,0)=PSS1(PSS1,0)_MRAB_", "
SENDMSG ;Send mail message when check is complete.
 N XMDUZ,XMSUB,XMTEXT,XMY,%,Y
 S XMDUZ="MANAGEMENT,PHARMACY DATA",XMSUB="CHECK FOR MED ROUTE ABBREVIATIONS COMPLETE",XMTEXT="PSS(",XMY(DUZ)="" D NOW^%DTC S Y=% X ^DD("DD")
 S PSS(1,0)="  The check of Med Route abbreviations completed as of "_Y_"."
 S PSS(2,0)=" ",PSS(3,0)="The following abbreviations contain IV, ID, IM, SC or SQ. Please update the"
 S PSS(4,0)="Injection Site prompt if appropriate.",PSS(5,0)=" "
 S PSS=PSS+1,PSS(PSS,0)="",PSS=PSS+1,PSS(PSS,0)="The following Med Routes may need to be displayed on the IVP/IVPB tab."
 S PSS=PSS+1,PSS(PSS,0)="Please update the DSPLY ON IVP/IVPB TAB IN BCMA? information appropriately."
 S PSS=PSS+1,PSS(PSS,0)=""
 F I=1:1:PSS1 S PSS=PSS+1,PSS(PSS,0)=PSS1(I,0)
 D ^XMD Q
