GPLMEDS ; CCDCCR/CJE - CCR/CCD PROCESSING FOR MEDICATIONS ;07/23/08  14:33
   ;;0.1;CCDCCR;;JUL 16,2008;
   ;Copyright 2008 WorldVistA.  Licensed under the terms of the GNU
   ;General Public License See attached copy of the License.
   ;
   ;This program is free software; you can redistribute it and/or modify
   ;it under the terms of the GNU General Public License as published by
   ;the Free Software Foundation; either version 2 of the License, or
   ;(at your option) any later version.
   ;
   ;This program is distributed in the hope that it will be useful,
   ;but WITHOUT ANY WARRANTY; without even the implied warranty of
   ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   ;GNU General Public License for more details.
   ;
   ;You should have received a copy of the GNU General Public License along
   ;with this program; if not, write to the Free Software Foundation, Inc.,
   ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
   ;
   W "NO ENTRY FROM TOP",!
   Q
   ;
EXTRACT(MEDXML,DFN,MEDOUTXML) ; EXTRACT MEDICATIONS INTO PROVIDED XML TEMPLATE
   ;
   ; MEDXML AND OUTXML ARE PASSED BY NAME SO GLOBALS CAN BE USED
   ; IMEDXML WILL CONTAIN ONLY THE MEDICATIONS SECTION OF THE OVERALL TEMPLATE
   ;
   N MEDRSLT,I,J,K,MEDPTMP,X,MEDVMAP,TBUF
   D ACTIVE^ORWPS(.MEDRSLT,DFN)
   I '$D(MEDRSLT(1)) D  ; NO MEDS FOR THIS PATIENT, EXIT
   . W "ERROR RUNNINIG MEDICATIONS RPC",!
   . S @MEDOUTXML@(0)=0
   . Q
   I DEBUG ZWR MEDRSLT
   S MEDTVMAP=$NA(^TMP("GPLCCR",$J,"MEDICATIONS"))
   S MEDTARYTMP=$NA(^TMP("GPLCCR",$J,"MEDARYTMP"))
   K @MEDTVMAP,@MEDTARYTMP
   F J=1:3 Q:'$D(MEDRSLT(J))  D  ; FOR EACH MEDICATION IN THE LIST
   . I DEBUG W "J IS ",J,!
   . S MEDVMAP=$NA(@MEDTVMAP@(J))
   . K @MEDVMAP
   . I DEBUG W "VMAP= ",MEDVMAP,!
   . S MEDPTMP=MEDRSLT(J) ; PULL OUT MEDICATION FROM RPC RETURN ARRAY
   . S @MEDVMAP@("MEDICATIONOBJECTID")="MED"_J ; UNIQUE OBJID FOR MEDS
   . ; PROCESSING FOR MEDS GOES HERE
   . S @MEDVMAP@("MEDISSUEDATETXT")=$$FMDTOUTC^CCRUTIL($P(MEDPTMP,"^",11),"DT") ; GETS LAST FILL DATE
   . S @MEDVMAP@("MEDICATIONDATETIMEAGE")=""
   . S @MEDVMAP@("MEDICATIONDATETIMEAGEUNITS")=""
   . S @MEDVMAP@("MEDTYPETEXT")="Medication"
   . S @MEDVMAP@("MEDSTATUSTEXT")=$P(MEDPTMP,"^",10) ; STATUS FROM RPC
   . S @MEDVMAP@("MEDSOURCEACTORID")="ACTORSYSTEM_1"
   . S @MEDVMAP@("MEDPRODUCTNAMETEXT")=$P(MEDPTMP,"^",3)
   . S @MEDVMAP@("MEDICATIONPRODUCTNAMECODEVALUE")=""
   . S @MEDVMAP@("MEDICATIONPRODUCTNAMECODINGINGSYSTEM")=""
   . S @MEDVMAP@("MEDICATIONPRODUCTNAMECODEVERSION")=""
   . S @MEDVMAP@("MEDBRANDNAMETEXT")=""
   . S @MEDVMAP@("MEDICATIONBRANDNAMECODEVALUE")=""
   . S @MEDVMAP@("MEDICATIONBRANDNAMECODINGSYSTEM")=""
   . S @MEDVMAP@("MEDICATIONBRANDNAMECODEVERSION")=""
   . S @MEDVMAP@("MEDSTRENGTHVALUE")=""
   . S @MEDVMAP@("MEDSTRENGTHUNIT")=""
   . S @MEDVMAP@("MEDFORMTEXT")=""
   . S @MEDVMAP@("MEDQUANTITYVALUE")=""
   . S @MEDVMAP@("MEDQUANTITYUNIT")=""
   . S @MEDVMAP@("MEDRFNO")=""
   . I $D(MEDRSLT(J+1)) D  ; IF SECOND LINE EXISTS
   . . S @MEDVMAP@("MEDICATIONDESCRIPTIONTEXT")=$P(MEDRSLT(J+1)," *",2)
   . I $D(MEDRSLT(J+2)) D  ; IF THIRD LINE EXISTS
   . . S @MEDVMAP@("MEDDIRECTIONDESCRIPTIONTEXT")=$P(MEDRSLT(J+2),"\ Sig: ",2)
   . S @MEDVMAP@("MEDICATIONDIRECTIONDOSEVALUE")=""
   . S @MEDVMAP@("MEDICATIONDIRECTIONROUTETEXT")=""
   . S @MEDVMAP@("MEDICATIONDIRECTIONFREQUENCYVALUE")=""
   . S MEDARYTMP=$NA(@MEDTARYTMP@(J))
   . K @MEDARYTMP
   . D MAP^GPLXPATH(MEDXML,MEDVMAP,MEDARYTMP)
   . I J=1 D  ; FIRST ONE IS JUST A COPY
   . . ; W "FIRST ONE",!
   . . D CP^GPLXPATH(MEDARYTMP,MEDOUTXML)
   . I J>1 D  ; AFTER THE FIRST, INSERT INNER XML
   . . D INSINNER^GPLXPATH(MEDOUTXML,MEDARYTMP)
   N MEDTMP,MEDI
   D MISSING^GPLXPATH(MEDOUTXML,"MEDTMP") ; SEARCH XML FOR MISSING VARS
   I MEDTMP(0)>0 D  ; IF THERE ARE MISSING VARS - MARKED AS @@X@@
   . W "MEDICATION MISSING ",!
   . F MEDI=1:1:MEDTMP(0) W MEDTMP(MEDI),!
   Q
   ;
