PXRMEVFI	; SLC/PKR - Driver for finding evaluation. ;04/02/2007
	;;2.0;CLINICAL REMINDERS;**6**;Feb 04, 2005;Build 123
	;
	;=====================================================
EVAL(DFN,DEFARR,FIEVAL)	;Evaluate the findings by group using the "E"
	;index.
	N ENODE
	S ENODE=""
	F  S ENODE=$O(DEFARR("E",ENODE)) Q:ENODE=""  D
	. I ENODE="AUTTEDT(" D EVALFI^PXRMEDU(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="AUTTEXAM(" D EVALFI^PXRMEXAM(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="AUTTHF(" D EVALFI^PXRMHF(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="AUTTIMM(" D EVALFI^PXRMIMM(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="AUTTSK(" D EVALFI^PXRMSKIN(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="GMRD(120.51," D EVALFI^PXRMVITL(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="LAB(60," D EVALFI^PXRMLAB(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="ORD(101.43," D EVALFI^PXRMORDR(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="PXD(811.2," D EVALFI^PXRMTAX(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="PXRMD(810.9," D EVALFI^PXRMLOCF(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="PXRMD(811.4," D EVALFI^PXRMCF(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="PXRMD(811.5," D EVALFI^PXRMTERM(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="PS(50.605," D EVALFI^PXRMDRCL(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="PSDRUG(" D EVALFI^PXRMDRUG(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="PSNDF(50.6," D EVALFI^PXRMDGEN(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="RAMIS(71," D EVALFI^PXRMRAD(DFN,.DEFARR,ENODE,.FIEVAL) Q
	. I ENODE="YTT(601.71," D EVALFI^PXRMMH(DFN,.DEFARR,ENODE,.FIEVAL) Q
	;Evaluate function findings.
	D EVAL^PXRMFF(DFN,.DEFARR,.FIEVAL)
	Q
	;
	;=====================================================
EVALPL(DEFARR,FINUM,PLIST)	;Create a patient list for a regular
	;finding.
	N FINDPA,TERMARR
	S FINDPA(0)=DEFARR(20,FINUM,0)
	S FINDPA(3)=DEFARR(20,FINUM,3)
	S FINDPA(10)=DEFARR(20,FINUM,10)
	S FINDPA(11)=DEFARR(20,FINUM,11)
	D GENTERM^PXRMPLST(FINDPA(0),FINUM,.TERMARR)
	D EVALPL^PXRMTERL(.FINDPA,.TERMARR,PLIST)
	Q
	;
