TIULO1 ; SLC/JER - More embedded Objects ;12-MAY-1999 16:19:39
 ;;1.0;TEXT INTEGRATION UTILITIES;**47**;Jun 20, 1997
VISDATE(TIU) ; Visit date/time
 N TIUX,TIUY
 S TIUX=$S(+$G(TIU("VISIT")):$P($G(TIU("VISIT")),U,2),$L($G(TIU("VSTR"))):$P($G(TIU("VSTR")),";",2),1:"")
 I TIUX']"" S TIUY="VISIT DATE UNKNOWN" G VISDTX
 S TIUY=$$DATE^TIULS(TIUX,"MM/DD/YY HR:MIN")
VISDTX Q $G(TIUY)
LABS(DFN,TIUTEST,TIUEDT,TIULDT) ; Get Lab Results
 N TIUY,TIUTST,TIUX S TIUTST=+$O(^LAB(60,"B",TIUTEST,0))
 I '+$G(TIUTST) G LABX
 D TEST^LR7OR2(.TIUY,DFN,"",$G(TIUEDT),$G(TIULDT),"",TIUTST)
 S TIUX=$S($D(TIUY)#2:$G(@TIUY@(1)),1:"____")
 I $L(TIUX,U)>1 D
 . S TIUTST=$P(TIUX,U,4)_" "_$P(TIUX,U,6)_" "_$P(TIUX,U,5)_"    ("
 . S TIUTST=TIUTST_$$DATE^TIULS($P(TIUX,U),"MM/DD/CCYY HR:MIN")_")"
 E  S TIUTST=TIUX
 I $D(TIUY)#2 K @TIUY
LABX Q $G(TIUTST)
 ;
HPHONE(DFN) ;Current Home Telephone Number
 N VAPA
 D ADD^VADPT
HPHX Q $G(VAPA(8))
 ;
SADD(DFN) ;Single Line Street Address
 N VAPA,J
 D ADD^VADPT
 S:$D(VAPA(1)) J=VAPA(1) S:$D(VAPA(2)) J=J_"  "_VAPA(2) S:$D(VAPA(3)) J=J_"  "_VAPA(3)
SADX Q J
 ;
CISTZI(DFN) ;City, State, Zip
 N VAPA,J
 D ADD^VADPT
 S:$D(VAPA(4)) J=VAPA(4) S:$D(VAPA(5)) J=J_", "_$P(VAPA(5),U,2) S:$D(VAPA(6)) J=J_", "_VAPA(6)
CSTX Q J
 ;