source: ccr/trunk/p/GPLCCR.m@ 151

Last change on this file since 151 was 151, checked in by George Lilly, 16 years ago

added Alerts to CCR processing on a switch - TESTALERTS=1 ;also ZTESTGPLCCR("ALERTS")
File size: 9.2 KB
Line 
1GPLCCR ; CCDCCR/GPL - CCR MAIN PROCESSING; 6/6/08
2 ;;0.1;CCDCCR;nopatch;noreleasedate
3 ;Copyright 2008 WorldVistA. Licensed under the terms of the GNU
4 ;General Public License See attached copy of the License.
5 ;
6 ;This program is free software; you can redistribute it and/or modify
7 ;it under the terms of the GNU General Public License as published by
8 ;the Free Software Foundation; either version 2 of the License, or
9 ;(at your option) any later version.
10 ;
11 ;This program is distributed in the hope that it will be useful,
12 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 ;GNU General Public License for more details.
15 ;
16 ;You should have received a copy of the GNU General Public License along
17 ;with this program; if not, write to the Free Software Foundation, Inc.,
18 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
19 ;
20 ; EXPORT A CCR
21 ;
22EXPORT ; EXPORT ENTRY POINT FOR CCR
23 ; Select a patient.
24 S DIC=2,DIC(0)="AEMQ" D ^DIC
25 I Y<1 Q ; EXIT
26 S DFN=$P(Y,U,1) ; SET THE PATIENT
27 D XPAT(DFN,"","") ; EXPORT TO A FILE
28 Q
29 ;
30XPAT(DFN,DIR,FN) ; EXPORT ONE PATIENT TO A FILE
31 ; DIR IS THE DIRECTORY, DEFAULTS IF NULL TO ^TMP("GPLCCR","ODIR")
32 ; FN IS FILE NAME, DEFAULTS IF NULL
33 N CCRGLO
34 D CCRRPC(.CCRGLO,DFN,"CCR","","","")
35 S OARY=$NA(^TMP("GPLCCR",$J,DFN,"CCR",1))
36 S ONAM=FN
37 I FN="" S ONAM="PAT_"_DFN_"_CCR_V1.xml"
38 S ODIRGLB=$NA(^TMP("GPLCCR","ODIR"))
39 I '$D(@ODIRGLB) D ; IF NOT ODIR HAS BEEN SET
40 . ;S @ODIRGLB="/home/glilly/CCROUT"
41 . ;S @ODIRGLB="/home/cedwards/"
42 . S @ODIRGLB="/opt/wv/p/"
43 S ODIR=DIR
44 I DIR="" S ODIR=@ODIRGLB
45 N ZY
46 S ZY=$$OUTPUT^GPLXPATH(OARY,ONAM,ODIR)
47 W !,$P(ZY,U,2),!
48 Q
49 ;
50DCCR(DFN) ; DISPLAY A CCR THAT HAS JUST BEEN EXTRACTED
51 ;
52 N G1
53 S G1=$NA(^TMP("GPLCCR",$J,DFN,"CCR"))
54 I $D(@G1@(0)) D ; CCR EXISTS
55 . D PARY^GPLXPATH(G1)
56 E W "CCR NOT CREATED, RUN D XPAT^GPLCCR(DFN,"""","""") FIRST",!
57 Q
58 ;
59CCRRPC(CCRGRTN,DFN,CCRPART,TIME1,TIME2,HDRARY) ;RPC ENTRY POINT FOR CCR OUTPUT
60 ; CCRGRTN IS RETURN ARRAY PASSED BY NAME
61 ; DFN IS PATIENT IEN
62 ; CCRPART IS "CCR" FOR ENTIRE CCR, OR SECTION NAME FOR A PART
63 ; OF THE CCR BODY.. PARTS INCLUDE "PROBLEMS" "VITALS" ETC
64 ; TIME1 IS STARTING TIME TO INCLUDE - NULL MEANS ALL
65 ; TIME2 IS ENDING TIME TO INCLUDE TIME IS FILEMAN TIME
66 ; - NULL MEANS NOW
67 ; HDRARY IS THE HEADER ARRAY DEFINING THE "FROM" AND
68 ; "TO" VARIABLES
69 ; IF NULL WILL DEFAULT TO "FROM" DUZ AND "TO" DFN
70 I '$D(DEBUG) S DEBUG=0
71 S CCD=0 ; NEED THIS FLAG TO DISTINGUISH FROM CCD
72 I '$D(TESTLAB) S TESTLAB=0 ; FLAG FOR TESTING RESULTS SECTION
73 I '$D(TESTALERT) S TESTALERT=0 ; FLAG FOR TESTING ALERTS SECTION
74 S TGLOBAL=$NA(^TMP("GPLCCR",$J,"TEMPLATE")) ; GLOBAL FOR STORING TEMPLATE
75 S CCRGLO=$NA(^TMP("GPLCCR",$J,DFN,"CCR")) ; GLOBAL FOR BUILDING THE CCR
76 S ACTGLO=$NA(^TMP("GPLCCR",$J,DFN,"ACTORS")) ; GLOBAL FOR ALL ACTORS
77 ; TO GET PART OF THE CCR RETURNED, PASS CCRPART="PROBLEMS" ETC
78 S CCRGRTN=$NA(^TMP("GPLCCR",$J,DFN,CCRPART)) ; RTN GLO NM OF PART OR ALL
79 D LOAD^GPLCCR0(TGLOBAL) ; LOAD THE CCR TEMPLATE
80 D CP^GPLXPATH(TGLOBAL,CCRGLO) ; COPY THE TEMPLATE TO CCR GLOBAL
81 ;
82 ; DELETE THE BODY, ACTORS AND SIGNATURES SECTIONS FROM GLOBAL
83 ; THESE WILL BE POPULATED AFTER CALLS TO THE XPATH ROUTINES
84 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Body")
85 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Actors")
86 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Signatures")
87 I DEBUG F I=1:1:@CCRGLO@(0) W @CCRGLO@(I),!
88 ;
89 D HDRMAP(CCRGLO,DFN,HDRARY) ; MAP HEADER VARIABLES
90 ;
91 K ^TMP("GPLCCR",$J,"CCRSTEP") ; KILL GLOBAL PRIOR TO ADDING TO IT
92 S CCRXTAB=$NA(^TMP("GPLCCR",$J,"CCRSTEP")) ; GLOBAL TO STORE CCR STEPS
93 D INITSTPS(CCRXTAB) ; INITIALIZED CCR PROCESSING STEPS
94 N PROCI,XI,TAG,RTN,CALL,XPATH,IXML,OXML,INXML,CCRBLD
95 F PROCI=1:1:@CCRXTAB@(0) D ; PROCESS THE CCR BODY SECTIONS
96 . S XI=@CCRXTAB@(PROCI) ; CALL COPONENTS TO PARSE
97 . S RTN=$P(XI,";",2) ; NAME OF ROUTINE TO CALL
98 . S TAG=$P(XI,";",1) ; LABEL INSIDE ROUTINE TO CALL
99 . S XPATH=$P(XI,";",3) ; XPATH TO XML TO PASS TO ROUTINE
100 . D QUERY^GPLXPATH(TGLOBAL,XPATH,"INXML") ; EXTRACT XML TO PASS
101 . S IXML="INXML"
102 . S OXML=$P(XI,";",4) ; ARRAY FOR SECTION VALUES
103 . ; K @OXML ; KILL EXPECTED OUTPUT ARRAY
104 . ; W OXML,!
105 . S CALL="D "_TAG_"^"_RTN_"(IXML,DFN,OXML)" ; SETUP THE CALL
106 . I DEBUG W "RUNNING ",CALL,!
107 . X CALL
108 . ; NOW INSERT THE RESULTS IN THE CCR BUFFER
109 . I @OXML@(0)'=0 D ; THERE IS A RESULT
110 . . D INSERT^GPLXPATH(CCRGLO,OXML,"//ContinuityOfCareRecord/Body")
111 . . I DEBUG F GPLI=1:1:@OXML@(0) W @OXML@(GPLI),!
112 D ACTLST^GPLCCR(CCRGLO,ACTGLO) ; GEN THE ACTOR LIST
113 D QUERY^GPLXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","ACTT")
114 D EXTRACT^GPLACTOR("ACTT",ACTGLO,"ACTT2")
115 D INSINNER^GPLXPATH(CCRGLO,"ACTT2","//ContinuityOfCareRecord/Actors")
116 N TRIMI,J,DONE S DONE=0
117 F TRIMI=0:0 D Q:DONE ; DELETE UNTIL ALL EMPTY ELEMENTS ARE GONE
118 . S J=$$TRIM^GPLXPATH(CCRGLO) ; DELETE EMPTY ELEMENTS
119 . I DEBUG W "TRIMMED",J,!
120 . I J=0 S DONE=1 ; DONE WHEN TRIM RETURNS FALSE
121 Q
122 ;
123INITSTPS(TAB) ; INITIALIZE CCR PROCESSING STEPS
124 ; TAB IS PASSED BY NAME
125 I DEBUG W "TAB= ",TAB,!
126 ; ORDER FOR CCR IS PROBLEMS,FAMILYHISTORY,SOCIALHISTORY,MEDICATIONS,VITALSIGNS,RESULTS,HEALTHCAREPROVIDERS
127 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLPROBS;//ContinuityOfCareRecord/Body/Problems;^TMP(""GPLCCR"",$J,DFN,""PROBLEMS"")")
128 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLMEDS;//ContinuityOfCareRecord/Body/Medications;^TMP(""GPLCCR"",$J,DFN,""MEDICATIONS"")")
129 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLVITAL;//ContinuityOfCareRecord/Body/VitalSigns;^TMP(""GPLCCR"",$J,DFN,""VITALS"")")
130 I TESTLAB D PUSH^GPLXPATH(TAB,"EXTRACT;GPLLABS;//ContinuityOfCareRecord/Body/Results;^TMP(""GPLCCR"",$J,DFN,""RESULTS"")")
131 I TESTALERT D PUSH^GPLXPATH(TAB,"EXTRACT;GPLALERT;//ContinuityOfCareRecord/Body/Alerts;^TMP(""GPLCCR"",$J,DFN,""ALERTS"")")
132 Q
133 ;
134HDRMAP(CXML,DFN,IHDR) ; MAP HEADER VARIABLES: FROM, TO ECT
135 N VMAP S VMAP=$NA(^TMP("GPLCCR",$J,DFN,"HEADER"))
136 ; K @VMAP
137 S @VMAP@("DATETIME")=$$FMDTOUTC^CCRUTIL($$NOW^XLFDT,"DT")
138 I IHDR="" D ; HEADER ARRAY IS NOT PROVIDED, USE DEFAULTS
139 . S @VMAP@("ACTORPATIENT")="ACTORPATIENT_"_DFN
140 . S @VMAP@("ACTORFROM")="ACTORORGANIZATION_"_DUZ ; FROM DUZ - ???
141 . S @VMAP@("ACTORFROM2")="ACTORSYSTEM_1" ; SECOND FROM IS THE SYSTEM
142 . S @VMAP@("ACTORTO")="ACTORPATIENT_"_DFN ; FOR TEST PURPOSES
143 . S @VMAP@("PURPOSEDESCRIPTION")="CEND PHR" ; FOR TEST PURPOSES
144 . S @VMAP@("ACTORTOTEXT")="Patient" ; FOR TEST PURPOSES
145 . ; THIS IS THE USE CASE FOR THE PHR WHERE "TO" IS THE PATIENT
146 I IHDR'="" D ; HEADER VALUES ARE PROVIDED
147 . D CP^GPLXPATH(IHDR,VMAP) ; COPY HEADER VARIABLES TO MAP ARRAY
148 N CTMP
149 D MAP^GPLXPATH(CXML,VMAP,"CTMP")
150 D CP^GPLXPATH("CTMP",CXML)
151 Q
152 ;
153ACTLST(AXML,ACTRTN) ; RETURN THE ACTOR LIST FOR THE XML IN AXML
154 ; AXML AND ACTRTN ARE PASSED BY NAME
155 ; EACH ACTOR RECORD HAS 3 PARTS - IE IF OBJECTID=ACTORPATIENT_2
156 ; P1= OBJECTID - ACTORPATIENT_2
157 ; P2= OBJECT TYPE - PATIENT OR PROVIDER OR SOFTWARE
158 ;OR INSTITUTION
159 ; OR PERSON(IN PATIENT FILE IE NOK)
160 ; P3= IEN RECORD NUMBER FOR ACTOR - 2
161 N I,J,K,L
162 K @ACTRTN ; CLEAR RETURN ARRAY
163 F I=1:1:@AXML@(0) D ; SCAN ALL LINES
164 . I @AXML@(I)?.E1"<ActorID>".E D ; THERE IS AN ACTOR THIS LINE
165 . . S J=$P($P(@AXML@(I),"<ActorID>",2),"</ActorID>",1)
166 . . I DEBUG W "<ActorID>=>",J,!
167 . . I J'="" S K(J)="" ; HASHING ACTOR
168 . . ; TO GET RID OF DUPLICATES
169 S I="" ; GOING TO $O THROUGH THE HASH
170 F J=0:0 D Q:$O(K(I))=""
171 . S I=$O(K(I)) ; WALK THROUGH THE HASH OF ACTORS
172 . S $P(L,U,1)=I ; FIRST PIECE IS THE OBJECT ID
173 . S $P(L,U,2)=$P($P(I,"ACTOR",2),"_",1) ; ACTOR TYPE
174 . S $P(L,U,3)=$P(I,"_",2) ; IEN RECORD NUMBER FOR ACTOR
175 . D PUSH^GPLXPATH(ACTRTN,L) ; ADD THE ACTOR TO THE RETURN ARRAY
176 Q
177 ;
178TEST ; RUN ALL THE TEST CASES
179 D TESTALL^GPLUNIT("GPLCCR")
180 Q
181 ;
182ZTEST(WHICH) ; RUN ONE SET OF TESTS
183 N ZTMP
184 D ZLOAD^GPLUNIT("ZTMP","GPLCCR")
185 D ZTEST^GPLUNIT(.ZTMP,WHICH)
186 Q
187 ;
188TLIST ; LIST THE TESTS
189 N ZTMP
190 D ZLOAD^GPLUNIT("ZTMP","GPLCCR")
191 D TLIST^GPLUNIT(.ZTMP)
192 Q
193 ;
194 ;;><TEST>
195 ;;><PROBLEMS>
196 ;;>>>K GPL S GPL=""
197 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","PROBLEMS","","","")
198 ;;>>?@GPL@(@GPL@(0))["</Problems>"
199 ;;><VITALS>
200 ;;>>>K GPL S GPL=""
201 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","VITALS","","","")
202 ;;>>?@GPL@(@GPL@(0))["</VitalSigns>"
203 ;;><CCR>
204 ;;>>>K GPL S GPL=""
205 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCR","","","")
206 ;;>>?@GPL@(@GPL@(0))["</ContinuityOfCareRecord>"
207 ;;><ACTLST>
208 ;;>>>K GPL S GPL=""
209 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCR","","","")
210 ;;>>>D ACTLST^GPLCCR(GPL,"ACTTEST")
211 ;;><ACTORS>
212 ;;>>>D ZTEST^GPLCCR("ACTLST")
213 ;;>>>D QUERY^GPLXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","G2")
214 ;;>>>D EXTRACT^GPLACTOR("G2","ACTTEST","G3")
215 ;;>>?G3(G3(0))["</Actors>"
216 ;;><TRIM>
217 ;;>>>D ZTEST^GPLCCR("CCR")
218 ;;>>>W $$TRIM^GPLXPATH(CCRGLO)
219 ;;><ALERTS>
220 ;;>>>S TESTALERT=1
221 ;;>>>K GPL S GPL=""
222 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","ALERTS","","","")
223 ;;>>?@GPL@(@GPL@(0))["</Alerts>"
224
Note: See TracBrowser for help on using the repository browser.