TMGRPC1B ;TMG/kst-RPC Functions ;3/28/10
         ;;1.0;TMG-LIB;**1**;3/28/10
 ;
 ;"TMG RPC FUNCTIONS
 ;
 ;"Copyright Kevin Toppenberg MD
 ;"Released under GNU General Public License (GPL)
 ;"
 ;"=======================================================================
 ;" RPC -- Public Functions.
 ;"=======================================================================
 ;"EVALTIUO
 ;"INSTALL -- Add the RPC's to the OPTION record OR CPRS GUI CHART
 ;"=======================================================================
 ;"PRIVATE API FUNCTIONS
 ;"=======================================================================
 ;"INSTALL1(RPCNAME) -- Add 1 RPC to the OPTION record OR CPRS GUI CHART
 ;
 ;"=======================================================================
 ;"=======================================================================
 ;"Dependencies:
 ;" DIC, TMGDEBUG
 ;"=======================================================================
 ;"=======================================================================
 ;
 ;"OK TO DELETE THIS FUNCTION LATER IF WANTED....
EVALTIUO(TMGY,TMGOBJNM) ;"--- DEPRECIATED.  Will use 'TIU TEMPLATE GETTEXT' RPC instead
        ;"Purpose: To return the resolved text of a TIU Text Object.
        ;"Input: TIUY -- This is output result for RPC caller
        ;"       TMGOBJNM -- This is the name of the TIU TEXT OBJECT to obtain.
        ;"Note: lines wrapped at 200 chars length
        ;"Results : none
        ;
        KILL ^TMG("TMP","TABLE")
        zshow "*":^TMG("TMP","TABLE")
        NEW TMGSTR
        SET TMGOBJNM=$GET(TMGOBJNM)
        IF TMGOBJNM["|" DO  GOTO STOR
        . SET TMGSTR="Passed TEXT OBJECT name should not contain '|' character"
        SET TMGSTR="|"_TMGOBJNM_"|"
        SET TMGSTR=$$BOIL^TIUSRVD(TMGSTR) ;" Execute Boilerplates
        ;
STOR    NEW REF SET REF=$NAME(^TMP("TMG OBJ EVAL",$J))
        NEW IDX SET IDX=0
        KILL @REF
        SET TMGY=REF
        FOR  DO  QUIT:(TMGSTR="")
        . NEW SA,SB
        . SET (SA,SB)=""
        . IF $LENGTH(TMGSTR)>200 DO
        . . SET SB=$EXTRACT(TMGSTR,201,999)
        . . SET TMGSTR=$EXTRACT(TMGSTR,1,200)
        . SET IDX=IDX+1
        . SET @REF@(IDX)=TMGSTR
        . SET TMGSTR=SB
        QUIT
 ;
 ;
INSTALL ;
        ;"Purpose: to add the RPC's to the OPTION record OR CPRS GUI CHART
        DO INSTALL1("TMG EVAL TIU TEXT OBJECT")
        QUIT
 ;
INSTALL1(RPCNAME) ;
        ;"Purpose: to add 1 RPC to the OPTION record OR CPRS GUI CHART
        NEW DIC,X,Y,DA
        SET DIC="^DIC(19,",DIC(0)="M"
        SET X="OR CPRS GUI CHART"
        DO ^DIC
        IF +Y'>0 DO  QUIT
        . WRITE "ERROR.  Unable to find [OR CPRS GUI CHART] in file OPTION (#19)",!
        . NEW TEMP READ "Press [ENTER] to continue...",TEMP:($GET(DTIME,3600))
        . WRITE !
        SET DA(1)=+Y
        SET DIC=DIC_DA(1)_",""RPC"","
        SET DIC(0)="ML" ;"LAYGO --> add entry if not found
        SET X=RPCNAME
        DO ^DIC
        IF +Y'>0 DO
        . WRITE "ERROR.  Unable to add or find "_RPCNAME_" for subfile RPC in record",!
        . WRITE "OR CPRS GUI CHART in file OPTION (#19)",!
        . NEW TEMP READ "Press [ENTER] to continue...",TEMP:($GET(DTIME,3600))
        . WRITE !
        QUIT