1 | BSDXAPI1 ; VEN/SMH - SCHEDULING APIs - Continued!!! ; 6/29/12 11:52am
|
---|
2 | ;;1.7T1;BSDX;;Aug 31, 2011;Build 18
|
---|
3 | ; Licensed under LGPL
|
---|
4 | ;
|
---|
5 | NOSHOW(PAT,CLINIC,DATE,NSFLAG) ; $$ PEP; No-show Patient at appt date (new in v1.7)
|
---|
6 | ; PAT = DFN
|
---|
7 | ; CLINIC = SC IEN
|
---|
8 | ; DATE = FM Date/Time of Appointment
|
---|
9 | ; NSFLAG = truthy value to add no-show, or falsy to remove (use 1 or 0 pls!)
|
---|
10 | ; 1^error for failure, 0 for success
|
---|
11 | ; Code follows EN1^SDN
|
---|
12 | ;
|
---|
13 | ; Check for failure conditions first before doing this. No globals set here
|
---|
14 | N NOSHOWCK S NOSHOWCK=$$NOSHOWCK(PAT,CLINIC,DATE,NSFLAG)
|
---|
15 | I NOSHOWCK Q NOSHOWCK
|
---|
16 | ;
|
---|
17 | ; Set up Protocol Driver
|
---|
18 | N SDNSHDL,SDDA S SDNSHDL=$$HANDLE^SDAMEVT(1) S SDDA=$$SCIEN^BSDXAPI(PAT,CLINIC,DATE)
|
---|
19 | N SDATA
|
---|
20 | D BEFORE^SDAMEVT(.SDATA,PAT,DATE,CLINIC,SDDA,SDNSHDL) ; Only ^TMP set here.
|
---|
21 | ;
|
---|
22 | ; Simulated Errors
|
---|
23 | Q:$D(BSDXSIMERR2) 1_U_"Simulated Error"
|
---|
24 | ;
|
---|
25 | ; Edit the ^DPT( "S" node entry - Noshow or undo noshow
|
---|
26 | ; Failure analysis: if we fail here, we presume no change happened in
|
---|
27 | ; ^DPT(DA,"S", and so we just have to roll back ^BSDXAPPT
|
---|
28 | N BSDXIENS S BSDXIENS=DATE_","_PAT_","
|
---|
29 | N BSDXFDA
|
---|
30 | I +NSFLAG D
|
---|
31 | . S BSDXFDA(2.98,BSDXIENS,3)="N"
|
---|
32 | . S BSDXFDA(2.98,BSDXIENS,14)=DUZ
|
---|
33 | . S BSDXFDA(2.98,BSDXIENS,15)=$$NOW^XLFDT()
|
---|
34 | E D
|
---|
35 | . S BSDXFDA(2.98,BSDXIENS,3)="@"
|
---|
36 | . S BSDXFDA(2.98,BSDXIENS,14)="@"
|
---|
37 | . S BSDXFDA(2.98,BSDXIENS,15)="@"
|
---|
38 | N BSDXMSG
|
---|
39 | D FILE^DIE("","BSDXFDA","BSDXMSG")
|
---|
40 | Q:$D(BSDXMSG) 1_U_"Fileman edit to DPT error: Patient="_PAT_" Appt="_DATE_" Error="_BSDXMSG("DIERR",1,"TEXT",1)
|
---|
41 | ;
|
---|
42 | ; This M error trigger tests if ^BSDXAPPT rolls back.
|
---|
43 | ; I won't try to roll back ^DPT(,"S"
|
---|
44 | ; The M error is caused here, so if I try to rollback, I can cause another
|
---|
45 | ; error. Infinite Errors then.
|
---|
46 | I $D(BSDXSIMERR3) N X S X=1/0
|
---|
47 | ;
|
---|
48 | ; Run the event driver
|
---|
49 | D NOSHOW^SDAMEVT(.SDATA,PAT,DATE,CLINIC,SDDA,0,SDNSHDL)
|
---|
50 | Q 0
|
---|
51 | ;
|
---|
52 | NOSHOWCK(PAT,CLINIC,DATE,NSFLAG) ; $$ PEP; No-show Check
|
---|
53 | ; TODO: Not all appointments can be no showed.
|
---|
54 | ; Check the code in SDAMN
|
---|
55 | ; S SDSTB=$$STATUS^SDAM1(DFN,SDT,SDCL,$G(^DPT(DFN,"S",SDT,0))) ; before status
|
---|
56 | ; Q:'$$CHK ; Checks $D(^SD(409.63,"ANS",1,+SDSTB))
|
---|
57 | QUIT 0
|
---|
58 | ;
|
---|
59 | RMCI(PAT,CLINIC,DATE) ;PEP; -- Remove Check-in; $$
|
---|
60 | ; PAT = DFN
|
---|
61 | ; CLINIC = SC IEN
|
---|
62 | ; DATE = FM Date/Time of Appointment
|
---|
63 | ;
|
---|
64 | ; Returns:
|
---|
65 | ; 0 if okay
|
---|
66 | ; -1 if failure
|
---|
67 | ;
|
---|
68 | ; Call like this: $$RMCI(233,33,3110102.1130)
|
---|
69 | ;
|
---|
70 | ; Move my variables into the ones used by SDAPIs (just a convenience)
|
---|
71 | NEW SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL,SDMODE
|
---|
72 | S DFN=PAT,SDT=DATE,SDCL=CLINIC,SDMODE=2,SDDA=$$SCIEN^BSDXAPI(DFN,SDCL,SDT)
|
---|
73 | ;
|
---|
74 | I SDDA<1 QUIT 0 ; Appt cancelled; cancelled appts rm'ed from file 44
|
---|
75 | ;
|
---|
76 | ; remember before status
|
---|
77 | S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
|
---|
78 | D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
|
---|
79 | ;
|
---|
80 | ; remove check-in using filer.
|
---|
81 | N BSDXIENS S BSDXIENS=SDDA_","_DATE_","_CLINIC_","
|
---|
82 | N BSDXFDA
|
---|
83 | S BSDXFDA(44.003,BSDXIENS,309)="@" ; CHECKED-IN
|
---|
84 | S BSDXFDA(44.003,BSDXIENS,302)="@" ; CHECK IN USER
|
---|
85 | S BSDXFDA(44.003,BSDXIENS,305)="@" ; CHECK IN ENTERED
|
---|
86 | N BSDXERR
|
---|
87 | D FILE^DIE("","BSDXFDA","BSDXERR")
|
---|
88 | I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
|
---|
89 | ;
|
---|
90 | ; set after status
|
---|
91 | ; S SDDA=$$SCIEN(DFN,SDCL,SDT) ;smh -why is this here? SDDA won't change.
|
---|
92 | S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
|
---|
93 | D AFTER^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
|
---|
94 | ;
|
---|
95 | ; call event driver
|
---|
96 | D EVT^SDAMEVT(.SDATA,4,SDMODE,SDCIHDL)
|
---|
97 | QUIT 0
|
---|
98 | ;
|
---|
99 | UPDATENT(PAT,CLINIC,DATE,NOTE) ; PEP; Update Note in ^SC for patient's appointment @ DATE
|
---|
100 | ; PAT = DFN
|
---|
101 | ; CLINIC = SC IEN
|
---|
102 | ; DATE = FM Date/Time of Appointment
|
---|
103 | ;
|
---|
104 | ; Returns:
|
---|
105 | ; 0 if okay
|
---|
106 | ; -1 if failure
|
---|
107 | ;
|
---|
108 | ; ERROR SIMULATION
|
---|
109 | I $G(BSDXSIMERR1) QUIT "-1~Simulated Error"
|
---|
110 | ;
|
---|
111 | N SCIEN S SCIEN=$$SCIEN^BSDXAPI(PAT,CLINIC,DATE) ; ien of appt in ^SC
|
---|
112 | I SCIEN<1 QUIT 0 ; Appt cancelled; cancelled appts rm'ed from file 44
|
---|
113 | N BSDXIENS S BSDXIENS=SCIEN_","_DATE_","_CLINIC_","
|
---|
114 | N BSDXFDA S BSDXFDA(44.003,BSDXIENS,3)=$E(NOTE,1,150)
|
---|
115 | N BSDXERR
|
---|
116 | D FILE^DIE("","BSDXFDA","BSDXERR")
|
---|
117 | I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
|
---|
118 | QUIT 0
|
---|
119 | ;
|
---|