Changes between Version 5 and Version 6 of security/electronic_signatures

Timestamp:

Feb 28, 2013, 5:11:46 PM (11 years ago)

Author:

Sam Habiel

Comment:

--

security/electronic_signatures

@@ -326 +326 @@
 }}}
 
+== How to implement ==
+To implement the changes in hashing and encryption, you need to perform conversions while users are offline from the system. The number of conversions you have to perform depends on the number of packages that use these features. In the world outside of the VA, these most likely will be the TIU and Radiology/Nuclear Medicine packages, results in two conversions in addition to that of hashing the electronic signature.
+
+As hashing is a lossy operation, it can only be done once from the plain text. To hash electronic signatures, you need to perform a loop on the new person file like this:
+
+{{{
+NP ; New Person File electronic signature conversion from plain text to hashed.
+ W !,"Hashing electronic signatures",!
+ N DUZ ; Needed for the hashing algorithm
+ N I S I=0 F  S I=$O(^VA(200,I)) Q:'I  D  ; for each NP
+ . N OLDES S OLDES=$P($G(^VA(200,I,20)),U,4) ; Get old signature
+ . Q:'$L(OLDES)  ; quit if it doesn't exist.
+ . W I_" "
+ . S DUZ=I ; DUZ is a hash salt
+ . N X S X=OLDES D HASH^XUSHSHP  ; hash old sig
+ . S $P(^VA(200,I,20),U,4)=X ; store result
+ W !
+ QUIT
+}}}
+
+PLEASE NOTE THAT IF YOU RUN THIS MORE THAN ONCE, YOU WILL NOT BE ABLE TO RETRIEVE BACK THE USER'S ELECTRONIC SIGNATURES.
+
+To convert TIU notes, perform the following:
+{{{
+TIU ; Encrypt Signatures for TIU documents; from plain text to encrypted.
+ W !,"Encrypting Signature Names and Titles in TIU Documents",!
+ K ^TMP($J,"UJOFDA") ; FDA Array
+ N I S I=0 F  S I=$O(^TIU(8925,I)) Q:'I  D  ; for each document
+ . N SB S SB=$G(^(I,15)) ; Get signature block **NAKED**
+ . Q:SB=""
+ . W I_" "
+ . ; We get the following fields:
+ . ; - 1503      SIGNATURE BLOCK NAME (FOX), [15;3]
+ . ; - 1504      SIGNATURE BLOCK TITLE (FOX), [15;4]
+ . ; - 1509      COSIGNATURE BLOCK NAME (FXO), [15;9]
+ . ; - 1510      COSIGNATURE BLOCK TITLE (FXO), [15;10]
+ . N F1503,F1504,F1509,F1510 ; encrypted pieces now in plain text
+ . S F1503=$P(SB,U,3),F1504=$P(SB,U,4),F1509=$P(SB,U,9),F1510=$P(SB,U,10) ; get text values
+ . ;
+ . ; Store in FDA.
+ . S:$L(F1503) ^TMP($J,"UJOFDA",8925,I_",",1503)=F1503
+ . S:$L(F1504) ^TMP($J,"UJOFDA",8925,I_",",1504)=F1504
+ . S:$L(F1509) ^TMP($J,"UJOFDA",8925,I_",",1509)=F1509
+ . S:$L(F1510) ^TMP($J,"UJOFDA",8925,I_",",1510)=F1510
+ ;
+ D CLEAN^DILF ; clean up variables
+ D WAIT^DICD ; Please wait a while
+ D FILE^DIE("ET",$NA(^TMP($J,"UJOFDA"))) ; External Values, Transaction
+ ; ZEXCEPT: DIERR ; Fileman variable cleaned in CLEAN^DILF call
+ I $D(DIERR) W "An error occured",! S $EC=",U1,"
+ W !!
+ QUIT
+}}}
+