Changeset 1464 for Scheduling/trunk/m/BSDXAPI1.m

Timestamp:

Jun 29, 2012, 7:09:55 PM (12 years ago)

Author:

Sam Habiel

Message:

BSDX25 refactoring, continued

File:

• Scheduling/trunk/m/BSDXAPI1.m (modified) (2 diffs)

Scheduling/trunk/m/BSDXAPI1.m

@@ -1 @@
-BSDXAPI1 ; VEN/SMH - SCHEDULING APIs - Continued!!! ; 6/27/12 4:45pm
+BSDXAPI1 ; VEN/SMH - SCHEDULING APIs - Continued!!! ; 6/29/12 11:52am
         ;;1.7T1;BSDX;;Aug 31, 2011;Build 18
         ; Licensed under LGPL  
@@ -56 +56 @@
         ; Q:'$$CHK ; Checks $D(^SD(409.63,"ANS",1,+SDSTB))
         QUIT 0
+        ;
+RMCI(PAT,CLINIC,DATE)    ;PEP; -- Remove Check-in; $$
+        ; PAT = DFN
+        ; CLINIC = SC IEN
+        ; DATE = FM Date/Time of Appointment
+        ;
+        ; Returns:
+        ; 0 if okay
+        ; -1 if failure
+        ;
+        ; Call like this: $$RMCI(233,33,3110102.1130)
+        ;
+        ; Move my variables into the ones used by SDAPIs (just a convenience)
+        NEW SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL,SDMODE
+        S DFN=PAT,SDT=DATE,SDCL=CLINIC,SDMODE=2,SDDA=$$SCIEN^BSDXAPI(DFN,SDCL,SDT)
+        ;
+        I SDDA<1 QUIT 0    ; Appt cancelled; cancelled appts rm'ed from file 44
+        ;
+        ; remember before status
+        S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
+        D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
+        ;
+        ; remove check-in using filer.
+        N BSDXIENS S BSDXIENS=SDDA_","_DATE_","_CLINIC_","
+        N BSDXFDA
+        S BSDXFDA(44.003,BSDXIENS,309)="@" ; CHECKED-IN
+        S BSDXFDA(44.003,BSDXIENS,302)="@" ; CHECK IN USER
+        S BSDXFDA(44.003,BSDXIENS,305)="@" ; CHECK IN ENTERED
+        N BSDXERR
+        D FILE^DIE("","BSDXFDA","BSDXERR")
+        I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
+        ;
+        ; set after status
+        ; S SDDA=$$SCIEN(DFN,SDCL,SDT) ;smh -why is this here? SDDA won't change.
+        S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
+        D AFTER^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
+        ;
+        ; call event driver
+        D EVT^SDAMEVT(.SDATA,4,SDMODE,SDCIHDL)
+        QUIT 0
+        ;
+UPDATENT(PAT,CLINIC,DATE,NOTE)  ; PEP; Update Note in ^SC for patient's appointment @ DATE
+        ; PAT = DFN
+        ; CLINIC = SC IEN
+        ; DATE = FM Date/Time of Appointment
+        ;
+        ; Returns:
+        ; 0 if okay
+        ; -1 if failure
+        ;
+        ; ERROR SIMULATION
+        I $G(BSDXSIMERR1) QUIT "-1~Simulated Error"
+        ;
+        N SCIEN S SCIEN=$$SCIEN^BSDXAPI(PAT,CLINIC,DATE) ; ien of appt in ^SC
+        I SCIEN<1 QUIT 0    ; Appt cancelled; cancelled appts rm'ed from file 44
+        N BSDXIENS S BSDXIENS=SCIEN_","_DATE_","_CLINIC_","
+        N BSDXFDA S BSDXFDA(44.003,BSDXIENS,3)=$E(NOTE,1,150)
+        N BSDXERR
+        D FILE^DIE("","BSDXFDA","BSDXERR")
+        I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
+        QUIT 0
+        ;