source: ccr/trunk/p/GPLCCR.m@ 157

Last change on this file since 157 was 157, checked in by George Lilly, 16 years ago

fixed XPATGPLCCR so it defaults last two parameters D XPATGPLCCR(dfn) works
File size: 9.3 KB
Line 
1GPLCCR ; CCDCCR/GPL - CCR MAIN PROCESSING; 6/6/08
2 ;;0.1;CCDCCR;nopatch;noreleasedate
3 ;Copyright 2008 WorldVistA. Licensed under the terms of the GNU
4 ;General Public License See attached copy of the License.
5 ;
6 ;This program is free software; you can redistribute it and/or modify
7 ;it under the terms of the GNU General Public License as published by
8 ;the Free Software Foundation; either version 2 of the License, or
9 ;(at your option) any later version.
10 ;
11 ;This program is distributed in the hope that it will be useful,
12 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 ;GNU General Public License for more details.
15 ;
16 ;You should have received a copy of the GNU General Public License along
17 ;with this program; if not, write to the Free Software Foundation, Inc.,
18 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
19 ;
20 ; EXPORT A CCR
21 ;
22EXPORT ; EXPORT ENTRY POINT FOR CCR
23 ; Select a patient.
24 S DIC=2,DIC(0)="AEMQ" D ^DIC
25 I Y<1 Q ; EXIT
26 S DFN=$P(Y,U,1) ; SET THE PATIENT
27 D XPAT(DFN,"","") ; EXPORT TO A FILE
28 Q
29 ;
30XPAT(DFN,DIR,FN) ; EXPORT ONE PATIENT TO A FILE
31 ; DIR IS THE DIRECTORY, DEFAULTS IF NULL TO ^TMP("GPLCCR","ODIR")
32 ; FN IS FILE NAME, DEFAULTS IF NULL
33 N CCRGLO
34 I '$D(DIR) S DIR=""
35 I '$D(FN) S FN=""
36 D CCRRPC(.CCRGLO,DFN,"CCR","","","")
37 S OARY=$NA(^TMP("GPLCCR",$J,DFN,"CCR",1))
38 S ONAM=FN
39 I FN="" S ONAM="PAT_"_DFN_"_CCR_V1.xml"
40 S ODIRGLB=$NA(^TMP("GPLCCR","ODIR"))
41 I '$D(@ODIRGLB) D ; IF NOT ODIR HAS BEEN SET
42 . ;S @ODIRGLB="/home/glilly/CCROUT"
43 . ;S @ODIRGLB="/home/cedwards/"
44 . S @ODIRGLB="/opt/wv/p/"
45 S ODIR=DIR
46 I DIR="" S ODIR=@ODIRGLB
47 N ZY
48 S ZY=$$OUTPUT^GPLXPATH(OARY,ONAM,ODIR)
49 W !,$P(ZY,U,2),!
50 Q
51 ;
52DCCR(DFN) ; DISPLAY A CCR THAT HAS JUST BEEN EXTRACTED
53 ;
54 N G1
55 S G1=$NA(^TMP("GPLCCR",$J,DFN,"CCR"))
56 I $D(@G1@(0)) D ; CCR EXISTS
57 . D PARY^GPLXPATH(G1)
58 E W "CCR NOT CREATED, RUN D XPAT^GPLCCR(DFN,"""","""") FIRST",!
59 Q
60 ;
61CCRRPC(CCRGRTN,DFN,CCRPART,TIME1,TIME2,HDRARY) ;RPC ENTRY POINT FOR CCR OUTPUT
62 ; CCRGRTN IS RETURN ARRAY PASSED BY NAME
63 ; DFN IS PATIENT IEN
64 ; CCRPART IS "CCR" FOR ENTIRE CCR, OR SECTION NAME FOR A PART
65 ; OF THE CCR BODY.. PARTS INCLUDE "PROBLEMS" "VITALS" ETC
66 ; TIME1 IS STARTING TIME TO INCLUDE - NULL MEANS ALL
67 ; TIME2 IS ENDING TIME TO INCLUDE TIME IS FILEMAN TIME
68 ; - NULL MEANS NOW
69 ; HDRARY IS THE HEADER ARRAY DEFINING THE "FROM" AND
70 ; "TO" VARIABLES
71 ; IF NULL WILL DEFAULT TO "FROM" DUZ AND "TO" DFN
72 I '$D(DEBUG) S DEBUG=0
73 S CCD=0 ; NEED THIS FLAG TO DISTINGUISH FROM CCD
74 I '$D(TESTLAB) S TESTLAB=0 ; FLAG FOR TESTING RESULTS SECTION
75 I '$D(TESTALERT) S TESTALERT=0 ; FLAG FOR TESTING ALERTS SECTION
76 S TGLOBAL=$NA(^TMP("GPLCCR",$J,"TEMPLATE")) ; GLOBAL FOR STORING TEMPLATE
77 S CCRGLO=$NA(^TMP("GPLCCR",$J,DFN,"CCR")) ; GLOBAL FOR BUILDING THE CCR
78 S ACTGLO=$NA(^TMP("GPLCCR",$J,DFN,"ACTORS")) ; GLOBAL FOR ALL ACTORS
79 ; TO GET PART OF THE CCR RETURNED, PASS CCRPART="PROBLEMS" ETC
80 S CCRGRTN=$NA(^TMP("GPLCCR",$J,DFN,CCRPART)) ; RTN GLO NM OF PART OR ALL
81 D LOAD^GPLCCR0(TGLOBAL) ; LOAD THE CCR TEMPLATE
82 D CP^GPLXPATH(TGLOBAL,CCRGLO) ; COPY THE TEMPLATE TO CCR GLOBAL
83 ;
84 ; DELETE THE BODY, ACTORS AND SIGNATURES SECTIONS FROM GLOBAL
85 ; THESE WILL BE POPULATED AFTER CALLS TO THE XPATH ROUTINES
86 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Body")
87 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Actors")
88 D REPLACE^GPLXPATH(CCRGLO,"","//ContinuityOfCareRecord/Signatures")
89 I DEBUG F I=1:1:@CCRGLO@(0) W @CCRGLO@(I),!
90 ;
91 D HDRMAP(CCRGLO,DFN,HDRARY) ; MAP HEADER VARIABLES
92 ;
93 K ^TMP("GPLCCR",$J,"CCRSTEP") ; KILL GLOBAL PRIOR TO ADDING TO IT
94 S CCRXTAB=$NA(^TMP("GPLCCR",$J,"CCRSTEP")) ; GLOBAL TO STORE CCR STEPS
95 D INITSTPS(CCRXTAB) ; INITIALIZED CCR PROCESSING STEPS
96 N PROCI,XI,TAG,RTN,CALL,XPATH,IXML,OXML,INXML,CCRBLD
97 F PROCI=1:1:@CCRXTAB@(0) D ; PROCESS THE CCR BODY SECTIONS
98 . S XI=@CCRXTAB@(PROCI) ; CALL COPONENTS TO PARSE
99 . S RTN=$P(XI,";",2) ; NAME OF ROUTINE TO CALL
100 . S TAG=$P(XI,";",1) ; LABEL INSIDE ROUTINE TO CALL
101 . S XPATH=$P(XI,";",3) ; XPATH TO XML TO PASS TO ROUTINE
102 . D QUERY^GPLXPATH(TGLOBAL,XPATH,"INXML") ; EXTRACT XML TO PASS
103 . S IXML="INXML"
104 . S OXML=$P(XI,";",4) ; ARRAY FOR SECTION VALUES
105 . ; K @OXML ; KILL EXPECTED OUTPUT ARRAY
106 . ; W OXML,!
107 . S CALL="D "_TAG_"^"_RTN_"(IXML,DFN,OXML)" ; SETUP THE CALL
108 . I DEBUG W "RUNNING ",CALL,!
109 . X CALL
110 . ; NOW INSERT THE RESULTS IN THE CCR BUFFER
111 . I @OXML@(0)'=0 D ; THERE IS A RESULT
112 . . D INSERT^GPLXPATH(CCRGLO,OXML,"//ContinuityOfCareRecord/Body")
113 . . I DEBUG F GPLI=1:1:@OXML@(0) W @OXML@(GPLI),!
114 D ACTLST^GPLCCR(CCRGLO,ACTGLO) ; GEN THE ACTOR LIST
115 D QUERY^GPLXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","ACTT")
116 D EXTRACT^GPLACTOR("ACTT",ACTGLO,"ACTT2")
117 D INSINNER^GPLXPATH(CCRGLO,"ACTT2","//ContinuityOfCareRecord/Actors")
118 N TRIMI,J,DONE S DONE=0
119 F TRIMI=0:0 D Q:DONE ; DELETE UNTIL ALL EMPTY ELEMENTS ARE GONE
120 . S J=$$TRIM^GPLXPATH(CCRGLO) ; DELETE EMPTY ELEMENTS
121 . I DEBUG W "TRIMMED",J,!
122 . I J=0 S DONE=1 ; DONE WHEN TRIM RETURNS FALSE
123 Q
124 ;
125INITSTPS(TAB) ; INITIALIZE CCR PROCESSING STEPS
126 ; TAB IS PASSED BY NAME
127 I DEBUG W "TAB= ",TAB,!
128 ; ORDER FOR CCR IS PROBLEMS,FAMILYHISTORY,SOCIALHISTORY,MEDICATIONS,VITALSIGNS,RESULTS,HEALTHCAREPROVIDERS
129 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLPROBS;//ContinuityOfCareRecord/Body/Problems;^TMP(""GPLCCR"",$J,DFN,""PROBLEMS"")")
130 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLMEDS;//ContinuityOfCareRecord/Body/Medications;^TMP(""GPLCCR"",$J,DFN,""MEDICATIONS"")")
131 D PUSH^GPLXPATH(TAB,"EXTRACT;GPLVITAL;//ContinuityOfCareRecord/Body/VitalSigns;^TMP(""GPLCCR"",$J,DFN,""VITALS"")")
132 I TESTLAB D PUSH^GPLXPATH(TAB,"EXTRACT;GPLLABS;//ContinuityOfCareRecord/Body/Results;^TMP(""GPLCCR"",$J,DFN,""RESULTS"")")
133 I TESTALERT D PUSH^GPLXPATH(TAB,"EXTRACT;GPLALERT;//ContinuityOfCareRecord/Body/Alerts;^TMP(""GPLCCR"",$J,DFN,""ALERTS"")")
134 Q
135 ;
136HDRMAP(CXML,DFN,IHDR) ; MAP HEADER VARIABLES: FROM, TO ECT
137 N VMAP S VMAP=$NA(^TMP("GPLCCR",$J,DFN,"HEADER"))
138 ; K @VMAP
139 S @VMAP@("DATETIME")=$$FMDTOUTC^CCRUTIL($$NOW^XLFDT,"DT")
140 I IHDR="" D ; HEADER ARRAY IS NOT PROVIDED, USE DEFAULTS
141 . S @VMAP@("ACTORPATIENT")="ACTORPATIENT_"_DFN
142 . S @VMAP@("ACTORFROM")="ACTORORGANIZATION_"_DUZ ; FROM DUZ - ???
143 . S @VMAP@("ACTORFROM2")="ACTORSYSTEM_1" ; SECOND FROM IS THE SYSTEM
144 . S @VMAP@("ACTORTO")="ACTORPATIENT_"_DFN ; FOR TEST PURPOSES
145 . S @VMAP@("PURPOSEDESCRIPTION")="CEND PHR" ; FOR TEST PURPOSES
146 . S @VMAP@("ACTORTOTEXT")="Patient" ; FOR TEST PURPOSES
147 . ; THIS IS THE USE CASE FOR THE PHR WHERE "TO" IS THE PATIENT
148 I IHDR'="" D ; HEADER VALUES ARE PROVIDED
149 . D CP^GPLXPATH(IHDR,VMAP) ; COPY HEADER VARIABLES TO MAP ARRAY
150 N CTMP
151 D MAP^GPLXPATH(CXML,VMAP,"CTMP")
152 D CP^GPLXPATH("CTMP",CXML)
153 Q
154 ;
155ACTLST(AXML,ACTRTN) ; RETURN THE ACTOR LIST FOR THE XML IN AXML
156 ; AXML AND ACTRTN ARE PASSED BY NAME
157 ; EACH ACTOR RECORD HAS 3 PARTS - IE IF OBJECTID=ACTORPATIENT_2
158 ; P1= OBJECTID - ACTORPATIENT_2
159 ; P2= OBJECT TYPE - PATIENT OR PROVIDER OR SOFTWARE
160 ;OR INSTITUTION
161 ; OR PERSON(IN PATIENT FILE IE NOK)
162 ; P3= IEN RECORD NUMBER FOR ACTOR - 2
163 N I,J,K,L
164 K @ACTRTN ; CLEAR RETURN ARRAY
165 F I=1:1:@AXML@(0) D ; SCAN ALL LINES
166 . I @AXML@(I)?.E1"<ActorID>".E D ; THERE IS AN ACTOR THIS LINE
167 . . S J=$P($P(@AXML@(I),"<ActorID>",2),"</ActorID>",1)
168 . . I DEBUG W "<ActorID>=>",J,!
169 . . I J'="" S K(J)="" ; HASHING ACTOR
170 . . ; TO GET RID OF DUPLICATES
171 S I="" ; GOING TO $O THROUGH THE HASH
172 F J=0:0 D Q:$O(K(I))=""
173 . S I=$O(K(I)) ; WALK THROUGH THE HASH OF ACTORS
174 . S $P(L,U,1)=I ; FIRST PIECE IS THE OBJECT ID
175 . S $P(L,U,2)=$P($P(I,"ACTOR",2),"_",1) ; ACTOR TYPE
176 . S $P(L,U,3)=$P(I,"_",2) ; IEN RECORD NUMBER FOR ACTOR
177 . D PUSH^GPLXPATH(ACTRTN,L) ; ADD THE ACTOR TO THE RETURN ARRAY
178 Q
179 ;
180TEST ; RUN ALL THE TEST CASES
181 D TESTALL^GPLUNIT("GPLCCR")
182 Q
183 ;
184ZTEST(WHICH) ; RUN ONE SET OF TESTS
185 N ZTMP
186 D ZLOAD^GPLUNIT("ZTMP","GPLCCR")
187 D ZTEST^GPLUNIT(.ZTMP,WHICH)
188 Q
189 ;
190TLIST ; LIST THE TESTS
191 N ZTMP
192 D ZLOAD^GPLUNIT("ZTMP","GPLCCR")
193 D TLIST^GPLUNIT(.ZTMP)
194 Q
195 ;
196 ;;><TEST>
197 ;;><PROBLEMS>
198 ;;>>>K GPL S GPL=""
199 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","PROBLEMS","","","")
200 ;;>>?@GPL@(@GPL@(0))["</Problems>"
201 ;;><VITALS>
202 ;;>>>K GPL S GPL=""
203 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","VITALS","","","")
204 ;;>>?@GPL@(@GPL@(0))["</VitalSigns>"
205 ;;><CCR>
206 ;;>>>K GPL S GPL=""
207 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCR","","","")
208 ;;>>?@GPL@(@GPL@(0))["</ContinuityOfCareRecord>"
209 ;;><ACTLST>
210 ;;>>>K GPL S GPL=""
211 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","CCR","","","")
212 ;;>>>D ACTLST^GPLCCR(GPL,"ACTTEST")
213 ;;><ACTORS>
214 ;;>>>D ZTEST^GPLCCR("ACTLST")
215 ;;>>>D QUERY^GPLXPATH(TGLOBAL,"//ContinuityOfCareRecord/Actors","G2")
216 ;;>>>D EXTRACT^GPLACTOR("G2","ACTTEST","G3")
217 ;;>>?G3(G3(0))["</Actors>"
218 ;;><TRIM>
219 ;;>>>D ZTEST^GPLCCR("CCR")
220 ;;>>>W $$TRIM^GPLXPATH(CCRGLO)
221 ;;><ALERTS>
222 ;;>>>S TESTALERT=1
223 ;;>>>K GPL S GPL=""
224 ;;>>>D CCRRPC^GPLCCR(.GPL,"2","ALERTS","","","")
225 ;;>>?@GPL@(@GPL@(0))["</Alerts>"
226
Note: See TracBrowser for help on using the repository browser.