ZIBCLU	; IHS/ADC/GTH - GENERAL PURPOSE CLEAN UP UTILITY GLOBALS - DRIVER TO GET UCI ; [ 02/07/97   3:02 PM ]
	;;4.0;XB;;Jul 20, 2009;Build 2
	;
	;THIS ROUTINE WILL INITIATE A JOB RUNNING ^%ZIBCLU0 IN EACH UCI
	;AND THEN WAIT 5 SECONDS TO ELAPSE BEFORE GETTING THE NEXT UCI
	;SKIP THE UCI THIS TASK IS IN AND THEN RUN ^%ZIBCLU0 HERE
	;  - %ZIBCLU0 WILL REMOVE ALL DANGLING ^UTILITY,^XUTL,^ZUT ENTRIES
	;THIS ROUTINE IS USUALLY STARTED VIA TASKMAN BY SCHEDULING
	;THE -ZIBCLU- OPTION WHICH RUNS THIS ROUTINE
	;
	;DSM ONLY - $ZU(ZIBI) RETURNS <NOUCI> ERROR AT END OF UCI LIST
	;MSM ONLY - $ZU(ZIBI) RETURNS -NULL- VALUE  AT END OF UCI LIST
	;
	W !,*7,"Entry not permitted here!"
	Q
	;
EN	;
	S X="%ZIBCLU0"
	D RCHK^XB
	I $G(XBFAIL) W:'$D(ZTQUEUED) !,"Cannot proceed because ^%ZIBCLU0 is not in MGR" Q
	S $ZT="ZT^ZIBCLU"
	F ZIBI=1:1 S ZIBUCI=$ZU(ZIBI) Q:ZIBUCI=""  I ZIBUCI'=$ZU(0) J ^%ZIBCLU0[ZIBUCI] H 5
	D ^%ZIBCLU0 ; CLEAN UP THIS UCI
ZT	;END OF UCI LIST
	I $ZV?1"DSM".E&($ZE'?1"<NOUCI>".E) D ^%ET
	S $ZT=""
	KILL XBFAIL,ZIBI,ZIBUCI
	Q
	;
